Timer problem when working with web server

Projects Programming
1

Hi,

I am developing a project for automatic watering system for my garden. I'm using an Arduino Yun and some relay shields.The garden is divided into 6 sprinklers zones, that can run individually.

I wrote a webpage from where I can control all my sprinklers from my smartphone/tablet. For each zone I added 3 buttons on my website: ON - OFF - TIMER. The ON & OFF functions are working perfectly, but I'm having problems with my TIMER. The idea is when you click the TIMER button, the sprinkler will run for a programmed time and then shuts off again.

A part of my sketch looks like this:

void loop() {
YunClient client=server.accept();
if(client){
String command = client.readString();
command.trim();
Console.println(command);

if(command == "z1on"){
z1on();
}
else if(command == "z1off"){
z1off();
}
else if(command == "z1timer"){
z1timer();
}
....

The function z1timer() looks like this:

void z1timer(){
digitalWrite(9,LOW);
delay(5000);
digitalWrite(9,HIGH);
}

And here is the problem: when the function is running the project is paused and waits for the delay to finish. So I can't use 2 zones at the same time, the first has to finish before the next is working. I know this is caused by the delay(), but I tried to fix it with a mills() solution. This also doesn't work because the command from the webpage is issued only once when clicking so it won't run continuously in the loop section.

Sorry for the long explanation, if you made it this far THX!
Anyone has a solution ?

2

You must pull the delay out of the z1timer function. It should turn on the valve, set the timer's current millis setting, and set a timer flag.

boolean z1timerFlag = false;
unsigned long z1timerMillis;
unsigned long z1Delay = 5000ul;

void loop() {
  // if the z1 timer is running, check it
  if(z1timerFlag) z1timerCheck();

  // rest of your loop stuff
}

void z1timer() {
  // turn on the valve
  digitalWrite(9,LOW);
  // get the time in millis
  z1timerMillis = millis();
  // set the timer flag
  z1timerFlag = true;
}

void z1timerCheck() {
  // if the time has elapsed...
  if(millis() - z1timerMillis > z1Delay) {
    // turn off the valve
    digitalWrite(9,HIGH);
    // clear the timer flag
    z1timerFlag = false;
  }
}

I haven't checked this for accuracy, but you should get the idea.

3

Hi SurferTim,

I tried your solution this morning and it works fine!
THX :slight_smile: