Shield ethernet multiple réception de données en GET

Bonsoir à toute et à tous,
Je suis en train de réalisé un petit projets où il faudrait que depuis un formulaire html sur un site web, je puisse envoyer au minimum 2 chaines de caractères, mais je ne sais pas comment les récupérer sur mon Arduino.
Cordialement,

Personne?

Bonjour, tu peux t’inspirer d’une partie de mon code :

/*
Récupère la valeur GET dans la Requette HTTP du Client
Doit etre de la forme :

http://192.168.1.98:2908/?Requete_GET=12345
=>Requete_GET_1=123
=>Requete_GET_2=45


*/


#include <SPI.h>
#include <Ethernet.h>

byte mac[] = {0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED};
IPAddress ip(192, 168, 1, 98);
EthernetServer serveur_HTML(2908);
EthernetClient client;

byte Requete_GET_1=0;
byte Requete_GET_2=0;


void setup() {
 
  Serial.begin(9600);// Demarre liaison série entre Arduino et PC pour la console
  Ethernet.begin(mac, ip);//Initialise la librairie ethernet et les paramètres du réseau.
  serveur_HTML.begin();   //Demande au serveur de commencer à écouter les connexions entrantes.
}


void loop() {
 
Affiche_la_Page_Web();

}


void Affiche_la_Page_Web(){
 
  String HTTP_req="";  // Stock la requête HTTP reçue
 
  client = serveur_HTML.available(); // création de 'client' s'il y a des données dans 'serveur_HTML'
  if (client) {// si tu detecte q'un client est connecté (Un client HTTP est un logiciel conçu pour se connecter à un serveur HTTP.)
                                                        //(Dans le cas le plus courant, il s'agit d'un navigateur Web)
    boolean Ligne_en_cours_est_vide = true;
   
    while (client.connected()) {// tant que le client est connecté
      if (client.available()) { // si il y a des données a lire
        char c = client.read(); //Associe chaque caractere entrant à c
        Serial.write(c); // Affiche 'c' sur la console
       
        if (HTTP_req.length() < 23) { // ne conserve que les 22 premier caractere de requête HTTP
            HTTP_req += c;
        }
        if (c == '\n' && Ligne_en_cours_est_vide) { // si la ligne en cour est vide
                                                    // et que l'on commence une nouvelle ligne
                                                    // la requête HTTP est terminée
          // Vérifie si une requête GET est présente dans la requête HTTP
          Serial.println(HTTP_req);
          if (HTTP_req.substring (0,6) == "GET /?") { // si la partie entre le caractere 0 et 6 de HTTP_req est egale à : "GET /?" => une requette GET est présente
              Requete_GET_1=(HTTP_req.substring (18,21)).toInt();
              Requete_GET_2=(HTTP_req.substring (21,23)).toInt();
              Serial.println(Requete_GET_1);
              Serial.println(Requete_GET_2);
          }
          // Répond au client avec une en-tête http standard
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          client.println("Page Web Moche");
          client.println("</html>");
          break;//L'instruction break est utilisée pour sortir de la boucle while
        }
        // si '\n' est suivi de '\r' => la ligne est vide
        if (c == '\n') { // si on commence une nouvelle ligne
          Ligne_en_cours_est_vide = true;
        }
        else if (c != '\r') { // si il y a un carractere autre que retour a la ligne
          Ligne_en_cours_est_vide = false; // la ligne n'est pas vide
        }
      }
    }
    delay(1);// laisser le temps au navigateur Web pour recevoir les données
    client.stop(); //Déconnecte le client du serveur.
  } 
}

Merci beaucoup pour votre code, il fonctionne. Cordialement