The Software Servo Library issues with example code provided

Projects Programming
1

The Software Servo Library

Hi guys,

I'm very glad that I've entered Arduino world. I hope you can help me with my issue.

I'm trying the SerialServo.pde example from SoftwareServo.zip downloaded form The Software Servo page [1], I believe the software waits for user to chose between two servos by sending "A" or "B" by serial monitor interface then it waits user to enter the angle by sending a number between 0-9.

The example code seems to stuck in any "switch case loop" it enter and never continue. I've added some debug code and found that when I send "A" or "B" it does not accept any input after it. With my modified code I can only control both of the servos together.

Do the example code have any problems, Or what? I provided the original example and my modification for debugging.

http://playground.arduino.cc/ComponentLib/servo

// Example Code
#include <SoftwareServo.h>

SoftwareServo servo1;
SoftwareServo servo2;

void setup()
{
  pinMode(13,OUTPUT);
  servo1.attach(2);
  servo1.setMaximumPulse(2200);
  servo2.attach(4);
  servo2.setMaximumPulse(2200);
  Serial.begin(9600);
  Serial.print("Ready");
}

void loop()
{
  static int value = 0;
  static char CurrentServo = 0;

  if ( Serial.available()) {
    char ch = Serial.read();
    switch(ch) {
      case 'A':
        servo1.attach(2);
        CurrentServo='A';
        digitalWrite(13,LOW);
        break;
      case 'B':
        servo2.attach(4);
        CurrentServo='B';
        digitalWrite(13,HIGH);
        break;
      case '0' ... '9':
        value=(ch-'0')*20;
        if (CurrentServo=='A')
        {
          servo1.write(value);
        }
        else if (CurrentServo=='B')
        {
          servo2.write(value);
        }
        break;
    }
  }
  SoftwareServo::refresh();
}

I've modified the code to help me debug the issue and it's like this.

//Modified for debugging

#include <SoftwareServo.h>

SoftwareServo servo1;
SoftwareServo servo2;

void setup()
{
  pinMode(13,OUTPUT);
  servo1.attach(2);
  servo1.setMaximumPulse(2200);
  servo2.attach(4);
  servo2.setMaximumPulse(2200);
  Serial.begin(9600);
  Serial.print("Ready");
}

void loop()
{
  static int value = 0;
  static char CurrentServo = 0;

  if ( Serial.available()) {
    char ch = Serial.read();
    switch(ch) {
      case 'A':
        servo1.attach(2);
        Serial.println(ch);
        CurrentServo='A';
        digitalWrite(13,LOW);
        break;
      case 'B':
        servo2.attach(4);
        CurrentServo='B';
        Serial.println(ch);
        digitalWrite(13,HIGH);
        break;
      case '0' ... '9':
        value=(ch-'0')*20;
        Serial.print(CurrentServo);
        servo1.write(value);
        servo2.write(value);
        Serial.println(value);
        break;
    }
  }
  SoftwareServo::refresh();
}
2

OK, the flaw escapes me, too.

When you say "refuses to accept any more input", are you saying that your debug version shows that you never enter the case'0'..'9' ? Or that the servos never move? If you enter ABA do you get ABA return?

I am not familiar with the SoftwareServo library, so I am assuming it behaves the same way as the hardware servo library. Have you tried the "normal" servo library?

3

Sorry I wrote "escapes" it actually stuck in the "switch case loop"

Msquare:
OK, the flaw escapes me, too.

When you say "refuses to accept any more input", are you saying that your debug version shows that you never enter the case'0'..'9' ? Or that the servos never move? If you enter ABA do you get ABA return?

debug version shows that it enter the case'0'..'9' and servos move but only if I did not press A or B. when I enter A or B it does not accept any thing afterward.

I am not familiar with the SoftwareServo library, so I am assuming it behaves the same way as the hardware servo library. Have you tried the "normal" servo library?

