Hello
I am again with the use of Arduino
I ask for help installing the sensor MTH02 I bought because like SHT10 but cheaper.
I tried to use the library SHT1x-master (By Jonathan Oxer) but not working.
I connected:
Sensor -> Arduino
Vdd -> 5v
Vss -> GND
Data -> 11 PIN
SNSB -> 10 PIN
Can you help me?
Cippa149:
Hello
I am again with the use of Arduino
I ask for help installing the sensor MTH02 I bought because like SHT10 but cheaper.
I tried to use the library SHT1x-master (By Jonathan Oxer) but not working.I connected:
Sensor -> ArduinoVdd -> 5v
Vss -> GND
Data -> 11 PIN
SNSB -> 10 PINCan you help me?
It is like the SHT10 but apparently not exactly the same. It seems that cheaper comes with a price ...
You need the datasheet of both sensors to see what to add/change/remove from the SHT library to get it working.
Posting links to those datasheets might help us to help you.
Posting your code so far too (use code tags with the </> button)
MTH02 Datasheet:
SHT1X.h
/**
* SHT1x Library
*
* Copyright 2009 Jonathan Oxer <jon@oxer.com.au> / <www.practicalarduino.com>
* Based on previous work by:
* Maurice Ribble: <www.glacialwanderer.com/hobbyrobotics/?p=5>
* Wayne ?: <ragingreality.blogspot.com/2008/01/ardunio-and-sht15.html>
*
* Manages communication with SHT1x series (SHT10, SHT11, SHT15)
* temperature / humidity sensors from Sensirion (www.sensirion.com).
*/
#ifndef SHT1x_h
#define SHT1x_h
#if (ARDUINO >= 100)
#include <Arduino.h>
#else
#include <WProgram.h>
#endif
class SHT1x
{
public:
SHT1x(int dataPin, int clockPin);
float readHumidity();
float readTemperatureC();
float readTemperatureF();
private:
int _dataPin;
int _clockPin;
int _numBits;
float readTemperatureRaw();
int shiftIn(int _dataPin, int _clockPin, int _numBits);
void sendCommandSHT(int _command, int _dataPin, int _clockPin);
void waitForResultSHT(int _dataPin);
int getData16SHT(int _dataPin, int _clockPin);
void skipCrcSHT(int _dataPin, int _clockPin);
};
#endif
SHT1X.cpp
/**
* SHT1x Library
*
* Copyright 2009 Jonathan Oxer <jon@oxer.com.au> / <www.practicalarduino.com>
* Based on previous work by:
* Maurice Ribble: <www.glacialwanderer.com/hobbyrobotics/?p=5>
* Wayne ?: <ragingreality.blogspot.com/2008/01/ardunio-and-sht15.html>
*
* Manages communication with SHT1x series (SHT10, SHT11, SHT15)
* temperature / humidity sensors from Sensirion (www.sensirion.com).
*/
#if (ARDUINO >= 100)
#include <Arduino.h>
#else
#include <WProgram.h>
#endif
#include "SHT1x.h"
SHT1x::SHT1x(int dataPin, int clockPin)
{
_dataPin = dataPin;
_clockPin = clockPin;
}
/* ================ Public methods ================ */
/**
* Reads the current temperature in degrees Celsius
*/
float SHT1x::readTemperatureC()
{
int _val; // Raw value returned from sensor
float _temperature; // Temperature derived from raw value
// Conversion coefficients from SHT15 datasheet
const float D1 = -40.0; // for 14 Bit @ 5V
const float D2 = 0.01; // for 14 Bit DEGC
// Fetch raw value
_val = readTemperatureRaw();
// Convert raw value to degrees Celsius
_temperature = (_val * D2) + D1;
return (_temperature);
}
/**
* Reads the current temperature in degrees Fahrenheit
*/
float SHT1x::readTemperatureF()
{
int _val; // Raw value returned from sensor
float _temperature; // Temperature derived from raw value
// Conversion coefficients from SHT15 datasheet
const float D1 = -40.0; // for 14 Bit @ 5V
const float D2 = 0.018; // for 14 Bit DEGF
// Fetch raw value
_val = readTemperatureRaw();
// Convert raw value to degrees Fahrenheit
_temperature = (_val * D2) + D1;
return (_temperature);
}
/**
* Reads current temperature-corrected relative humidity
*/
float SHT1x::readHumidity()
{
int _val; // Raw humidity value returned from sensor
float _linearHumidity; // Humidity with linear correction applied
float _correctedHumidity; // Temperature-corrected humidity
float _temperature; // Raw temperature value
// Conversion coefficients from SHT15 datasheet
const float C1 = -4.0; // for 12 Bit
const float C2 = 0.0405; // for 12 Bit
const float C3 = -0.0000028; // for 12 Bit
const float T1 = 0.01; // for 14 Bit @ 5V
const float T2 = 0.00008; // for 14 Bit @ 5V
// Command to send to the SHT1x to request humidity
int _gHumidCmd = 0b00000101;
// Fetch the value from the sensor
sendCommandSHT(_gHumidCmd, _dataPin, _clockPin);
waitForResultSHT(_dataPin);
_val = getData16SHT(_dataPin, _clockPin);
skipCrcSHT(_dataPin, _clockPin);
// Apply linear conversion to raw value
_linearHumidity = C1 + C2 * _val + C3 * _val * _val;
// Get current temperature for humidity correction
_temperature = readTemperatureC();
// Correct humidity value for current temperature
_correctedHumidity = (_temperature - 25.0 ) * (T1 + T2 * _val) + _linearHumidity;
return (_correctedHumidity);
}
/* ================ Private methods ================ */
/**
* Reads the current raw temperature value
*/
float SHT1x::readTemperatureRaw()
{
int _val;
// Command to send to the SHT1x to request Temperature
int _gTempCmd = 0b00000011;
sendCommandSHT(_gTempCmd, _dataPin, _clockPin);
waitForResultSHT(_dataPin);
_val = getData16SHT(_dataPin, _clockPin);
skipCrcSHT(_dataPin, _clockPin);
return (_val);
}
/**
*/
int SHT1x::shiftIn(int _dataPin, int _clockPin, int _numBits)
{
int ret = 0;
int i;
for (i=0; i<_numBits; ++i)
{
digitalWrite(_clockPin, HIGH);
delay(10); // I don't know why I need this, but without it I don't get my 8 lsb of temp
ret = ret*2 + digitalRead(_dataPin);
digitalWrite(_clockPin, LOW);
}
return(ret);
}
/**
*/
void SHT1x::sendCommandSHT(int _command, int _dataPin, int _clockPin)
{
int ack;
// Transmission Start
pinMode(_dataPin, OUTPUT);
pinMode(_clockPin, OUTPUT);
digitalWrite(_dataPin, HIGH);
digitalWrite(_clockPin, HIGH);
digitalWrite(_dataPin, LOW);
digitalWrite(_clockPin, LOW);
digitalWrite(_clockPin, HIGH);
digitalWrite(_dataPin, HIGH);
digitalWrite(_clockPin, LOW);
// The command (3 msb are address and must be 000, and last 5 bits are command)
shiftOut(_dataPin, _clockPin, MSBFIRST, _command);
// Verify we get the correct ack
digitalWrite(_clockPin, HIGH);
pinMode(_dataPin, INPUT);
ack = digitalRead(_dataPin);
if (ack != LOW) {
//Serial.println("Ack Error 0");
}
digitalWrite(_clockPin, LOW);
ack = digitalRead(_dataPin);
if (ack != HIGH) {
//Serial.println("Ack Error 1");
}
}
/**
*/
void SHT1x::waitForResultSHT(int _dataPin)
{
int i;
int ack;
pinMode(_dataPin, INPUT);
for(i= 0; i < 100; ++i)
{
delay(10);
ack = digitalRead(_dataPin);
if (ack == LOW) {
break;
}
}
if (ack == HIGH) {
//Serial.println("Ack Error 2"); // Can't do serial stuff here, need another way of reporting errors
}
}
/**
*/
int SHT1x::getData16SHT(int _dataPin, int _clockPin)
{
int val;
// Get the most significant bits
pinMode(_dataPin, INPUT);
pinMode(_clockPin, OUTPUT);
val = shiftIn(_dataPin, _clockPin, 8);
val *= 256;
// Send the required ack
pinMode(_dataPin, OUTPUT);
digitalWrite(_dataPin, HIGH);
digitalWrite(_dataPin, LOW);
digitalWrite(_clockPin, HIGH);
digitalWrite(_clockPin, LOW);
// Get the least significant bits
pinMode(_dataPin, INPUT);
val |= shiftIn(_dataPin, _clockPin, 8);
return val;
}
/**
*/
void SHT1x::skipCrcSHT(int _dataPin, int _clockPin)
{
// Skip acknowledge to end trans (no CRC)
pinMode(_dataPin, OUTPUT);
pinMode(_clockPin, OUTPUT);
digitalWrite(_dataPin, HIGH);
digitalWrite(_clockPin, HIGH);
digitalWrite(_clockPin, LOW);
}
PROGRAM EXAMPLE
/**
* ReadSHT1xValues
*
* Read temperature and humidity values from an SHT1x-series (SHT10,
* SHT11, SHT15) sensor.
*
* Copyright 2009 Jonathan Oxer <jon@oxer.com.au>
* www.practicalarduino.com
*/
#include <SHT1x.h>
// Specify data and clock connections and instantiate SHT1x object
#define dataPin 10
#define clockPin 11
SHT1x sht1x(dataPin, clockPin);
void setup()
{
Serial.begin(38400); // Open serial connection to report values to host
Serial.println("Starting up");
}
void loop()
{
float temp_c;
float temp_f;
float humidity;
// Read values from the sensor
temp_c = sht1x.readTemperatureC();
temp_f = sht1x.readTemperatureF();
humidity = sht1x.readHumidity();
// Print the values to the serial port
Serial.print("Temperature: ");
Serial.print(temp_c, DEC);
Serial.print("C / ");
Serial.print(temp_f, DEC);
Serial.print("F. Humidity: ");
Serial.print(humidity);
Serial.println("%");
delay(2000);
}
Can we help me?
For the sake of completeness, pls. see attachment :o
MTH02_hum_temp_sensor.zip (270 KB)