SMS Versenden mit Siemens TC 35 + DHT11

nachtgeist · September 3, 2022, 4:24pm

Hallo Zusammen, aktuell bastell ich an einem Code für den Siemens TC 35.

Ich würde gerne anhand einer Temperaturabfrage ab einem bestimmten Wert automatisch eine SMS versenden. Der folgende Code funktioniert einwandfrei leider aber nur über den Seriellen Monitor wenn man einen Befehl gefolgt von einem Punkt(.) eingibt. (ohne Einbindung DHT11)

Wie und wo setzte ich jetzt die If Schleife? für den bestimmten wert X des DHT11 Sensors.... eine Variabel t für den Temperaturwert habe ich bereits im DHT11 Code vergeben.
Ich bin leider brutaler Anfänger, von daher Danke für jegliche Infos

Anbei nur der Code vom Siemens TC 35 Modul:

#include <SoftwareSerial.h>
#define rxPin 2
#define txPin 3
 
SoftwareSerial gsmSerial(rxPin, txPin);
char recu[150];    // Array for message
String message = "";
int i;
 
void setup() {
  // initialize digital pin 13 as an output.
  pinMode(13, OUTPUT);
 
  Serial.begin(9600);
  while(!Serial) {}
 
  //--- turn on TC35 ---
  // wire pin 8 Arduino to IGT pin on TC35
  // ground pin for 100 ms - this is the same as pressing the button on the TC35 to start it up
  pinMode(8, INPUT);
  digitalWrite(8, LOW);
  pinMode(8, OUTPUT);
  delay(100);
  pinMode(8, INPUT); 
 
  gsmSerial.begin(9600);
  delay(5000);
  Serial.println("Ready");
}
 
void loop() {
  i = 0;
  while (Serial.available() > 0) {
    recu[i] = Serial.read();
    if ((recu[i] != 46) && (recu[i] != 13) && (recu[i] != 10))
    {
      message += char(recu[i]);
    }
    i++;
    // 46 is ASCII code for "."
    if (recu[i - 1] == 46) {
      SendTextMessage();
      ShowSerialData();
      delay(1000);
      message = "";
      i = 0;
    }
  }
}
 
void SendTextMessage() {
  digitalWrite(13, HIGH);
  Serial.println("Sende SMS...");
 
  gsmSerial.println("AT+CMGF=1");
  delay(500);
  gsmSerial.print("AT+CMGS=\"+49178...\"\r");
  delay(500);
  gsmSerial.print(message);
  delay(500);
  gsmSerial.println((char)26); // ASCII Ctrl-Z
  delay(500);
 
  Serial.println("SMS gesendet.");
  digitalWrite(13, LOW);
}
 
void ShowSerialData() {
  while(gsmSerial.available() > 0) {
    Serial.write(gsmSerial.read());
  }
}

UKHeliBob · September 3, 2022, 4:25pm

Im englischen Teil des Forum müssen die Beiträge und Diskussionen in englischer Sprache verfasst werden. Deswegen wurde diese Diskussion in den deutschen Teil des Forums verschoben.

mfg ein Moderator.

HotSystems · September 3, 2022, 7:58pm

Mein Tipp:
Suche mal hier im Forum nach TC35, da wirst du fündig, da es schon mehrere Beiträge mit diesem Teil hier gibt.

Kai-R · September 3, 2022, 9:49pm

Mal exemplarisch ein Beispiel. Evtl. Fehler beim Einlesen der Temperatur werden nicht behandelt. Ob die Lib für den DHT11 mit Deiner verwendeten übereinstimmt, weiß ich nicht. Aber es geht ja wohl mehr um den Aufbau in der loop Funktion:

#include <Adafruit_Sensor.h>
#include <SoftwareSerial.h>
#include <DHT.h>
#include <DHT_U.h>

// Konstanten
constexpr byte rxPin {2};
constexpr byte txPin {3};
constexpr byte dhtPin {4};     // Digital pin connected to the DHT sensor
constexpr byte igtPin {8};
 
// Globale Variablen/Objekte 
SoftwareSerial gsmSerial(rxPin, txPin);
DHT_Unified dht(dhtPin, DHT11);
String message;

// Forward-Deklarationen
double getTemperature(void);
void buildTemperatureMsg(String&, double);

