The Sticky Harray, stuck on sizeof two forever - help

Projects Programming
1

Crazy stuff... just taking on array programming and much like anything else programming I do, nothin'werks loll

What am I doing wrong (again); I(we) don't know the size of the rows but do know its a 4 col array. Why this keeps telling me I have a size of 2 (two) despite having 3 rows? I was sure I've read the rows can be omitted.

Troubleshooting I've done: 1) doing it again, restarting the IDE, the computer, went for walk, dbl-ed up coffee.... nothing'werks

char* myArray[][4] = { 
                      {"A","B","C","D"},
                      {"1","2","3","4"},
                      {"O","O","P","S"},
                      };
                      
void getCharArray(char* myArray[][4]){
  //Serial.println(sizeof(myArray)); // =2 ?!?!
  //Serial.println(sizeof(*myArray)); // =8
  //Serial.println(sizeof(*myArray)/sizeof(myArray)); // =4
  
  Serial.println(sizeof(myArray));
  for(int i = 0; i<sizeof(myArray); i++)
  {
    Serial.print("Record " + String(i) +": ");
    for(int ii = 0; ii<4; ii++){
      Serial.print(myArray[i][ii]); Serial.print(",");
    }
    Serial.println(" ");
  }
  Serial.println(" ");
};


void setup() {
  Serial.begin(9600);
}

void loop() {
  getCharArray(myArray);
  delay(1000);
  //whatever(1,000,000);
}
2

char* myArray size of a pointer is always going to be two.
(On an eight bit Arduino)

3

Yup, very true :confused: Removing those lil assterix trows out a grand collection of exceptions, so...

sketch_jul13a:6:23: error: too many initializers for 'char [4]'
exit status 1
too many initializers for 'char [4]'

nut sure where to take this. Any half-decent tutorials on array for beginner? from the look of it the one I've picked nearly got me to quit and outsource to fivver LOL

4 
void setup() {
  Serial.begin(9600);
  Serial.println (sizeof myArray);
}

Any help?

5

Seriously?!

const char *myArray[][4] = { 
                      {"A","B","C","D"},
                      {"1","2","3","4"},
                      {"A","W","O","L"},
                      {"R","O","C","K"},
                      };
                      
void getCharArray(int row, const char *myArray[][4]){
  for(int i = 0; i<row/sizeof(*myArray); i++)
  {
    Serial.print("Record " + String(i) +": ");
    for(int ii = 0; ii<4; ii++){
      Serial.print(myArray[i][ii]); Serial.print(",");
    }
    Serial.println(" ");
  }
  Serial.println(" ");
};

void setup() {
  Serial.begin(9600);
}

void loop() {
  getCharArray(sizeof myArray, myArray);
  delay(1000);
}
6

Seriously what?

7

Seriously? as in, that's all that was needed to get this to work??...

Spent a few more hours than I could afford-to-spend on this array training. And from the look it seems I'm not even near the end of learning more about arrays ;/

ps: left you a grateful subliminal note in the myArray[][4]. See above! Thx AWOL

8

The thing to remember is, if you pass it into a function, it stops being an array and just becomes a pointer.

9

Gotcha. Thanks for the heads up.

man oh man, took my Friday to learn new tricks hoping to get some endless loops from previous code squeezed down in size (and IO). Kinda in sorting-out-old-programs time! So far so good, just long hours learning that's all. Sorry for the panic attack :wink:

10

GTC:
Yup, very true :confused: Removing those lil assterix trows out a grand collection of exceptions, so...

sketch_jul13a:6:23: error: too many initializers for 'char [4]'
exit status 1
too many initializers for 'char [4]'

nut sure where to take this. Any half-decent tutorials on array for beginner? from the look of it the one I've picked nearly got me to quit and outsource to fivver LOL

That particular error is caused by enclosing the characters in double quotes instead of single quotes. The correct form would be:

char myArray[][4] = { 
                      {'A','B','C','D'},
                      {'1','2','3','4'},
                      {'O','O','P','S'},
                      };
11

david_2018:
That particular error is caused by enclosing the characters in double quotes instead of single quotes.

Oh :confused: Good catch David, thanks for letting me know, didn't know. Due to spending too much time dev'ing with C# I'm starting to assume everyone else uses the same syntax. Need to revisit the good old school printf() days I guess.

Thanks again guys, awesome help and generosity.

12

Here is a slightly more generic example. It gives warnings about the initializers being too long (because there is no room for the null terminator) but should work for 2D arrays with up to 255 rows or columns.

const char myArray[][4] =
{
  "ABCD",
  "1234",
  "AWOL",
  "ROCK"
};

const byte MyArrayRows = sizeof myArray / sizeof myArray[0];
const byte MyArrayColumns = sizeof myArray[0] / sizeof myArray[0][0];

void getCharArray(byte rows, byte columns, const char *myArray)
{
  for (byte row = 0; row < rows; row++)
  {
    Serial.print("Record ");
    Serial.print(row);
    Serial.print(": ");
    for (byte col = 0; col < columns; col++)
    {
      Serial.print(myArray[row*columns+col]);
      Serial.print(",");
    }
    Serial.println(" ");
  }
  Serial.println(" ");
};

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  getCharArray(MyArrayRows, MyArrayColumns, &myArray[0][0]);
  delay(1000);
}