JimboZA:
As you can guess i try run 4 BPM085 sensors on arduino uno
Well I can't speak for other members, but no, I would not have guessed that in a zillion years :~
I should write " AS you can guess NOW"
MattS-UK:
Sorry, I don't have particular experience with the particular sensor you are using.
It looks like your code is crashing elsewhere, so the execution point never reaches your simple print statement - Pretty much what PaulS just said. I am currently re-writing a sensor library after I found a state which could cause the library code to enter an end less loop.
It stands a chance there may be more to reading from multiple sensors than 'just' setting a pin high/low. You might have to reinitialise the sensor, for instance. Exactly what you need to do may well depend on the library code and when you don't do it right, the code crashes within the library.
As ever, best start getting something simple working with one sensor. Then the same simple thing with two and only then attempt to scale up.
Tnx for pointing to right direction. It started work (well at lest printing to serial monitor) then I wrote:
void loop()
{
digitalWrite(6,HIGH); // missing line
Looks what Arduino needed sensor to set all values. Without that line it was no active sensors to do... afraid to write absolute nonsense, but think it's calibration and counting temperature, pressure.
But still.. as MikeGrusin at sparkfun wrote:
You can’t normally connect multiple BMP085s to the same I2C bus since they all have the same I2C (Wire) address. However you can run additional I/O pins to the XCLR input on each BMP085 to turn all of them off (LOW) except one (HIGH), and then talk to that one.
Remember that the calibration data is different from each device. The example code doesn’t handle this by default. You might work around this by re-grabbing the calibration data each time you want to do a reading on a different BMP085, or re-writing the code to save all the calibration data from all connected devices. I know of no existing sketch code to do this, but Google and see what you can find. Good luck!
So to make it work right I'm need more brain, more luck, more help. I'll try my luck with google. If it fails I'll make new post.
PaulS:
Post ALL of your code now.
My code is p0rn you wont able to handle it . I tested many things on it(lcd, some other sensors, some lcd code, like bars) and didn't delete a thing, just commented unused lines... most of them. but original code was this:
/* BMP085 Extended Example Code
by: Jim Lindblom
SparkFun Electronics
date: 1/18/11
updated: 2/26/13
license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/
Get pressure and temperature from the BMP085 and calculate
altitude. Serial.print it out at 9600 baud to serial monitor.
Update (7/19/11): I've heard folks may be encountering issues
with this code, who're running an Arduino at 8MHz. If you're
using an Arduino Pro 3.3V/8MHz, or the like, you may need to
increase some of the delays in the bmp085ReadUP and
bmp085ReadUT functions.
Board I2C / TWI pins
Uno, Ethernet A4 (SDA), A5 (SCL)
Mega2560 20 (SDA), 21 (SCL)
Leonardo 2 (SDA), 3 (SCL)
Due 20 (SDA), 21 (SCL), SDA1, SCL1
**POWER 1.8-3.6V**
*/
#include <Wire.h>
#define BMP085_ADDRESS 0x77 // I2C address of BMP085
const unsigned char OSS = 0; // Oversampling Setting
// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;
// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;
short temperature;
long pressure;
// Use these for altitude conversions
const float p0 = 101325; // Pressure at sea level (Pa)
float altitude;
void setup()
{
Serial.begin(9600);
Wire.begin();
bmp085Calibration();
}
void loop()
{
temperature = bmp085GetTemperature(bmp085ReadUT());
pressure = bmp085GetPressure(bmp085ReadUP());
altitude = (float)44330 * (1 - pow(((float) pressure/p0), 0.190295));
Serial.print("Temperature: ");
Serial.print(temperature, DEC);
Serial.println(" *0.1 deg C");
Serial.print("Pressure: ");
Serial.print(pressure, DEC);
Serial.println(" Pa");
Serial.print("Altitude: ");
Serial.print(altitude, 2);
Serial.println(" m");
Serial.println();
delay(1000);
}
// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
ac1 = bmp085ReadInt(0xAA);
ac2 = bmp085ReadInt(0xAC);
ac3 = bmp085ReadInt(0xAE);
ac4 = bmp085ReadInt(0xB0);
ac5 = bmp085ReadInt(0xB2);
ac6 = bmp085ReadInt(0xB4);
b1 = bmp085ReadInt(0xB6);
b2 = bmp085ReadInt(0xB8);
mb = bmp085ReadInt(0xBA);
mc = bmp085ReadInt(0xBC);
md = bmp085ReadInt(0xBE);
}
// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
long x1, x2;
x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
x2 = ((long)mc << 11)/(x1 + md);
b5 = x1 + x2;
return ((b5 + 8)>>4);
}
// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
long x1, x2, x3, b3, b6, p;
unsigned long b4, b7;
b6 = b5 - 4000;
// Calculate B3
x1 = (b2 * (b6 * b6)>>12)>>11;
x2 = (ac2 * b6)>>11;
x3 = x1 + x2;
b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
// Calculate B4
x1 = (ac3 * b6)>>13;
x2 = (b1 * ((b6 * b6)>>12))>>16;
x3 = ((x1 + x2) + 2)>>2;
b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
b7 = ((unsigned long)(up - b3) * (50000>>OSS));
if (b7 < 0x80000000)
p = (b7<<1)/b4;
else
p = (b7/b4)<<1;
x1 = (p>>8) * (p>>8);
x1 = (x1 * 3038)>>16;
x2 = (-7357 * p)>>16;
p += (x1 + x2 + 3791)>>4;
return p;
}
// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
unsigned char data;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 1);
while(!Wire.available())
;
return Wire.read();
}
// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
unsigned char msb, lsb;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 2);
while(Wire.available()<2)
;
msb = Wire.read();
lsb = Wire.read();
return (int) msb<<8 | lsb;
}
// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
unsigned int ut;
// Write 0x2E into Register 0xF4
// This requests a temperature reading
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x2E);
Wire.endTransmission();
// Wait at least 4.5ms
delay(5);
// Read two bytes from registers 0xF6 and 0xF7
ut = bmp085ReadInt(0xF6);
return ut;
}
// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
unsigned char msb, lsb, xlsb;
unsigned long up = 0;
// Write 0x34+(OSS<<6) into register 0xF4
// Request a pressure reading w/ oversampling setting
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x34 + (OSS<<6));
Wire.endTransmission();
// Wait for conversion, delay time dependent on OSS
delay(2 + (3<<OSS));
// Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF6);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 3);
// Wait for data to become available
while(Wire.available() < 3)
;
msb = Wire.read();
lsb = Wire.read();
xlsb = Wire.read();
up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
return up;
}
Tnx to Owner of code for sharing it, if you know him say tnx from me
Again thanks everyone for help. I'm really happy what my for
loop and if
statements was ok. As I sad it's my hobby, I'm carpenter so in my job here is nothing even close to coding.