void setup() {
  Serial.begin(9600);
  while(!Serial) {}

  message.reserve(150);
 
  pinMode(LED_BUILTIN, OUTPUT);
  //--- turn on TC35 ---
  // wire pin 8 Arduino to IGT pin on TC35
  // ground pin for 100 ms - this is the same as pressing the button on the TC35 to start it up
  pinMode(igtPin, INPUT);
  digitalWrite(igtPin, LOW);
  pinMode(igtPin, OUTPUT);
  delay(100);
  pinMode(igtPin, INPUT); 
  gsmSerial.begin(9600);
  dht.begin();

  delay(5000);
  Serial.println("Ready");
}
 
void loop() {
  double temp = getTemperature();
  if (temp > 30.00) {                        // Nur eine Nachricht senden, wenn die 
    buildTemperatureMsg(message,temp);       // Temperatur > 30°C ist.
    SendTextMessage(message);
  }  
  delay(2000);
}
 
void SendTextMessage(String& msg) {
  digitalWrite(LED_BUILTIN, HIGH);
  Serial.println("Sende SMS...");
  gsmSerial.println("AT+CMGF=1");
  delay(500);
  gsmSerial.print("AT+CMGS=\"+49178...\"\r");
  delay(500);
  Serial.println(msg);  
  gsmSerial.print(msg);
  delay(500);
  gsmSerial.println((char)26); // ASCII Ctrl-Z
  delay(500);
  Serial.println("SMS gesendet.");
  digitalWrite(LED_BUILTIN, LOW);
}
 
void ShowSerialData() {
  while(gsmSerial.available() > 0) {
    Serial.write(gsmSerial.read());
  }
}

double getTemperature() {
  sensors_event_t event;
  dht.temperature().getEvent(&event);
  if (isnan(event.temperature)) {
    Serial.println(F("Error reading temperature!"));
  }
  return event.temperature;
}

void buildTemperatureMsg(String& msg, double temp) {
  msg = "Hitzealarm!\nTemperatur: " + String(temp,2) + "°C";
}

noiasca · September 4, 2022, 5:16am

evtl. nur einmal bei überschreiten des Grenzwertes ein SMS senden.
Sonst ist die Wertkarte ruck zuck leer...
ungetestet

#include <Adafruit_Sensor.h>
#include <SoftwareSerial.h>
#include <DHT.h>
#include <DHT_U.h>

// Konstanten
constexpr byte rxPin {2};
constexpr byte txPin {3};
constexpr byte dhtPin {4};     // Digital pin connected to the DHT sensor
constexpr byte igtPin {8};
 
// Globale Variablen/Objekte 
SoftwareSerial gsmSerial(rxPin, txPin);
DHT_Unified dht(dhtPin, DHT11);
String message;   

bool previousState = LOW;  // was war der letzte Status

// Forward-Deklarationen
double getTemperature(void);
void buildTemperatureMsg(String&, double);

void setup() {
  Serial.begin(9600);
  while(!Serial) {}

  message.reserve(150);
 
  pinMode(LED_BUILTIN, OUTPUT);
  //--- turn on TC35 ---
  // wire pin 8 Arduino to IGT pin on TC35
  // ground pin for 100 ms - this is the same as pressing the button on the TC35 to start it up
  pinMode(igtPin, INPUT);
  digitalWrite(igtPin, LOW);
  pinMode(igtPin, OUTPUT);
  delay(100);
  pinMode(igtPin, INPUT); 
  gsmSerial.begin(9600);
  dht.begin();

  delay(5000);
  Serial.println("Ready");
}
 
void loop() {
  double temp = getTemperature();
  if (temp > 30.00 && previousState == LOW) {                        // Nur eine Nachricht senden, wenn die 
    buildTemperatureMsg(message,temp);       // Temperatur > 30°C ist.
    SendTextMessage(message);
    previousState == HIGH;
  }
  else if (temp < 29.50 && previousState == HIGH)
  {
    // zurücksetzen
    previousState == LOW;
  }
  delay(2000);
}
 
void SendTextMessage(String& msg) {
  digitalWrite(LED_BUILTIN, HIGH);
  Serial.println("Sende SMS...");
  gsmSerial.println("AT+CMGF=1");
  delay(500);
  gsmSerial.print("AT+CMGS=\"+49178...\"\r");
  delay(500);
  Serial.println(msg);  
  gsmSerial.print(msg);
  delay(500);
  gsmSerial.println((char)26); // ASCII Ctrl-Z
  delay(500);
  Serial.println("SMS gesendet.");
  digitalWrite(LED_BUILTIN, LOW);
}
 
void ShowSerialData() {
  while(gsmSerial.available() > 0) {
    Serial.write(gsmSerial.read());
  }
}

double getTemperature() {
  sensors_event_t event;
  dht.temperature().getEvent(&event);
  if (isnan(event.temperature)) {
    Serial.println(F("Error reading temperature!"));
  }
  return event.temperature;
}

void buildTemperatureMsg(String& msg, double temp) {
  msg = "Hitzealarm!\nTemperatur: " + String(temp,2) + "°C";
}

Kai-R · September 4, 2022, 5:25am

Ein wichtiger Hinweis . Ich hab. ich bei der Antwort nur auf die „IF“ Frage beschränkt.

Evtl. soll ja auch eine Nachricht gesendet werden, wenn eine bestimmte Temperatur nicht mehr überschritten wird. Spätestens dann muss man sich um bestimmte Zustände kümmern.

my_xy_projekt · September 4, 2022, 6:59am

In Anlehnung an #5 noch mit Wiederholfunktion, wenn die Temperatur weiterhin hoch bleibt.

@noiasca
previousState == LOW; (und HIGH auch)

#include <Adafruit_Sensor.h>
#include <SoftwareSerial.h>
#include <DHT.h>
#include <DHT_U.h>

// Konstanten
constexpr byte rxPin {2};
constexpr byte txPin {3};
constexpr byte dhtPin {4};     // Digital pin connected to the DHT sensor
constexpr byte igtPin {8};

// Globale Variablen/Objekte
SoftwareSerial gsmSerial(rxPin, txPin);
DHT_Unified dht(dhtPin, DHT11);
String message;

bool previousState = LOW;  // was war der letzte Status
const uint32_t repeatTime = 1000UL * 60 * 30;
uint32_t lastSend;

// Forward-Deklarationen
double getTemperature(void);
void buildTemperatureMsg(String &, double);

void setup()
{
  Serial.begin(9600);
  while (!Serial) {}
  message.reserve(150);
  pinMode(LED_BUILTIN, OUTPUT);
  //--- turn on TC35 ---
  // wire pin 8 Arduino to IGT pin on TC35
  // ground pin for 100 ms - this is the same as pressing the button on the TC35 to start it up
  pinMode(igtPin, INPUT);
  digitalWrite(igtPin, LOW);
  pinMode(igtPin, OUTPUT);
  delay(100);
  pinMode(igtPin, INPUT);
  gsmSerial.begin(9600);
  dht.begin();
  delay(5000);
  Serial.println("Ready");
}

void loop()
{
  double temp = getTemperature();
  if (temp > 30.00)                             // Wenn Temperatur > 30°C ist
  {
    if (previousState == LOW ||                 // Nachricht senden, wenn vorher noch nicht
        millis() - lastSend > repeatTime)       // ODER Zeit abgelaufen
    {
      buildTemperatureMsg(message, temp);       
      SendTextMessage(message);
      previousState = HIGH;
      lastSend = millis();
    }
  }
  else if (temp < 29.50)
  {
    // zurücksetzen
    previousState = LOW;
  }
  delay(2000);
}
void SendTextMessage(String &msg)
{
  digitalWrite(LED_BUILTIN, HIGH);
  Serial.println("Sende SMS...");
  gsmSerial.println("AT+CMGF=1");
  delay(500);
  gsmSerial.print("AT+CMGS=\"+49178...\"\r");
  delay(500);
  Serial.println(msg);
  gsmSerial.print(msg);
  delay(500);
  gsmSerial.println((char)26); // ASCII Ctrl-Z
  delay(500);
  Serial.println("SMS gesendet.");
  digitalWrite(LED_BUILTIN, LOW);
}
void ShowSerialData()
{
  while (gsmSerial.available() > 0)
  {
    Serial.write(gsmSerial.read());
  }
}
double getTemperature()
{
  sensors_event_t event;
  dht.temperature().getEvent(&event);
  if (isnan(event.temperature))
  {
    Serial.println(F("Error reading temperature!"));
  }
  return event.temperature;
}
void buildTemperatureMsg(String &msg, double temp)
{
  msg = "Hitzealarm!\nTemperatur: " + String(temp, 2) + "°C";
}

