Unire due sketch

Salve a tutti volevo unire questi due codici in modo da poter misurare la temperatura interna e l’umidità con il dht11 e nello strsso tempo anche la temperatura esterna con la sonda ds18b20.
Il codice non l’ho scritto io essendo alle primissime armi con la programmazione ma vorrei attuare questo progetto.
Grazie.

#include <DHT11.h>
int pin=4;
DHT11 dht11(pin); 
void setup()
{
   Serial.begin(9600);
  while (!Serial) {
      ; // wait for serial port to connect. Needed for Leonardo only
    }
}

void loop()
{
  int err;
  float temp, humi;
  if((err=dht11.read(humi, temp))==0)
  {
    Serial.print("temperature:");
    Serial.print(temp);
    Serial.print(" humidity:");
    Serial.print(humi);
    Serial.println();
  }
  else
  {
    Serial.println();
    Serial.print("Error No :");
    Serial.print(err);
    Serial.println();    
  }
  delay(DHT11_RETRY_DELAY); //delay for reread
}
#include <OneWire.h>

OneWire  ds(10);  // on pin 10 (a 4.7K resistor is necessary)

void setup(void) {
  Serial.begin(9600);
}

void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;
  
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }
  
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
 
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, with parasite power on at the end
  
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
  
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}
// DHT 
#include <DHT11.h>
int pin=4;
DHT11 dht11(pin); 
int err;
float temp, humi;

  
// DS - ONEWIRE
#include <OneWire.h>
OneWire  ds(10);  // on pin 10 (a 4.7K resistor is necessary)
byte i;
byte present = 0;
byte type_s;
byte data[12];
byte addr[8];
float celsius, fahrenheit;


void setup()
{
   Serial.begin(9600);
   while(!Serial); // wait for serial port to connect. Needed for Leonardo only
}

void loop()
{
  readDHT();
  readDS();
  delay(2000); //aspetto un secondo tra una serie di letture ed un altra
}



void readDHT(){
  if((err=dht11.read(humi, temp))==0)
  {
    Serial.print(F("temperature:"));
    Serial.print(temp);
    Serial.print(F(" humidity:"));
    Serial.println(humi);    
  }
  else
  {
    Serial.println();
    Serial.print(F("Error No :"));
    Serial.println(err);    
  }
  //delay(DHT11_RETRY_DELAY); //delay for reread - LO FACCIO GIA NEL MAIN
}

void readDS(){
	  if ( !ds.search(addr)) {
		Serial.println(F("No more addresses.\n"));		
		ds.reset_search();
		delay(250);
		return;
	  }
	  
	  Serial.print("ROM =");
	  for( i = 0; i < 8; i++) {
		Serial.write(' ');
		Serial.print(addr[i], HEX);
	  }

	  if (OneWire::crc8(addr, 7) != addr[7]) {
		  Serial.println(F("CRC is not valid!"));
		  return;
	  }
	  Serial.println();
	 
	  // the first ROM byte indicates which chip
	  switch (addr[0]) {
		case 0x10:
		  Serial.println(F("  Chip = DS18S20"));  // or old DS1820
		  type_s = 1;
		  break;
		case 0x28:
		  Serial.println(F("  Chip = DS18B20"));
		  type_s = 0;
		  break;
		case 0x22:
		  Serial.println(F("  Chip = DS1822"));
		  type_s = 0;
		  break;
		default:
		  Serial.println(F("Device is not a DS18x20 family device."));
		  return;
	  } 

	  ds.reset();
	  ds.select(addr);
	  ds.write(0x44, 1);        // start conversion, with parasite power on at the end
	  
	  delay(1000);     // maybe 750ms is enough, maybe not
	  // we might do a ds.depower() here, but the reset will take care of it.
	  
	  present = ds.reset();
	  ds.select(addr);    
	  ds.write(0xBE);         // Read Scratchpad

	  Serial.print(F("  Data = "));
	  Serial.print(present, HEX);
	  Serial.print(F(" "));
	  for ( i = 0; i < 9; i++) {           // we need 9 bytes
		data[i] = ds.read();
		Serial.print(data[i], HEX);
		Serial.print(F(" "));
	  }
	  Serial.print(F(" CRC="));
	  Serial.println(OneWire::crc8(data, 8), HEX);
	  
	  // Convert the data to actual temperature
	  // because the result is a 16 bit signed integer, it should
	  // be stored to an "int16_t" type, which is always 16 bits
	  // even when compiled on a 32 bit processor.
	  int16_t raw = (data[1] << 8) | data[0];
	  if (type_s) {
		raw = raw << 3; // 9 bit resolution default
		if (data[7] == 0x10) {
		  // "count remain" gives full 12 bit resolution
		  raw = (raw & 0xFFF0) + 12 - data[6];
		}
	  } else {
		byte cfg = (data[4] & 0x60);
		// at lower res, the low bits are undefined, so let's zero them
		if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
		else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
		else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
		//// default is 12 bit resolution, 750 ms conversion time
	  }
	  celsius = (float)raw / 16.0;
	  fahrenheit = celsius * 1.8 + 32.0;
	  Serial.print(F("  Temperature = "));
	  Serial.print(celsius);
	  Serial.print(F(" Celsius, "));
	  Serial.print(fahrenheit);
	  Serial.println(F(" Fahrenheit"));

}

Grazie molte

grazie