I have a DHT22 temperature humidity sensor hooked to a breadboard.
I don't have a camera however the positive 5 volts is connected to the far left pin, the output is through connected to Analog A2 and a 10kohm resistor is between the same pin on the sensor and 5V.
The negative is connected to gnd.
the code I am trying to use is as follows:
int counter =0;
int pin =13;
int temperature =A2;
void setup() {
Serial.begin(9600);
pinMode(pin, OUTPUT);
pinMode (temperature, INPUT);
digitalWrite(pin, LOW);
}
My problem is that no matter what the temperature in the room is, the printout on the screen reads
Temperature 16 Blink #268
The blink increments okay. The temperature reading is definitely not working.
If I change the pin number in the program to A1 the temperature will change to 15, if I change it to A3 the temperature will change to 17. The number seems to depend on which pin I call out in the program and not on what the input on that pin is.
I don't have a camera handy to take a photo of the breadboard.
Thanks for any assistance you may provide.
Ken
Thank you. That gave me a hint as to where I need to go to find my solution.
I have a book on programming Arduino in 24 hours but it doesn't cover this problem as such. I think I can get closer to my solution now.
Thanks again.
Ken
I have downloaded the sensor library from Adafruit several times and when I try to use it I always get a message that the DHT.h or one of the sensor files is not there. Theyu say there is no such file. I go there and look at the files and they are listed.
I added them through the Adafruit sketch File Manager.
I am going to look up some more tonight in my book on Arduino programming.
Right now I am getting
temperature 1023 Blink99 (or whichever blink it is.)
The number for the temperature still doesn't change so I will need to find a way to get the libraries recognized.
I am considering removing the IDE and starting all over again, but that will have to wait until tomorrow as it is beginning to be too late here for today.
I noticed that now I am getting readings around 360-400 on the temperature and they seem to be varying. It doesn't seem to matter which pins I use as long as they are A1-A4. (I didn't try A5).
Are these numbers related to the temperature in the room (around 77Degrees F) or are they just random?
The connections are the same except I move the wire around from A1-A2)
Thanks for any information.
Ken
you don't use a dht sensor like that. Its a digital not analogue so there should be some code in the example pack that you got when you downloaded the dht.h
if (temp_timer >=1){
h = dht.readHumidity();
// Read temperature as Celsius
t = dht.readTemperature();
// Read temperature as Fahrenheit
f = dht.readTemperature(true);
humidity = h;
temp =f;
temp_timer =0;}
//failed to read sensor alarm
if (isnan(h) || isnan(t) || isnan(f)) {
alarm_active=7;
}
ignore the extra code I just copied from my sketch (sensor needs to be disabled for 1 sec on boot or it could throw out a number that's not correct and its a slow sensor so you don't want to call it every scan)
// Example testing sketch for various DHT humidity/temperature sensors
// Written by ladyada, public domain
#include "DHT.h"
#define DHTPIN 9 // what pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302)
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor for normal 16mhz Arduino
DHT dht(DHTPIN, DHTTYPE);
// NOTE: For working with a faster chip, like an Arduino Due or Teensy, you
// might need to increase the threshold for cycle counts considered a 1 or 0.
// You can do this by passing a 3rd parameter for this threshold. It's a bit
// of fiddling to find the right value, but in general the faster the CPU the
// higher the value. The default for a 16mhz AVR is a value of 6. For an
// Arduino Due that runs at 84mhz a value of 30 works.
// Example to initialize DHT sensor for Arduino Due:
//DHT dht(DHTPIN, DHTTYPE, 30);
void setup() {
Serial.begin(9600);
Serial.println("DHTxx test!");
dht.begin();
}
void loop() {
// Wait a few seconds between measurements.
delay(2000);
// Reading temperature or humidity takes about 250 milliseconds!
// Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
float h = dht.readHumidity();
// Read temperature as Celsius
float t = dht.readTemperature();
// Read temperature as Fahrenheit
float f = dht.readTemperature(true);
// Check if any reads failed and exit early (to try again).
if (isnan(h) || isnan(t) || isnan(f)) {
Serial.println("Failed to read from DHT sensor!");
return;
}
// Compute heat index
// Must send in temp in Fahrenheit!
float hi = dht.computeHeatIndex(f, h);
Serial.print("Humidity: ");
Serial.print(h);
Serial.print(" %\t");
Serial.print("Temperature: ");
Serial.print(t);
Serial.print(" *C ");
Serial.print(f);
Serial.print(" *F\t");
Serial.print("Heat index: ");
Serial.print(hi);
Serial.println(" *F");
}
That seemed to work. It is 32degrees C in here. No wonder I am sweating a lot. I am in the Philippines with only a fan going so that may be pretty close to right.
Thanks. I am going to have to study that code to see what I was doing wrong.
Ken