Send data to emoncms with yun

Ho recentemente acquistato un arduino Yun e vorrei utilizzarlo per inviare dati a emoncms. Mi potreste indicare dove trovare la modalità di utilizzo di curl, ho provato con l'esempio presente su Arduino 1.5.4 per xively ma non capisco le modalità di invio dei dati. Grazie

Ciao

questa è l'homepage del progetto curl http://curl.haxx.se/, il link docs ha un link alla "huge man page" con tutte le opzioni disponibili

here is reference link for how to use Yun to send data to Emoncms: https://github.com/dragino/modules/tree/master/examples/Bridge/EmoncmsClient

Here is the code tested and working

/*
  Emoncms sensor client with Strings 
 
 This sketch sends fake data to EmonCMS,
 
 
 Based on a script
 created 15 March 2010
 updated 27 May 2013
 by Tom Igoe
   
 updated 6, Oct, 2013 to support Emoncms
 by Edwin Chen
 
 updated 8, Dic, 2013 to support Yun
 by Vincenzo Altieri aka raxpa
   
 */


// include all Libraries needed:
#include <Process.h>
#define APIKEY        "Your apikey"                  // replace your pachube api key here
#define USERAGENT     "Arduino-Yun"           // user agent is the project name


// set up net client info:
const unsigned long postingInterval = 60000;  //delay between updates to emoncms.com
unsigned long lastRequest = 0;      // when you last made a request
String dataString = "";

void setup() {
  // start serial port:
  Bridge.begin();
  Console.begin(); 
  

  while(!Console);    // wait for Network Serial to open
  Console.println("Emoncms client");

  // Do a first update immediately
  updateData();
  sendData();
  lastRequest = millis();
}

void loop() {
  // get a timestamp so you can calculate reading and sending intervals:
  long now = millis();

  // if the sending interval has passed since your
  // last connection, then connect again and send data:
  if (now - lastRequest >= postingInterval) {
    updateData();
    sendData();
    lastRequest = now;
  }
}

void updateData() {
  // convert the readings to a String to send it:
  dataString = "Temperature:";
  dataString += random(10) + 20;
  // add pressure:
  dataString += ",Humidity:";
  dataString += random(5) + 100;
}

// this method makes a HTTP connection to the server:
void sendData() {
  // form the string for the API header parameter:
  String apiString = "apikey=";
  apiString += APIKEY;

  // form the string for the URL parameter:
  String url = "http://emoncms.org/api/post?";
  url += "json={";
  url += dataString;
  url += "}&";
  url += apiString;
  // Send the HTTP PUT request

  // Is better to declare the Process here, so when the
  // sendData function finishes the resources are immediately
  // released. Declaring it global works too, BTW.
  Process emoncms;
  Console.print("\n\nSending data... ");
  emoncms.begin("curl");
  emoncms.addParameter(url);
  emoncms.run();
  Console.println("done!");

  // If there's incoming data from the net connection,
  // send it out the Serial:
  while (emoncms.available()>0) {
    char c = emoncms.read();
    Console.write(c);
  }

}

Grazie raxpa, con il tuo esempio ho risolto velocemente. :)

Ho provato lo script riportato qui da raxpa e funziona perfettamente. Ho poi tentato di inviare dei dati reali leggendoli dalla A0 e A1. Il risultato è che nella console locale appaiono i dati ma all'interno di emoncms appare sempre un valore nullo. Si può avere una variante di codice che legge i dati dalle due porte e li invia correttamente? grazie