u8g2 wake from power save on first button press

I have a nice little OLED running u8g2.

When the display is on, each press of a button cycles through display modes (switch case).

The display enters power save after 30 seconds. A button press wakes the display but also changes the case.

I would rather it didn't change case. Can I test for whether the display is in power save? Or some other way?

void draw(void) {
  switch (draw_state) {
    case 0: showParsedData(); break;
    case 1: showBatteryVoltage(); break;
  }
}

//============

void setup() {
  Serial.begin(9600);
  u8g2.begin();
  BTSerial.begin(38400);
  debouncer.attach(modeButtonPin, INPUT_PULLUP);
  debouncer.interval(50);
}

//============

void loop() {
  u8g2.firstPage();
  do {
    draw();
  } while ( u8g2.nextPage() );

  debouncer.update(); // Update the Bounce instance
  if ( debouncer.fell() ) {  // Call code if button transitions from HIGH to LOW
    u8g2.setPowerSave(0);
    draw_state++;
    displaySleepTimer = millis();
    if ( draw_state >= 2 )
      draw_state = 0;
  }

  if ((millis() - displaySleepTimer) > displaySleepDelay) {
    u8g2.setPowerSave(1);
  }

}

Just set a boolean flag when changing the powersave mode.

  static bool powerSave = false;
  ...
  debouncer.update(); // Update the Bounce instance
  if ( debouncer.fell() ) {  // Call code if button transitions from HIGH to LOW
    if (powerSave == true) {
      powerSave = false;
      u8g2.setPowerSave(powerSave);
    } else {
      draw_state++;
    }
    displaySleepTimer = millis();
    if ( draw_state >= 2 )
      draw_state = 0;
  }

  if ((millis() - displaySleepTimer) > displaySleepDelay) {
    powerSave = true;
    u8g2.setPowerSave(powerSave);
  }

Thank you! So simple, brilliant.