Thank you for trying to help. I don't think it's related to the library. anyway other codes works for moving servos but this one allow me (if it did work) to chose which one to run between the two servos.

4

I believe the software waits for user to chose between two servos by sending "A" or "B" by serial monitor interface

It doesn't wait. It just does nothing until that happens.

then it waits user to enter the angle by sending a number between 0-9.

No. It doesn't wait. If you enter A108, the A servo will move to 1, then 10, then 108.

Not an intelligent design, since there is no way to reset the value. If you enter A108 followed by B90, the B servo will jump to position 1089 when the 9 is read.

Also, attaching the servo every time an A or B is received is not necessary.

I've modified the code to help me debug the issue and it's like this.

Why are you now moving both servos to the same position?

Why are you using SoftwareServo?

Shitcan that awful code. Write some code to receive something like "" or "". This code can receive the information:

#define SOP '<'
#define EOP '>'

bool started = false;
bool ended = false;

char inData[80];
byte index;

void setup()
{
   Serial.begin(57600);
   // Other stuff...
}

void loop()
{
  // Read all serial data available, as fast as possible
  while(Serial.available() > 0)
  {
    char inChar = Serial.read();
    if(inChar == SOP)
    {
       index = 0;
       inData[index] = '\0';
       started = true;
       ended = false;
    }
    else if(inChar == EOP)
    {
       ended = true;
       break;
    }
    else
    {
      if(index < 79)
      {
        inData[index] = inChar;
        index++;
        inData[index] = '\0';
      }
    }
  }

  // We are here either because all pending serial
  // data has been read OR because an end of
  // packet marker arrived. Which is it?
  if(started && ended)
  {
    // The end of packet marker arrived. Process the packet

    // Reset for the next packet
    started = false;
    ended = false;
    index = 0;
    inData[index] = '\0';
  }
}

Where it says Process the packet, write some code to copy the first letter in inData, change that first letter to a space, and call atoi() on the rest of it. Move the appropriate servo, based on the copied first letter.

5

PaulS:

I believe the software waits for user to chose between two servos by sending "A" or "B" by serial monitor interface

It doesn't wait. It just does nothing until that happens.

Thank you for your clarification. I'm a newbie.

Why are you now moving both servos to the same position?

I'm moving the two servos together just to make sure the problem is not in my wiring or servos.

Why are you using SoftwareServo?

Because it's in top 5 of Google search results & I didn't notice any warning in red similar to other deprecated libraries

Now I got the code to work using the Servo library. but with the flaws you talked about:
It accept input in these form: A1 or A (send) 1.

#include <Servo.h>

Servo servo1;
Servo servo2;

void setup()
{
  pinMode(13,OUTPUT);
  servo1.attach(2);
  servo2.attach(4);
  Serial.begin(9600);
  Serial.print("Ready");
}

void loop()
{
  static int value = 0;
  static char CurrentServo = 0;
  
  if ( Serial.available()) {
    char ch = Serial.read();
    switch(ch) {
    case 'A':
      servo1.attach(2);
      Serial.println("Print channel first case:");
      Serial.println(ch);
      CurrentServo='A';
      digitalWrite(13,LOW);
      Serial.println("About to leave first loop");
      break;

    case 'B':
      servo2.attach(4);
      CurrentServo='B';
      Serial.println("Print channel second case:");
      Serial.println(ch);
      digitalWrite(13,HIGH);
      Serial.println("About to leave second loop");
      break;
      Serial.println("after break case B");
      
    case '0' ... '9':
      value=(ch-'0')*20;
      Serial.println("print current servo");
      Serial.println(CurrentServo);
      Serial.println("print current value");
      Serial.println(value);
      if (CurrentServo=='A')
      {
        servo1.write(value);
        Serial.println("command sent to servo A");
      }
      else if (CurrentServo=='B')
      {
        servo2.write(value);
        Serial.println("command sent to servo B");
      }
      break;
   }
  }
}