Station météo connecté + MQTT

N1co44 · July 22, 2022, 10:39am

Bonjour, j'ai un souci dans mon code de station météo connecté, j'ai une fonction qui n'est pas prise en compte, celle de récupérer une température de piscine en MQTT. Je ne comprends pas pourquoi.

Je précise que cette fonctionne marche quand elle n'est pas intégrer au code de la station météo,
je récupère bien cette valeur de température.

Voici la fonction qui n'est pas exécuté:

void callback(char* topic, byte* payload, unsigned int length) {
char str[length+1];
Serial.print("Message arrived [");
Serial.print(topic);
Serial.print("] ");
int i=0;
for (i=0;i<length;i++) {
Serial.print((char)payload[i]);
str[i]=(char)payload[i];
}
str[i] = 0; // Null termination
Serial.println();
StaticJsonDocument <256> doc;
deserializeJson(doc,payload);
// deserializeJson(doc,str); can use string instead of payload
//const char* Tmp = doc["Tmp"];
long Tmp = doc["Tmp"];
Serial.print("Test ");
int a = Tmp;
int b = 100.0;
//float TempPool = (float)a / b;
TempPool = (float)a / b;

Voici le code complet:
Station_meteo_OLED_V4.zip (17.6 KB)

Ou:

#include <Arduino.h>
#include <ESPWiFi.h>
#include <ESP8266WiFi.h>
#include <ESPHTTPClient.h>
#include <JsonListener.h> 
#include <time.h>                       // time() ctime()
#include <sys/time.h>                   // struct timeval
#include <coredecls.h>                  // settimeofday_cb()

#include "SSD1306Wire.h"
#include "OLEDDisplayUi.h"
#include "Wire.h"
#include "OpenWeatherMapCurrent.h"
#include "OpenWeatherMapForecast.h"
#include "WeatherStationFonts.h"
#include "WeatherStationImages.h"
#include "DHT.h"
#include <PubSubClient.h>
#include <ArduinoJson.h>



//Parametre Wifi:
const char* WIFI_SSID = "XXXX";
const char* WIFI_PWD = "XXXXX";
const char* mqtt_server = "192.168.1.91";
const int port = 1883; 

//Variable Température Piscine
float TempPool;

#define TZ              2       // (utc+) TZ in hours
#define DST_MN          0      // use 60mn for summer time in some countries

//MQTT
WiFiClient espClient;
PubSubClient client(espClient);


// Setup
const int UPDATE_INTERVAL_SECS = 10 * 60; // Update every 30 minutes

// Display Settings
const int I2C_DISPLAY_ADDRESS = 0x3C;

const int SDA_PIN = D2;
const int SDC_PIN = D1;


String OPEN_WEATHER_MAP_APP_ID = "XXXX";
String OPEN_WEATHER_MAP_LOCATION_ID = "XXXX";

// Pick a language code from this list:
// Arabic - ar, Bulgarian - bg, Catalan - ca, Czech - cz, German - de, Greek - el,
// English - en, Persian (Farsi) - fa, Finnish - fi, French - fr, Galician - gl,
// Croatian - hr, Hungarian - hu, Italian - it, Japanese - ja, Korean - kr,
// Latvian - la, Lithuanian - lt, Macedonian - mk, Dutch - nl, Polish - pl,
// Portuguese - pt, Romanian - ro, Russian - ru, Swedish - se, Slovak - sk,
// Slovenian - sl, Spanish - es, Turkish - tr, Ukrainian - ua, Vietnamese - vi,
// Chinese Simplified - zh_cn, Chinese Traditional - zh_tw.
String OPEN_WEATHER_MAP_LANGUAGE = "fr";
const uint8_t MAX_FORECASTS = 4;

const boolean IS_METRIC = true;

// Adjust according to your language
const String WDAY_NAMES[] = {"DIM", "LUN", "MAR", "MER", "JEU", "VEN", "SAM"};
const String MONTH_NAMES[] = {"JAN", "FEV", "MAR", "AVR", "MAI", "JUI", "JUL", "AUT", "SEP", "OCT", "NOV", "DEC"};

/***************************
 * End Settings
 **************************/
 SSD1306Wire     display(I2C_DISPLAY_ADDRESS, SDA_PIN, SDC_PIN);
 OLEDDisplayUi   ui( &display );



OpenWeatherMapCurrentData currentWeather;
OpenWeatherMapCurrent currentWeatherClient;

OpenWeatherMapForecastData forecasts[MAX_FORECASTS];
OpenWeatherMapForecast forecastClient;

#define TZ_MN           ((TZ)*60)
#define TZ_SEC          ((TZ)*3600)
#define DST_SEC         ((DST_MN)*60)
time_t now;

// flag changed in the ticker function every 10 minutes
bool readyForWeatherUpdate = false;

String lastUpdate = "--";

long timeSinceLastWUpdate = 0;



//declaring prototypes
void drawProgress(OLEDDisplay *display, int percentage, String label);
void updateData(OLEDDisplay *display);
void drawDateTime(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawTemp(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawTempPool(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawHum(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawCurrentWeather(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawForecast(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawForecastDetails(OLEDDisplay *display, int x, int y, int dayIndex);
void drawHeaderOverlay(OLEDDisplay *display, OLEDDisplayUiState* state);
void setReadyForWeatherUpdate();

FrameCallback frames[] = { drawDateTime, drawCurrentWeather, drawForecast, drawTemp, drawHum, drawTempPool };
int numberOfFrames = 6;

OverlayCallback overlays[] = { drawHeaderOverlay };
int numberOfOverlays = 1;

DHT dht = DHT(D6, DHT22, 6);





void setup() {
  Serial.begin(115200);
 

  // initialize dispaly
  display.init();
  display.clear();
  display.display();

  display.setFont(ArialMT_Plain_10);
  display.setTextAlignment(TEXT_ALIGN_CENTER);
  display.setContrast(255);
//  display.flipScreenVertically();
  
//  display.begin(SSD1306_SWITCHCAPVCC, 0x3c); // Address 0x3C for 128x32
  dht.begin();
  WiFi.begin(WIFI_SSID, WIFI_PWD);

  
  int counter = 0;
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connexion Wifi...");
    display.clear();
    display.drawString(64, 10, "Connexion WiFi");
    display.drawXbm(46, 30, 8, 8, counter % 3 == 0 ? activeSymbole : inactiveSymbole);
    display.drawXbm(60, 30, 8, 8, counter % 3 == 1 ? activeSymbole : inactiveSymbole);
    display.drawXbm(74, 30, 8, 8, counter % 3 == 2 ? activeSymbole : inactiveSymbole);
    display.display();

    counter++;
  
  }
  Serial.println("Connecté au réseau WIFI");
  delay(2000);
//*******************
  
//****************Connexion MQTT**********************
  client.setServer(mqtt_server, port);
  client.setCallback(callback);
  
  Serial.println("Connexion  MQTT...");
  delay(2000);
  
  while (!client.connected()) {
    Serial.println("Connexion  MQTT...");
    delay(2000);
    if (client.connect("ESP32Client")) {

      Serial.println("connecté !");  

    } else {

      Serial.print("failed with state ");
      Serial.print(client.state());
      delay(2000);

    }
  }
  
  client.subscribe("Home/Pool/Meas1");
  Serial.println("Home/Pool/Meas1");
  delay(8000);

delay(2000);
Serial.print("Temperature Piscine :");
Serial.print(TempPool);
Serial.print("°C");
delay(2000);

//************************************
 
  // Get time from network time service
  configTime(TZ_SEC, DST_SEC, "pool.ntp.org");

  ui.setTargetFPS(30);

  ui.setActiveSymbol(activeSymbole);
  ui.setInactiveSymbol(inactiveSymbole);

  // You can change this to
  // TOP, LEFT, BOTTOM, RIGHT
  ui.setIndicatorPosition(BOTTOM);

  // Defines where the first frame is located in the bar.
  ui.setIndicatorDirection(LEFT_RIGHT);

  // You can change the transition that is used
  // SLIDE_LEFT, SLIDE_RIGHT, SLIDE_TOP, SLIDE_DOWN
  ui.setFrameAnimation(SLIDE_LEFT);

  ui.setFrames(frames, numberOfFrames);

  ui.setOverlays(overlays, numberOfOverlays);

  // Inital UI takes care of initalising the display too.
  ui.init();

  Serial.println("Démarrage Ecran");
 delay(6000);

 
  updateData(&display);
 
  
  display.clear();
  display.setTextAlignment(TEXT_ALIGN_LEFT);
  display.setFont(ArialMT_Plain_10);
  display.drawString(0,0,"Chargement...");
  display.display();  
  delay(4000);
  display.drawString(0,10,"Heure et Date");
  display.display();  
  delay(4000);
  display.drawString(0,20,"Température Pièce");
  display.display();  
  delay(4000);
  display.drawString(0,30,"Humidité");
  display.display();  
  delay(4000);
  display.drawString(0,40,"Prévision Météo Puceul");
  display.display();  
  delay(4000);
  display.drawString(0,50,"Température Piscine");
  display.display();  
  delay(3000);
  Serial.print("Enumération");
  delay(3000);


 
  
}


//*************************************************************


void loop() {

client.loop();


    
  if (millis() - timeSinceLastWUpdate > (1000L*UPDATE_INTERVAL_SECS)) {
    setReadyForWeatherUpdate();
    timeSinceLastWUpdate = millis();
  }

  if (readyForWeatherUpdate && ui.getUiState()->frameState == FIXED) {
    updateData(&display);
  }

  int remainingTimeBudget = ui.update();

  if (remainingTimeBudget > 0) {
    // You can do some work here
    // Don't do stuff if you are below your
    // time budget.
    delay(remainingTimeBudget);
  }


  
}


//***************Temperature PISCINE**************
void callback(char* topic, byte* payload, unsigned int length) {

char str[length+1];
Serial.print("Message arrived [");
Serial.print(topic);
Serial.print("] ");
int i=0;
for (i=0;i<length;i++) {
Serial.print((char)payload[i]);
str[i]=(char)payload[i];

}


str[i] = 0; // Null termination
Serial.println();

StaticJsonDocument <256> doc;
deserializeJson(doc,payload);

// deserializeJson(doc,str); can use string instead of payload
//const char* Tmp = doc["Tmp"];
long Tmp = doc["Tmp"];
Serial.print("Test ");
int a = Tmp;
int b = 100.0;
//float TempPool = (float)a / b;
TempPool = (float)a / b;

}  
//************************************ 




  
void drawProgress(OLEDDisplay *display, int percentage, String label) {
  display->clear();
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  display->drawString(64, 10, label);
  display->drawProgressBar(2, 28, 124, 10, percentage);
  display->display();
}

void updateData(OLEDDisplay *display) {
  drawProgress(display, 10, "Mise à jour Heure...");
  drawProgress(display, 30, "Mise à jour Météo...");
  currentWeatherClient.setMetric(IS_METRIC);
  currentWeatherClient.setLanguage(OPEN_WEATHER_MAP_LANGUAGE);
  currentWeatherClient.updateCurrentById(&currentWeather, OPEN_WEATHER_MAP_APP_ID, OPEN_WEATHER_MAP_LOCATION_ID);
  drawProgress(display, 50, "Mise à jour des prévisions...");
  forecastClient.setMetric(IS_METRIC);
  forecastClient.setLanguage(OPEN_WEATHER_MAP_LANGUAGE);
  uint8_t allowedHours[] = {12};
  forecastClient.setAllowedHours(allowedHours, sizeof(allowedHours));
  forecastClient.updateForecastsById(forecasts, OPEN_WEATHER_MAP_APP_ID, OPEN_WEATHER_MAP_LOCATION_ID, MAX_FORECASTS);

  readyForWeatherUpdate = false;
  drawProgress(display, 100, "FIN...");
  Serial.print("FIN...");
  delay(1000);
}

 
void drawDateTime(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  now = time(nullptr);
  struct tm* timeInfo;
  timeInfo = localtime(&now);
  char buff[16];


  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  String date = WDAY_NAMES[timeInfo->tm_wday];

  sprintf_P(buff, PSTR("%s, %02d/%02d/%04d"), WDAY_NAMES[timeInfo->tm_wday].c_str(), timeInfo->tm_mday, timeInfo->tm_mon+1, timeInfo->tm_year + 1900);
  display->drawString(64 + x, 5 + y, String(buff));
  display->setFont(ArialMT_Plain_24);

  sprintf_P(buff, PSTR("%02d:%02d:%02d"), timeInfo->tm_hour, timeInfo->tm_min, timeInfo->tm_sec);
  display->drawString(64 + x, 15 + y, String(buff));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawTemp(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {

  float temperature = dht.readTemperature()/1.216;
  
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  
  display->drawString(64 + x, 5 + y, "Température Pièce");
  display->setFont(ArialMT_Plain_24);

  display->drawString(64 + x, 15 + y, String(temperature,1)+("°C"));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawHum(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {

  int humidity = dht.readHumidity();
  
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  
  display->drawString(64 + x, 5 + y, "Humidité");
  display->setFont(ArialMT_Plain_24);

  display->drawString(64 + x, 15 + y, String(humidity)+(" %"));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawTempPool(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  //int TempPool;
  //float temperaturePool =  TemperaturePiscine;
  //float temperaturePool = dht.readTemperature();
  //int temperaturePool = TempPool;
  
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  
  display->drawString(64 + x, 5 + y, "Température Piscine");
  display->setFont(ArialMT_Plain_24);

  display->drawString(64 + x, 15 + y, String(TempPool,1)+("°C"));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawCurrentWeather(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  display->setFont(ArialMT_Plain_10);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->drawString(64 + x, 38 + y, currentWeather.description);

  display->setFont(ArialMT_Plain_24);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
  String temp = String(currentWeather.temp, 1) + (IS_METRIC ? "°C" : "°F");
  display->drawString(51 + x, 5 + y, temp);

  display->setFont(Meteocons_Plain_36);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->drawString(23  + x, 0 + y, currentWeather.iconMeteoCon);
}


void drawForecast(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  drawForecastDetails(display, x, y, 0);
  drawForecastDetails(display, x + 44, y, 1);
  drawForecastDetails(display, x + 88, y, 2);
}

void drawForecastDetails(OLEDDisplay *display, int x, int y, int dayIndex) {
  time_t observationTimestamp = forecasts[dayIndex].observationTime;
  struct tm* timeInfo;
  timeInfo = localtime(&observationTimestamp);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  display->drawString(x + 20, y, WDAY_NAMES[timeInfo->tm_wday]);

  display->setFont(Meteocons_Plain_21);
  display->drawString(x + 20, y + 12, forecasts[dayIndex].iconMeteoCon);
  String temp = String(forecasts[dayIndex].temp, 0) + (IS_METRIC ? "°C" : "°F");
  display->setFont(ArialMT_Plain_10);
  display->drawString(x + 20, y + 34, temp);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawHeaderOverlay(OLEDDisplay *display, OLEDDisplayUiState* state) {
  now = time(nullptr);
  struct tm* timeInfo;
  timeInfo = localtime(&now);
  char buff[14];
  sprintf_P(buff, PSTR("%02d:%02d"), timeInfo->tm_hour, timeInfo->tm_min);

  display->setColor(WHITE);
  display->setFont(ArialMT_Plain_10);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
  display->drawString(0, 54, String(buff));
  display->setTextAlignment(TEXT_ALIGN_RIGHT);
  String temp = String(currentWeather.temp, 1) + (IS_METRIC ? "°C" : "°F");
  display->drawString(128, 54, temp);
  display->drawHorizontalLine(0, 52, 128);
}

void setReadyForWeatherUpdate() {
  Serial.println("Setting readyForUpdate to true");
  readyForWeatherUpdate = true;
}

Merci d'avance pour votre aide

al1fch · July 22, 2022, 10:50am

Bonjour @N1co44

Un nombre croissant d'utilisateurs utilisent leur smartphone pour visiter le forum.
Mettre le code en fichier joint ne leur permet pas d'intervenir

-> Publier le code intégral dans le corps du message en respectant le balisage mentionné dans les Bonnes Pratiques du Forum Francophone

Il sera alors possible de voir entre autres comment le programme s'y prend pour souscrire au topic porteur de l'information et réceptionner celle-ci

J-M-L · July 22, 2022, 12:04pm

vous déserialisez le payload qui n'est pas forcément terminé par un caractère nul — il semblerait puisque dans la cString que vous construisez str[] (mais n'utilisez pas) vous rajoutez le caractère de fin de chaîne.

si vous voulez utiliser le payload, prenez la variante qui a une taille en paramètre

DeserializationError deserializeJson(JsonDocument& doc, const char* input, size_t inputSize);

➜

deserializeJson(doc, (const char* ) payload, length);

Sinon :
➜ est-ce que le callback est appelé ?
➜ si oui qu'est-ce qui s'affiche

N1co44 · July 25, 2022, 10:20am

Bonjour,

Merci de votre retour. J'ai apporté votre solution mais elle ne fonctionne pas.

Le callback n'est pas appelé, je ne comprend pas pourquoi .

J-M-L · July 25, 2022, 6:33pm

Commencez par faire un petit code où le callback fonctionne . Ensuite il sera temps de rajouter le reste

N1co44 · July 26, 2022, 3:01pm

J'ai déjà fait ça et cela fonctionne...

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>



//Connexion Wifi !
char* WIFI_SSID = "XXX";
char* WIFI_PWD = "XXX";
char* mqtt_server = "192.168.1.91";
const int port = 1883;

float TempPool;

Adafruit_SSD1306 display = Adafruit_SSD1306(128, 64, &WIRE);

//MQTT
WiFiClient espClient;
PubSubClient client(espClient);


void callback(char* topic, byte* payload, unsigned int length) {

char str[length+1];
Serial.print("Message arrived [");
Serial.print(topic);
Serial.print("] ");
int i=0;
for (i=0;i<length;i++) {
Serial.print((char)payload[i]);
str[i]=(char)payload[i];

}


str[i] = 0; // Null termination
Serial.println();

StaticJsonDocument <256> doc;
deserializeJson(doc,payload);

// deserializeJson(doc,str); can use string instead of payload
//const char* Tmp = doc["Tmp"];
long Tmp = doc["Tmp"];

int a = Tmp;
int b = 100.0;
TempPool = (float)a / b;


Serial.print("Temperature Piscine :");
Serial.print(TempPool);
Serial.print("°C");

display.clearDisplay();
  display.display();
  
  display.setTextSize(1.5);
  display.setTextColor(SSD1306_WHITE);

  display.setCursor(0,20);
  
  display.print("Temperature Piscine: ");
  display.print(TempPool);
  display.println(" C");


  

}
void setup() {
  
  Serial.begin(115200);
  
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C); // Address 0x3C for 128x32
  
   WiFi.begin(WIFI_SSID, WIFI_PWD);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connexion  WiFi..");
  }
  Serial.println("Connecté au réseau WIFI");

  

  client.setServer(mqtt_server, port);
  client.setCallback(callback);

  while (!client.connected()) {
    Serial.println("Connexion  MQTT...");

    if (client.connect("ESP32Client")) {

      Serial.println("connecté !");  

    } else {

      Serial.print("failed with state ");
      Serial.print(client.state());
      delay(2000);

    }
  }
  
  client.subscribe("Home/Pool/Meas1");

display.display();
  delay(1000);

  // Clear the buffer.
  display.clearDisplay();
  display.display();
 

 
}

void loop() {

  
 client.loop();

 display.display();
  delay(1000);

//  Clear the buffer.
  display.clearDisplay();
  display.display();
  
  display.setTextSize(1.5);
  display.setTextColor(SSD1306_WHITE);

  display.setCursor(0,40);
  
  display.print("Temp Piscine: ");
  display.print(TempPool);
  display.println(" C");
  
  Serial.print("Temp Piscine: ");
  Serial.print(TempPool);
  Serial.println("°C ");
  //delay(3000);


}

J-M-L · July 27, 2022, 9:02am

pourquoi avez vous deux fois l'affichage et des délais ?

essayez de simplifier. est-ce que cela fonctionne? (tapé ici à partie de votre code)

#include <ArduinoJson.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

//Connexion Wifi !
char* WIFI_SSID = "XXX";
char* WIFI_PWD = "XXX";
const char* mqtt_server = "192.168.1.91";
const int port = 1883;
float TempPool;

Adafruit_SSD1306 display = Adafruit_SSD1306(128, 64, &WIRE);

//MQTT
WiFiClient espClient;
PubSubClient client(espClient);

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print(F("Message arrived ["));  Serial.print(topic);  Serial.print(F("] "));
  Serial.write(payload, length);
  Serial.println();

  StaticJsonDocument <256> doc;
  DeserializationError err = deserializeJson(doc, (char*) payload, length);
  if (err) {
    Serial.print(F("deserializeJson() failed: "))
    Serial.println(err.c_str())
  } else {
    TempPool = doc["Tmp"].as<float>() / 100.0;
    Serial.print(F("Temperature Piscine :")); Serial.print(TempPool);  Serial.print(F("°C"));

    display.clearDisplay();
    display.display();
    display.setTextSize(1.5);
    display.setTextColor(SSD1306_WHITE);
    display.setCursor(0, 20);
    display.print(F("Temperature Piscine: "));
    display.print(TempPool);
    display.println(F(" C"));
  }
}

void setup() {
  Serial.begin(115200);
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C); // Address 0x3C for 128x32
  WiFi.begin(WIFI_SSID, WIFI_PWD);

  Serial.println(F("Connexion  WiFi.."));
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.write('.');
  }
  Serial.println(F(" => Connecté au réseau WIFI"));

  client.setServer(mqtt_server, port);
  client.setCallback(callback);

  while (!client.connected()) {
    Serial.println(F("Connexion  MQTT..."));
    if (client.connect(F("ESP32Client")) {
    Serial.println(F("connecté !"));
    } else {
      Serial.print(F("failed with state "));
      Serial.print(client.state());
      delay(2000);
    }
  }

  client.subscribe(F("Home/Pool/Meas1"));
  delay(1000);

  // Clear the buffer.
  display.clearDisplay();
  display.display();
}

void loop() {
  client.loop();
}

la loop() ne fait qu'attendre le callback. c'est le callback qui se charge de faire l'affichage.
J'ai viré le buffer temporaire, on doit pouvoir utiliser directement le payload pour extraire l'info du JSON

N1co44 · July 27, 2022, 10:58am

Bonjour, merci pour votre aide.
Le code transmis avec simplement le payload fonctionne déjà, c'est dès qu'il est intégré à la station météo que la fonction n'est pas appelé. J'avais ajouté deux fois l'affichage pour voir le code déroulé.
pourquoi rajoutez-vous F ?
avec votre code, j'ai l'erreur suivante:

no matching function for call to 'PubSubClient::connect(const __FlashStringHelper*)'

J-M-L · July 27, 2022, 11:59am

quand on met F("un bout de texte") ça range le texte en mémoire flash donc on économise de la RAM.

Pour l'erreur il semblerait que ça ne fonctionne pas pour connect() donc remettre juste
if (client.connect("ESP32Client")) {
et idem pour le subscribe()

quel est votre arduino?

le but de ce nettoyage est d'avoir un bout de code le plus simple possible dans lequel vous pourrez ensuite rajouter vos éléments

quel est votre Arduino?

le code

#include <ArduinoJson.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

//Connexion Wifi !
const char* WIFI_SSID = "XXX";
const char* WIFI_PWD = "XXX";
const char* mqtt_server = "192.168.1.91";
const int port = 1883;
float TempPool;

Adafruit_SSD1306 display = Adafruit_SSD1306(128, 64, &Wire);

//MQTT
WiFiClient espClient;
PubSubClient client(espClient);

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print(F("Message arrived ["));  Serial.print(topic);  Serial.print(F("] "));
  Serial.write(payload, length);
  Serial.println();

  StaticJsonDocument <256> doc;
  DeserializationError err = deserializeJson(doc, (char*) payload, length);
  if (err) {
    Serial.print(F("deserializeJson() failed: "));
    Serial.println(err.c_str());
  } else {
    TempPool = doc["Tmp"].as<float>() / 100.0;
    Serial.print(F("Temperature Piscine :")); Serial.print(TempPool);  Serial.print(F("°C"));

    display.clearDisplay();
    display.display();
    display.setTextSize(1.5);
    display.setTextColor(SSD1306_WHITE);
    display.setCursor(0, 20);
    display.print(F("Temperature Piscine: "));
    display.print(TempPool);
    display.println(F(" C"));
  }
}

void setup() {
  Serial.begin(115200);
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C); // Address 0x3C for 128x32
  WiFi.begin(WIFI_SSID, WIFI_PWD);

  Serial.println(F("Connexion  WiFi.."));
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.write('.');
  }
  Serial.println(F(" => Connecté au réseau WIFI"));

  client.setServer(mqtt_server, port);
  client.setCallback(callback);

  while (!client.connected()) {
    Serial.println(F("Connexion  MQTT..."));
    if (client.connect("ESP32Client")) {
    Serial.println(F("connecté !"));
    } else {
      Serial.print(F("failed with state "));
      Serial.print(client.state());
      delay(2000);
    }
  }

  client.subscribe("Home/Pool/Meas1");
  delay(1000);

  // Clear the buffer.
  display.clearDisplay();
  display.display();
}

void loop() {
  client.loop();
}

N1co44 · July 27, 2022, 12:33pm

Merci, ça fonctionne dans le moniteur. Le message arrive bien.

J'ai la version 1.8.19

J-M-L · July 27, 2022, 12:49pm

OK

je suppose que vous avez un autre arduino qui exporte la T° de la piscine vers votre serveur MQTT ?

donc si vous rajoutez le code qui va récupérer les données de OpenWeatherMap c'est là que ça se complique

d'où viennent les bibliothèques suivantes ?

#include "OpenWeatherMapCurrent.h"
#include "OpenWeatherMapForecast.h"

quel est votre arduino?

N1co44 · July 27, 2022, 12:54pm

Oui j'ai un autre arduino qui envoie la température vers un broker (jeedom)
et c'est depuis celui-ci que je récupère la température pour afficher sur un oled

#include "OpenWeatherMapCurrent.h"
#include "OpenWeatherMapForecast.h"

Ce sont les bibliothèques pour récupérer les infos météo (prévisions, ect...)

Ma carte est un wemos.

J-M-L · July 27, 2022, 1:03pm

ces bibliothèques (si ce sont celles ci) ont été écrite pour un NodeMCU V2 ESP8266 (avec un ESP-12F). Il faudrait s'assurer de la compatibilité complète

lors de la requête il ya des traces dans le moniteur série. Que voyez vous ? (par exemple un "[HTTP] failed to connect to host" serait louche)

N1co44 · July 27, 2022, 1:08pm

Non la station météo fonctionne bien avec le wemos, quand j'intègre le code avec le payload elle fonctionne toujours mais le payload n'est pas appelé.

J-M-L · July 27, 2022, 1:12pm

vérifiez dans la loop que client.connected()) est toujours vrai

N1co44 · July 27, 2022, 5:20pm

Voici le code, ca ne fonctionne pas, le payload n'est pas executé

#include <Arduino.h>
#include <ESPWiFi.h>
#include <ESP8266WiFi.h>
#include <ESPHTTPClient.h>
#include <JsonListener.h> 
#include <time.h>                       // time() ctime()
#include <sys/time.h>                   // struct timeval
#include <coredecls.h>                  // settimeofday_cb()

#include "SSD1306Wire.h"
#include "OLEDDisplayUi.h"
#include "Wire.h"
#include "OpenWeatherMapCurrent.h"
#include "OpenWeatherMapForecast.h"
#include "WeatherStationFonts.h"
#include "WeatherStationImages.h"
#include "DHT.h"
#include <PubSubClient.h>
#include <ArduinoJson.h>



//Parametre Wifi:
const char* WIFI_SSID = "XXX";
const char* WIFI_PWD = "XXX";
const char* mqtt_server = "192.168.1.91";
const int port = 1883; 

//Variable Température Piscine
float TempPool;

#define TZ              2       // (utc+) TZ in hours
#define DST_MN          0      // use 60mn for summer time in some countries

//MQTT
WiFiClient espClient;
PubSubClient client(espClient);

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print(F("Message arrived ["));  Serial.print(topic);  Serial.print(F("] "));
  Serial.write(payload, length);
  Serial.println();

  StaticJsonDocument <256> doc;
  DeserializationError err = deserializeJson(doc, (char*) payload, length);
  if (err) {
    Serial.print(F("deserializeJson() failed: "));
    Serial.println(err.c_str());
  } else {
    TempPool = doc["Tmp"].as<float>() / 100.0;
    Serial.print(F("Temperature Piscine :")); Serial.print(TempPool);  Serial.print(F("°C"));

      }
}

// Setup
const int UPDATE_INTERVAL_SECS = 10 * 60; // Update every 30 minutes

// Display Settings
const int I2C_DISPLAY_ADDRESS = 0x3C;

const int SDA_PIN = D2;
const int SDC_PIN = D1;


String OPEN_WEATHER_MAP_APP_ID = "XXX";
String OPEN_WEATHER_MAP_LOCATION_ID = "XXX";

// Pick a language code from this list:
// Arabic - ar, Bulgarian - bg, Catalan - ca, Czech - cz, German - de, Greek - el,
// English - en, Persian (Farsi) - fa, Finnish - fi, French - fr, Galician - gl,
// Croatian - hr, Hungarian - hu, Italian - it, Japanese - ja, Korean - kr,
// Latvian - la, Lithuanian - lt, Macedonian - mk, Dutch - nl, Polish - pl,
// Portuguese - pt, Romanian - ro, Russian - ru, Swedish - se, Slovak - sk,
// Slovenian - sl, Spanish - es, Turkish - tr, Ukrainian - ua, Vietnamese - vi,
// Chinese Simplified - zh_cn, Chinese Traditional - zh_tw.
String OPEN_WEATHER_MAP_LANGUAGE = "fr";
const uint8_t MAX_FORECASTS = 4;

const boolean IS_METRIC = true;

// Adjust according to your language
const String WDAY_NAMES[] = {"DIM", "LUN", "MAR", "MER", "JEU", "VEN", "SAM"};
const String MONTH_NAMES[] = {"JAN", "FEV", "MAR", "AVR", "MAI", "JUI", "JUL", "AUT", "SEP", "OCT", "NOV", "DEC"};

/***************************
 * End Settings
 **************************/
 SSD1306Wire     display(I2C_DISPLAY_ADDRESS, SDA_PIN, SDC_PIN);
 OLEDDisplayUi   ui( &display );



OpenWeatherMapCurrentData currentWeather;
OpenWeatherMapCurrent currentWeatherClient;

OpenWeatherMapForecastData forecasts[MAX_FORECASTS];
OpenWeatherMapForecast forecastClient;

#define TZ_MN           ((TZ)*60)
#define TZ_SEC          ((TZ)*3600)
#define DST_SEC         ((DST_MN)*60)
time_t now;

// flag changed in the ticker function every 10 minutes
bool readyForWeatherUpdate = false;

String lastUpdate = "--";

long timeSinceLastWUpdate = 0;



//declaring prototypes
void drawProgress(OLEDDisplay *display, int percentage, String label);
void updateData(OLEDDisplay *display);
void drawDateTime(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawTemp(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawTempPool(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawHum(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawCurrentWeather(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawForecast(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawForecastDetails(OLEDDisplay *display, int x, int y, int dayIndex);
void drawHeaderOverlay(OLEDDisplay *display, OLEDDisplayUiState* state);
void setReadyForWeatherUpdate();

FrameCallback frames[] = { drawDateTime, drawCurrentWeather, drawForecast, drawTemp, drawHum, drawTempPool };
int numberOfFrames = 6;

OverlayCallback overlays[] = { drawHeaderOverlay };
int numberOfOverlays = 1;

DHT dht = DHT(D6, DHT22, 6);





void setup() {
  Serial.begin(115200);
 

  // initialize dispaly
  display.init();
  display.clear();
  display.display();

  display.setFont(ArialMT_Plain_10);
  display.setTextAlignment(TEXT_ALIGN_CENTER);
  display.setContrast(255);
//  display.flipScreenVertically();
  
//  display.begin(SSD1306_SWITCHCAPVCC, 0x3c); // Address 0x3C for 128x32
  dht.begin();
  WiFi.begin(WIFI_SSID, WIFI_PWD);

  
  int counter = 0;
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connexion Wifi...");
    display.clear();
    display.drawString(64, 10, "Connexion WiFi");
    display.drawXbm(46, 30, 8, 8, counter % 3 == 0 ? activeSymbole : inactiveSymbole);
    display.drawXbm(60, 30, 8, 8, counter % 3 == 1 ? activeSymbole : inactiveSymbole);
    display.drawXbm(74, 30, 8, 8, counter % 3 == 2 ? activeSymbole : inactiveSymbole);
    display.display();

    counter++;
  
  }
  Serial.println("Connecté au réseau WIFI");
  delay(2000);
//*******************
  
//****************Connexion MQTT**********************
  client.setServer(mqtt_server, port);
  client.setCallback(callback);
  
  Serial.println("Connexion  MQTT...");
  delay(2000);
  
  while (!client.connected()) {
    Serial.println("Connexion  MQTT...");
    delay(2000);
    if (client.connect("ESP32Client")) {

      Serial.println("connecté !");  

    } else {

      Serial.print("failed with state ");
      Serial.print(client.state());
      delay(2000);

    }
  }
  
  client.subscribe("Home/Pool/Meas1");
  Serial.println("Home/Pool/Meas1");
  delay(1000);
/*
delay(2000);
Serial.print("Temperature Piscine :");
Serial.print(TempPool);
Serial.print("°C");
delay(2000);
*/

//************************************
 
  // Get time from network time service
  configTime(TZ_SEC, DST_SEC, "pool.ntp.org");

  ui.setTargetFPS(30);

  ui.setActiveSymbol(activeSymbole);
  ui.setInactiveSymbol(inactiveSymbole);

  // You can change this to
  // TOP, LEFT, BOTTOM, RIGHT
  ui.setIndicatorPosition(BOTTOM);

  // Defines where the first frame is located in the bar.
  ui.setIndicatorDirection(LEFT_RIGHT);

  // You can change the transition that is used
  // SLIDE_LEFT, SLIDE_RIGHT, SLIDE_TOP, SLIDE_DOWN
  ui.setFrameAnimation(SLIDE_LEFT);

  ui.setFrames(frames, numberOfFrames);

  ui.setOverlays(overlays, numberOfOverlays);

  // Inital UI takes care of initalising the display too.
  ui.init();

  Serial.println("Démarrage Ecran");
 delay(6000);

 
  updateData(&display);
 
  
  display.clear();
  display.setTextAlignment(TEXT_ALIGN_LEFT);
  display.setFont(ArialMT_Plain_10);
  display.drawString(0,0,"Chargement...");
  display.display();  
  delay(4000);
  display.drawString(0,10,"Heure et Date");
  display.display();  
  delay(4000);
  display.drawString(0,20,"Température Pièce");
  display.display();  
  delay(4000);
  display.drawString(0,30,"Humidité");
  display.display();  
  delay(4000);
  display.drawString(0,40,"Prévision Météo Puceul");
  display.display();  
  delay(4000);
  display.drawString(0,50,"Température Piscine");
  display.display();  
  delay(3000);
  Serial.print("Enumération");
  delay(3000);


 
  
}


//*************************************************************


void loop() {

client.loop();


    
  if (millis() - timeSinceLastWUpdate > (1000L*UPDATE_INTERVAL_SECS)) {
    setReadyForWeatherUpdate();
    timeSinceLastWUpdate = millis();
  }

  if (readyForWeatherUpdate && ui.getUiState()->frameState == FIXED) {
    updateData(&display);
  }

  int remainingTimeBudget = ui.update();

  if (remainingTimeBudget > 0) {
    // You can do some work here
    // Don't do stuff if you are below your
    // time budget.
    delay(remainingTimeBudget);
  }


  
}


  
void drawProgress(OLEDDisplay *display, int percentage, String label) {
  display->clear();
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  display->drawString(64, 10, label);
  display->drawProgressBar(2, 28, 124, 10, percentage);
  display->display();
}

void updateData(OLEDDisplay *display) {
  drawProgress(display, 10, "Mise à jour Heure...");
  drawProgress(display, 30, "Mise à jour Météo...");
  currentWeatherClient.setMetric(IS_METRIC);
  currentWeatherClient.setLanguage(OPEN_WEATHER_MAP_LANGUAGE);
  currentWeatherClient.updateCurrentById(&currentWeather, OPEN_WEATHER_MAP_APP_ID, OPEN_WEATHER_MAP_LOCATION_ID);
  drawProgress(display, 50, "Mise à jour des prévisions...");
  forecastClient.setMetric(IS_METRIC);
  forecastClient.setLanguage(OPEN_WEATHER_MAP_LANGUAGE);
  uint8_t allowedHours[] = {12};
  forecastClient.setAllowedHours(allowedHours, sizeof(allowedHours));
  forecastClient.updateForecastsById(forecasts, OPEN_WEATHER_MAP_APP_ID, OPEN_WEATHER_MAP_LOCATION_ID, MAX_FORECASTS);

  readyForWeatherUpdate = false;
  drawProgress(display, 100, "FIN...");
  Serial.print("FIN...");
  delay(1000);
}

 
void drawDateTime(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  now = time(nullptr);
  struct tm* timeInfo;
  timeInfo = localtime(&now);
  char buff[16];


  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  String date = WDAY_NAMES[timeInfo->tm_wday];

  sprintf_P(buff, PSTR("%s, %02d/%02d/%04d"), WDAY_NAMES[timeInfo->tm_wday].c_str(), timeInfo->tm_mday, timeInfo->tm_mon+1, timeInfo->tm_year + 1900);
  display->drawString(64 + x, 5 + y, String(buff));
  display->setFont(ArialMT_Plain_24);

  sprintf_P(buff, PSTR("%02d:%02d:%02d"), timeInfo->tm_hour, timeInfo->tm_min, timeInfo->tm_sec);
  display->drawString(64 + x, 15 + y, String(buff));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawTemp(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {

  float temperature = dht.readTemperature()/1.216;
  
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  
  display->drawString(64 + x, 5 + y, "Température Pièce");
  display->setFont(ArialMT_Plain_24);

  display->drawString(64 + x, 15 + y, String(temperature,1)+("°C"));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawHum(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {

  int humidity = dht.readHumidity();
  
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  
  display->drawString(64 + x, 5 + y, "Humidité");
  display->setFont(ArialMT_Plain_24);

  display->drawString(64 + x, 15 + y, String(humidity)+(" %"));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawTempPool(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  //int TempPool;
  //float temperaturePool =  TemperaturePiscine;
  //float temperaturePool = dht.readTemperature();
  //int temperaturePool = TempPool;
  
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  
  display->drawString(64 + x, 5 + y, "Température Piscine");
  display->setFont(ArialMT_Plain_24);

  display->drawString(64 + x, 15 + y, String(TempPool,1)+("°C"));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawCurrentWeather(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  display->setFont(ArialMT_Plain_10);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->drawString(64 + x, 38 + y, currentWeather.description);

  display->setFont(ArialMT_Plain_24);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
  String temp = String(currentWeather.temp, 1) + (IS_METRIC ? "°C" : "°F");
  display->drawString(51 + x, 5 + y, temp);

  display->setFont(Meteocons_Plain_36);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->drawString(23  + x, 0 + y, currentWeather.iconMeteoCon);
}


void drawForecast(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  drawForecastDetails(display, x, y, 0);
  drawForecastDetails(display, x + 44, y, 1);
  drawForecastDetails(display, x + 88, y, 2);
}

void drawForecastDetails(OLEDDisplay *display, int x, int y, int dayIndex) {
  time_t observationTimestamp = forecasts[dayIndex].observationTime;
  struct tm* timeInfo;
  timeInfo = localtime(&observationTimestamp);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  display->drawString(x + 20, y, WDAY_NAMES[timeInfo->tm_wday]);

  display->setFont(Meteocons_Plain_21);
  display->drawString(x + 20, y + 12, forecasts[dayIndex].iconMeteoCon);
  String temp = String(forecasts[dayIndex].temp, 0) + (IS_METRIC ? "°C" : "°F");
  display->setFont(ArialMT_Plain_10);
  display->drawString(x + 20, y + 34, temp);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawHeaderOverlay(OLEDDisplay *display, OLEDDisplayUiState* state) {
  now = time(nullptr);
  struct tm* timeInfo;
  timeInfo = localtime(&now);
  char buff[14];
  sprintf_P(buff, PSTR("%02d:%02d"), timeInfo->tm_hour, timeInfo->tm_min);

  display->setColor(WHITE);
  display->setFont(ArialMT_Plain_10);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
  display->drawString(0, 54, String(buff));
  display->setTextAlignment(TEXT_ALIGN_RIGHT);
  String temp = String(currentWeather.temp, 1) + (IS_METRIC ? "°C" : "°F");
  display->drawString(128, 54, temp);
  display->drawHorizontalLine(0, 52, 128);
}

void setReadyForWeatherUpdate() {
  Serial.println("Setting readyForUpdate to true");
  readyForWeatherUpdate = true;
}

J-M-L · July 27, 2022, 9:18pm

comme dit précédemment, vérifiez que le client est toujours connecté avant d'appeler client.loop();

N1co44 · July 28, 2022, 4:44pm

dans le client.loop(); j'ai rajouté:
if (!client.connected()) {
Serial.println();
Serial.println("le client est connecté");
}

dans le moniteur série, le client est bien connecté, je ne vois jamais le payload.

J-M-L · July 28, 2022, 4:49pm

ce test

veut dire ... si le client n'est pas connecté...

void loop() {
  if (!client.connected()) {
    Serial.println("perte de connection");
    while (true) yield(); // on ne continue pas plus loin (en pratique il faut rétablir la connexion)
  } else  client.loop();
...

N1co44 · July 28, 2022, 5:12pm

ça fonctionne ! je rétablie la connexion à cet endroit. Merci beaucoup pour votre aide et réactivité !

Pour comprendre, avez-vous idée sur le fait qu'il perde la connexion ?

Topic		Replies	Views
Recupérer données reçues en json sur esp8266 Français	41	451	September 14, 2025
Json Parsing Issue Programming	19	157	November 22, 2025
Configuration de Putty pour un monitoring à distance Français	33	183	November 28, 2025
ESP32 E-Paper 2.9" Display MQTT Daten von ESP01 (Tasmota) anzeigen Deutsch	55	1242	December 13, 2024
Récupération des couleurs Tempo EDF avec un ESP32 Tutoriels et cours	251	13799	February 12, 2026

Station météo connecté + MQTT

Related topics