nachtgeist · September 8, 2022, 8:01am

Danke für die Zahlreiche Rückmeldung Habs !

nachtgeist · September 8, 2022, 9:38am

Zur Info der Finalen Version: Der String der als SMS - versendet wird, darf nicht zu lang sein. meine Anfangs-Nachricht: Temperaturanstieg inkl. Grad kam bei mir keinmal an. Hab mich jetzt beschränkt auf "SOS" damit funktioniert es in 80% der Fälle.

#include <Adafruit_Sensor.h>
#include <SoftwareSerial.h>
#include <DHT.h>
#include <DHT_U.h>

// Konstanten
constexpr byte rxPin {2};
constexpr byte txPin {3};
constexpr byte dhtPin {4};     // Digital pin connected to the DHT sensor
constexpr byte igtPin {8};
 
// Globale Variablen/Objekte 
SoftwareSerial gsmSerial(rxPin, txPin);
DHT_Unified dht(dhtPin, DHT22);
String message;   

bool previousState = LOW;  // was war der letzte Status

// Forward-Deklarationen
double getTemperature(void);
void buildTemperatureMsg(String&, double);

void setup() {
  Serial.begin(9600);
  while(!Serial) {}

  message.reserve(150);
 
  pinMode(LED_BUILTIN, OUTPUT);
  //--- turn on TC35 ---
  // wire pin 8 Arduino to IGT pin on TC35
  // ground pin for 100 ms - this is the same as pressing the button on the TC35 to start it up
  pinMode(igtPin, INPUT);
  digitalWrite(igtPin, LOW);
  pinMode(igtPin, OUTPUT);
  delay(100);
  pinMode(igtPin, INPUT); 
  gsmSerial.begin(9600);
  dht.begin();

  delay(2000);
  Serial.println("Ready");
}
 
void loop() {
  double temp = getTemperature();
  if (temp > 28.00 && previousState == LOW) { // Nur eine Nachricht senden, wenn die 
    buildTemperatureMsg(message,temp);        // Temperatur > 30°C ist.
    SendTextMessage(message);
    previousState == HIGH;
  }
  else if (temp < 27.50 && previousState == HIGH)
  {
    // zurücksetzen
    previousState == LOW;
  }
  delay(2000);
}

 
void SendTextMessage(String& msg) {
  digitalWrite(LED_BUILTIN, HIGH);
  Serial.println("Sende SMS...");
  gsmSerial.println("AT+CMGF=1");
  delay(500);
  gsmSerial.print("AT+CMGS=\"+4915736526239\"\r");
  delay(500);
  Serial.println(msg);  
  gsmSerial.print("SOS");
  delay(500);
  gsmSerial.println((char)26); // ASCII Ctrl-Z
  delay(500);
  Serial.println("SMS gesendet.");
  digitalWrite(LED_BUILTIN, LOW);
}
 
void ShowSerialData() {
  while(gsmSerial.available() > 0) {
    Serial.write(gsmSerial.read());
  }
}

double getTemperature() {
  sensors_event_t event;
  dht.temperature().getEvent(&event);
  if (isnan(event.temperature)) {
    Serial.println(F("Error reading temperature!"));
  }
  return event.temperature;
}

void buildTemperatureMsg(String& msg, double temp) {
  msg = "Hitzealarm!\nTemperatur: " + String(temp,2) + "°C";
}

my_xy_projekt · September 8, 2022, 9:55am

Der Sketch macht nicht, was Du willst.
Du hast den Fehler mit übernommen, den ich angemerkt hatte.

system · March 7, 2023, 9:55am

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.

Topic		Replies	Views
TC35 SMS empfangen Deutsch	6	2696	May 6, 2021
SIEMENS TC35 GSM Modul funktioniert nicht Deutsch	31	2095	May 6, 2021
NodeMCU and Siemens TC35 for SMS sending Programming	5	772	May 5, 2021
SMS mit TC35 automatisch versenden Deutsch	2	625	May 6, 2021
Siemens TC35 GSM Modul Deutsch	11	9098	May 6, 2021

SMS Versenden mit Siemens TC 35 + DHT11

Related topics