<SOLVED>ESP32 WebServer doesn't respond / responds too late sometimes

Hello there. I’m using a NodeMCU ESP32 as a webserver to controll a LED with my smartphone. It does work acutally and the webserver responds immediately most of the time but sometimes it just takes a few seconds or minutes to respond. Sometimes it doesn’t even respond and I don’t have any idea what the problem is. The website is just reloading / waitng for a respond and eventually gets the respond or gives me an “ERR_ADDRESS_UNREACHABLE” on the browser. Here is my code (actually an example code from the IDE):

#include <WiFi.h>

const char* ssid     = "-";           
const char* password = "-";

WiFiServer server(80);

void setup()
{
    Serial.begin(115200);
    pinMode(5, OUTPUT);      // set the LED pin mode

    delay(10);

    // We start by connecting to a WiFi network

    Serial.println();
    Serial.println();
    Serial.print("Connecting to ");
    Serial.println(ssid);

    WiFi.begin(ssid, password);

    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }

    Serial.println("");
    Serial.println("WiFi connected.");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());
    
    server.begin();

}

int value = 0;

void loop(){
 WiFiClient client = server.available();   // listen for incoming clients

  if (client) {                             // if you get a client,
    Serial.println("New Client.");           // print a message out the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        if (c == '\n') {                    // if the byte is a newline character

          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println();

            // the content of the HTTP response follows the header:
            client.print("Click <a href=\"/H\">here</a> to turn the LED on pin 5 on.
");
            client.print("Click <a href=\"/L\">here</a> to turn the LED on pin 5 off.
");

            // The HTTP response ends with another blank line:
            client.println();
            // break out of the while loop:
            break;
          } else {    // if you got a newline, then clear currentLine:
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }

        // Check to see if the client request was "GET /H" or "GET /L":
        if (currentLine.endsWith("GET /H")) {
          digitalWrite(5, HIGH);               // GET /H turns the LED on
        }
        if (currentLine.endsWith("GET /L")) {
          digitalWrite(5, LOW);                // GET /L turns the LED off
        }
      }
    }
    // close the connection:
    client.stop();
    Serial.println("Client Disconnected.");
  }
}

It could be possible that my network is just week or something but I haven’t had any problems with it before. Maybe it’s just my board… Anyone with same experience? I’m thankful for any help! :slight_smile:

EDIT: Just found out that there is absolutly no problem when using the ESP32 as an Access Point too, so I can connect my smartphone with it and communicate with the ESP using its Access Point. I also found out that there is no specific problem with my network, because my local NodeJS server works fine as well.

But I still want to use the ESP on my local network and not as an Access Point.

It could be possible that my network is just week or something but I haven't had any problems with it before. Maybe it's just my board... Anyone with same experience?

Most probably it's your WiFi network. Remember the ESP32 has a much smaller antenna than for example your laptop. It works only reliably where your laptop's signal quality is good or very good. If the WiFi speed is decreased on your laptop the ESP32 probably will fail as you see it.

But what can I exactly do to fix it?

But what can I exactly do to fix it?

Increase the WiFi signal strength at the ESP32's location. That might be achieved by moving the access point (router), adding a repeater or installing a mesh network.

I would start debugging it by moving the ESP32 directly beside the WiFi access point. Is it reliable then?

I solved it. For some reason it works perfectly, when I add

WiFi.mode (WIFI_STA);

  esp_wifi_set_ps(WIFI_PS_NONE);

before the WiFi.begin().

Can I somehow mark this topic as "solved"?

mageio:
Can I somehow mark this topic as “solved”?

Edit your first post and add to the Subject: