Serial Monitor ReadString()

Hallo Zusammen, ich möchte meinen Seriellen Monitor nutzen, um Befehle an den Controller zu schicken. Mit Zahlen geht es, aber ich möchte zur einfacheren Benutzbarkeit ausgeschriebene Befehle verarbeiten. Beispiel:

String Command;

if (Serial.available() > 0){ 
Command = Serial.readString();

    if (Command == "Format SPIFFS") {
      Serial.println("SPIFFS wird formatiert...");
      SPIFFS.format();
      Serial.println("SPIFFS wurde erfolgreich Formatiert");
    }
....

Ich gebe nun "Format SPIFFS" in die Konsole ein, jedoch passiert leider nichts. Deswegen habe ich

Serial.print(Command);

vor meine Abfrage geschrieben und bekomme auch "Format SPIFFS" als eingelesen Wert ausgegeben. Woran liegt der Fehler und noch wichtiger: wie kann ich Ihn beheben?

Vor der If abfrage habe ich mir die "empfangene" Information noch einmal ausgeben lassen, um dadurch meinen Fehler

Hab es selbst hinbekommen - Close -

void ReadSerialCommands() {

  String Command = "";
  
  while (Serial.available() > 0) {
    Command += (char) Serial.read();
    delay(5); 
    
  if (Command == "Format SPIFFS") 
  {
    Serial.println("SPIFFS wird formatiert...");
    SPIFFS.format();
    Serial.println("SPIFFS wurde erfolgreich Formatiert");
  }
  else if (Command == "Get Temp")
  {
    Serial.println("Temp");
    Serial.println("Aktuelle Temperatur: " + String(Get_Temp()));
  } 

  }
  
}

Besser man macht es nicht-blockierend. Dazu den Serial Monitor so einstellen dass ein CR oder LF am Ende gesendet wird:

const int SERIAL_BUFFER_SIZE = 31;
char serialBuffer[SERIAL_BUFFER_SIZE];

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  if (readSerial(Serial) == true)
  {
    if (strcmp_P(serialBuffer, PSTR("Format SPIFFS")) == 0)
    {
      Serial.println(F("Kommando korrekt"));
    }
    else
    {
      Serial.println(F("Kommando falsch"));
    }
  }
}

bool readSerial(Stream& stream)
{
  static byte index;

  while (stream.available())
  {
    char c = stream.read();

    if (c >= 32 && index < SERIAL_BUFFER_SIZE - 1)
    {
      serialBuffer[index++] = c;
    }
    else if ((c == '\n' || c == '\r') && index > 0)
    {
      serialBuffer[index] = '\0';
      index = 0;
      return true;
    }
  }
  return false;
}