un sensor y activación 2 reles

International Español Software
13

Yo no te pido nada que no lo exijan las normas.
Si pones 3 lineas y supones que por ahi esta el problema nosotros no tenemos porque entender o proyectar cual es el posible resultado que persigues.

Ahora comprendo mejor todo!!. Por qué abres un tema con cada nueva duda que tienes en lugar de seguir con el mismo hilo una y otra vez hasta terminarlo?
Veo que vienes de este hilo ¿Como temporizar la salida 2 del esp8266-01? - Software - Arduino Forum donde dices ahora le agrego los reles.. y justamente estamos en el hilo donde le agregas el relé y te estancas una vez mas. Entonces el anterior no estaba solucionado y para nosotros ese hilo sumado a este tiene mas continuidad y tu post anterior tendría un mejor contexto.
Para mi este hilo estaba descontextualizado hasta leer tu hilo anterior.
Se comprende?
Voy a unir los hilos para que mejore la comprensión del tema.

Entonces veamos qué ocurre y porqué te estancas a cada paso, mas alla que lo que encaras no es fácil cuando tienes muchas dudas.

Yo he vuelto al msg original ESP8266WIFI y modifiqué levemente el tuyo

//SERVIDOR
#include <ESP8266WiFi.h>

const char WiFiClave[] = "";  //Sin clave
const char AP_Nombre[] = "ESP8266";

WiFiServer server(80);

const int releAbajo = 0;
const int releArriba = 2;
String req;
enum {Indeterminado, Arriba, Abajo} estadoPersiana=Indeterminado;


void setup(void) {

  pinMode(releAbajo, OUTPUT);
  digitalWrite ( releAbajo, HIGH );

  pinMode(releArriba,OUTPUT);
  digitalWrite ( releArriba, HIGH );

  Serial.begin(115200);
  delay(10);

  Serial.println();
  Serial.println();
  Serial.print("Conectando a...");
  Serial.println();
  Serial.println(AP_Nombre); 

 
  WiFi.softAP(AP_Nombre, WiFiClave);  
  IPAddress myIP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(myIP);
  server.begin();
  Serial.println("HTTP server started");
}

void loop( void ) {

  int estado_releAbajo = digitalRead(releAbajo);

  WiFiClient client = server.available();   // ¿Hay un cliente conectado?
  if (!client) { 
      return;
  }
  else {
      Serial.println("Nuevo Cliente");
     
      String req = client.readStringUntil('\r');  // Lee la primera linea de la petición del cliente
      Serial.println(req);
     
      if (req.indexOf("/gpio/0") != -1){ 
        if (estadoPersiana!=Abajo) {
            Serial.println("Procesando Persiana Abajo");       
            digitalWrite(releAbajo,HIGH );
            delay(5000);
            digitalWrite(releAbajo,LOW);
            estadoPersiana=Abajo;
        } 
      }
      else if (req.indexOf("/gpio/1") != -1) {
        if (estadoPersiana!=Arriba) {
          Serial.println("Procesando Persiana Arriba");       
          digitalWrite(releArriba,HIGH);
          delay(5000);
          digitalWrite(releArriba,LOW );
          estadoPersiana=Arriba;
        }   
      }
      
      client.flush();
      delay(1);
      client.stop();
      Serial.println("Client disconnected.");
 }
}

Y obtuve esto

Conectando a...
ESP8266
AP IP address: 192.168.4.1
HTTP server started
Nuevo Cliente
GET /gpio/0 HTTP/1.1 <=== ENVIO http://192.168.4.1/gpio/0
Procesando Persiana Abajo
Client disconnected.
Nuevo Cliente
GET /gpio/1 HTTP/1.1 <=== ENVIO http://192.168.4.1/gpio/1
Procesando Persiana Arriba
Client disconnected.
Nuevo Cliente