# Uno Rev2 Wifi server/client connection problems

**URL:** <https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217>\
**Category:** UNO WiFi Rev2\
**Created:** [July 2, 2025, 9:24pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217 "2025-07-02T21:24:01Z")\
**Posts on this page:** 12\
**Page:** 1

<div class="post-metadata">

**Author:** ![malathisguy](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/malathisguy/32/1225535_2.png) [@malathisguy](https://forum.arduino.cc/u/malathisguy)\
**Post date:** [July 2, 2025, 9:24pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/1 "2025-07-02T21:24:01Z")

</div>

Good afternoon,  
I have two Arduino Uno Rev2 WiFi boards with one as the server, while the other a client. The client uses a ultrasonic sensor to detect if an object goes in front of it. Then sends a GET request to the static IP of the server indicating that someone is blocking its view.

Both the server and client can work, and have worked several times with one another. The problem is that if the client doesn't find the server within 10 minutes, it likely will never find it.

On the other end of this problem is that, if there is connectivity it lasts only an hour or two before freezing up on both ends. I believe that it's _client.connect()_'s issue, because it takes at least 10 seconds to try and connect before timing out. But also the server freezes as well, so I'm not too sure what the issue is.

I just need a bit of help with making sure that both connect within at least a minute of being reset/powered-on externally, and lasting at minimum 24 hours.

If you can help in any way, thank you and I appreciate your input.

This is the Server code:

```arduino
#include <SPI.h>
#include "WiFiNINA.h"
#include "arduino_secrets.h" 

#define greenLED 10

//Network specific variables
char ssid[] = SECRET_SSID; // WiFi SSID
char pass[] = SECRET_PASS; // WiFi Password
int status = WL_IDLE_STATUS;

IPAddress ip(192, 168, 46, 244);
IPAddress dns(8, 8, 8, 8);
IPAddress gateway(192, 168, 46, 1);
IPAddress subnet(255, 255, 255, 0);

WiFiServer server(80);
String readString;

//Setup Function
void setup() {
  Serial.begin(115200);
  pinMode(greenLED, OUTPUT);

  while (!Serial) {;}

  digitalWrite(LED_BUILTIN, LOW);
  WiFi.config(ip, dns, gateway, subnet);
  while (status != WL_CONNECTED) {status = WiFi.begin(ssid, pass);}
  digitalWrite(LED_BUILTIN, HIGH);

  IPAddress ip = WiFi.localIP();
  Serial.print("http://");
  Serial.println(ip); //Prints to the newly generated IP Address
  server.begin();
}

void loop(){
  WiFiClient client = server.available();
  if (client) {
    boolean currentLineIsBlank = true;
    while (client.connected()){
      if (client.available()){
        char c = client.read();
        if (readString.length() < 50){
          readString += c;
        if (c == '\n') {
          currentLineIsBlank = true;
          if (readString.indexOf("one") > 0){
            analogWrite(greenLED, 15);
          }
          else{
            analogWrite(greenLED, 0);
          }
          readString = "";
        } else if (c != '\r') {
          currentLineIsBlank = false;
          }
        }
      }
    }
  }
  delay(1);
  //Serial.print(millis()/1000);
  //Serial.println(" seconds elapsed");
}

```

This is the Client code:

```arduino
#include <SPI.h>
#include "WiFiNINA.h"
#include "arduino_secrets.h" 

#define bluePin 10
#define trigPin 8
#define echoPin 9

//Network specific variables
char ssid[] = SECRET_SSID; // WiFi SSID
char pass[] = SECRET_PASS; // WiFi Password
int status = WL_IDLE_STATUS;

char setIP[] = "192.168.46.244"; //IP Address trying to connect to
int port = 80; //The port for HTTP transmission

WiFiClient client;

//Setup Function
void setup() {
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  pinMode(bluePin, OUTPUT);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  while (!Serial) {;}

  digitalWrite(LED_BUILTIN, LOW);
  while (status != WL_CONNECTED) {
    status = WiFi.begin(ssid, pass);
    }
  digitalWrite(LED_BUILTIN, HIGH);
}

int sensorDist() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  if (pulseIn(echoPin, HIGH) < 500){return 1;}
  else{return 0;};
}

void loop(){
  if (sensorDist() == 0) {
    if (client.connect(setIP, port)) {
      client.write("GET /zro HTTP/1.1\r\n");
      analogWrite(bluePin, 0);
    }
  } else {
    if (client.connect(setIP, port)) {
      client.write("GET /one HTTP/1.1\r\n");
      analogWrite(bluePin, 15);
    }
  }
  if (client.connected()) {client.stop();}
  delay(1000);
  //Serial.print(millis()/1000);
  //Serial.println(" seconds elapsed");
}

```

---

<div class="post-metadata">

**Author:** ![qubits-us](https://avatars.discourse-cdn.com/v4/letter/q/5daacb/32.png) [@qubits-us](https://forum.arduino.cc/u/qubits-us)\
**Post date:** [July 3, 2025, 12:03am UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/2 "2025-07-03T00:03:09Z")

</div>

Hi @malathisguy ,

Welcome to the forum..

> [@malathisguy](#):
>
> lasting at minimum 24 hours.

Really need a state machine in your loop keeping tack of everything that could possibly go wrong..  
for starters, you connect wifi in setup one time, what happens when it disconnects..  
these boards only got like 6k of ram available, your probably chewing it up in a few minutes, which would lock them up..

using a String could lead to memory fragmentation..  
having a global client connect and disconnect once per second, will cause you grief..  
TCP is a guaranteed protocol, hence you must connect and disconnect both of which take time..  
you might have better results leaving the client connected..

i'm thinking this would be better using UDP..  
the client could broadcast once per second, the server listens for these, it's not guaranteed but it also does not require a connection..

here's something to look over..  
[a nice state machine..](https://github.com/qubits-us/ArdsAndEnds/blob/main/CamServer/esp/ESPCamCli.ino)  
[UDP Sender..](https://github.com/qubits-us/ArdsAndEnds/tree/main/UDPsend)  
[UDP Receiver..](https://github.com/qubits-us/ArdsAndEnds/tree/main/UDPreceive)  
the above is for esp32 but the udp should be easily adaptable to your board..

good luck.. ~q

---

<div class="post-metadata">

**Author:** ![malathisguy](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/malathisguy/32/1225535_2.png) [@malathisguy](https://forum.arduino.cc/u/malathisguy)\
**Post date:** [July 3, 2025, 5:07pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/3 "2025-07-03T17:07:34Z")

</div>

I'm currently trying to debug the code sent, and for my board _Wifi.mode(WIFI\_STA)_ throws the following error:

_Compilation error: 'class WiFiClass' has no member named 'mode'_

I've already looked through the github repo, and can't find an equivalent for my Uno. When I comment out that line from both ends, the "Receiver" doesn't capture any data transmitted.

---

<div class="post-metadata">

**Author:** ![qubits-us](https://avatars.discourse-cdn.com/v4/letter/q/5daacb/32.png) [@qubits-us](https://forum.arduino.cc/u/qubits-us)\
**Post date:** [July 3, 2025, 5:46pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/4 "2025-07-03T17:46:22Z")

</div>

commenting out the mode was correct..  
and you should have replaced \<WiFi.h\> with \<WiFiNINA.h\>..

looking through [the official demo..](https://github.com/arduino-libraries/WiFiNINA/blob/master/examples/WiFiUdpSendReceiveString/WiFiUdpSendReceiveString.ino)  
seems the same..  
please post the sketches for the sender and receiver, i'll take a look at them for you..

~q

---

<div class="post-metadata">

**Author:** ![qubits-us](https://avatars.discourse-cdn.com/v4/letter/q/5daacb/32.png) [@qubits-us](https://forum.arduino.cc/u/qubits-us)\
**Post date:** [July 3, 2025, 6:21pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/5 "2025-07-03T18:21:59Z")

</div>

what do these do..

sender..

```arduino
#include <SPI.h>
#include <WiFiNINA.h>
#include <WiFiUdp.h>
#include "arduino_secrets.h" 

#define bluePin 10
#define trigPin 8
#define echoPin 9

//Network specific variables
char ssid[] = SECRET_SSID; // WiFi SSID
char pass[] = SECRET_PASS; // WiFi Password
int status = WL_IDLE_STATUS;

char setIP[] = "192.168.46.244"; //IP Address trying to connect to

IPAddress udpServer(192, 168, 46, 244);

#define UDP_PORT 3000
WiFiUDP udp;

// UDP Datagram
struct __attribute__ ((packed)) UDPDatagram {
  int16_t sdata; // 16 bit integer data
  uint16_t crc; // crc check
} udpDatagram = { 0, 0 }; // initial values

//Setup Function
void setup() {
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  pinMode(bluePin, OUTPUT);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  while (!Serial) {;}

  digitalWrite(LED_BUILTIN, LOW);
  while (status != WL_CONNECTED) {
    status = WiFi.begin(ssid, pass);
    delay(10000);
    }
  digitalWrite(LED_BUILTIN, HIGH);
}

int sensorDist() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  if (pulseIn(echoPin, HIGH) < 500){return 1;}
  else{return 0;};
}

void loop(){

  if (sensorDist() == 0) {
      analogWrite(bluePin, 0);
      udpDatagram.sdata = 0
  } else {
      analogWrite(bluePin, 15);
      udpDatagram.sdata = 1;
    }

//calc checksum..
  udpDatagram.crc = 0;
  for (int i = 0; i < sizeof(udpDatagram) - 2; i++) {
    udpDatagram.crc += ((uint8_t *)&udpDatagram)[i];
  }
  // Send Packet to UDP server
  udp.beginPacket(udpServer, UDP_PORT);

  delay(1000);

}

```

receiver..

```arduino
#include <SPI.h>
#include <WiFiNINA.h>
#include <WiFiUdp.h>
#include "arduino_secrets.h" 

#define greenLED 10

//Network specific variables
char ssid[] = SECRET_SSID; // WiFi SSID
char pass[] = SECRET_PASS; // WiFi Password
int status = WL_IDLE_STATUS;

IPAddress ip(192, 168, 46, 244);
IPAddress dns(8, 8, 8, 8);
IPAddress gateway(192, 168, 46, 1);
IPAddress subnet(255, 255, 255, 0);

#define UDP_PORT 3000
WiFiUDP udp;
// UDP Datagram
struct __attribute__ ((packed)) UDPDatagram {
  int16_t sdata; // 16 bit integer data
  uint16_t crc; // crc check
} udpDatagram = { 0, 0 }; // initial values

uint8_t buff[sizeof(UDPDatagram)];

//Setup Function
void setup() {
  Serial.begin(115200);
  pinMode(greenLED, OUTPUT);

  while (!Serial) {;}

  digitalWrite(LED_BUILTIN, LOW);
  WiFi.config(ip, dns, gateway, subnet);
  while (status != WL_CONNECTED) {status = WiFi.begin(ssid, pass); delay(10000);}
  digitalWrite(LED_BUILTIN, HIGH);

  IPAddress ip = WiFi.localIP();
  Serial.print("http://");
  Serial.println(ip); //Prints to the newly generated IP Address
  udp.begin(UDP_PORT);
}

void loop(){

  if (udp.parsePacket()) {
    //new packet..
    int recv = udp.read(buff, sizeof(buff));
    if (recv == sizeof(UDPDatagram)) {
      memcpy(&udpDatagram,&buff, sizeof(UDPDatagram));
      if (crcVerify()) {
        Serial.println("Packet received..");
        if (udpDatagram.sdata == 1 ){
            analogWrite(greenLED, 15);
        } else{
            analogWrite(greenLED, 0);
        }
      } else{
        Serial.println("Ignoring packet..");
      }
    }
  }
}

bool crcVerify() {
  uint16_t crc = 0;
  Serial.print("Datagram data ");
  for (int i = 0; i < sizeof(udpDatagram) - 2; i++) {
    Serial.print((uint8_t)((uint8_t *)&udpDatagram)[i], HEX);
    Serial.print(' ');
    crc += ((uint8_t *)&udpDatagram)[i];
  }
  return (crc == udpDatagram.crc);
}

```

~q

---

<div class="post-metadata">

**Author:** ![malathisguy](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/malathisguy/32/1225535_2.png) [@malathisguy](https://forum.arduino.cc/u/malathisguy)\
**Post date:** [July 3, 2025, 9:06pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/6 "2025-07-03T21:06:35Z")

</div>

I've tested the code you both the sender/receiver. The "sender" code is sending out _udpDatagram_ values while shining its blue light, but the "receiver" is not collecting any packets. The Port and IP remain the same.

Once in the main loop, `if (udp.parsePacket()){...}` always returns false.

I'll still keeping looking into what the issue is.

---

<div class="post-metadata">

**Author:** ![qubits-us](https://avatars.discourse-cdn.com/v4/letter/q/5daacb/32.png) [@qubits-us](https://forum.arduino.cc/u/qubits-us)\
**Post date:** [July 3, 2025, 9:46pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/7 "2025-07-03T21:46:30Z")

</div>

@malathisguy i see an issue with the sender..

try this..

```arduino
#include <SPI.h>
#include <WiFiNINA.h>
#include <WiFiUdp.h>
#include "arduino_secrets.h" 

#define bluePin 10
#define trigPin 8
#define echoPin 9

//Network specific variables
char ssid[] = SECRET_SSID; // WiFi SSID
char pass[] = SECRET_PASS; // WiFi Password
int status = WL_IDLE_STATUS;

char setIP[] = "192.168.46.244"; //IP Address trying to connect to

IPAddress udpServer(192, 168, 46, 244);

#define UDP_PORT 3000
WiFiUDP udp;

// UDP Datagram
struct __attribute__ ((packed)) UDPDatagram {
  int16_t sdata; // 16 bit integer data
  uint16_t crc; // crc check
} udpDatagram = { 0, 0 }; // initial values

//Setup Function
void setup() {
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  pinMode(bluePin, OUTPUT);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  while (!Serial) {;}

  digitalWrite(LED_BUILTIN, LOW);
  while (status != WL_CONNECTED) {
    status = WiFi.begin(ssid, pass);
    delay(10000);
    }
  digitalWrite(LED_BUILTIN, HIGH);
}

int sensorDist() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  if (pulseIn(echoPin, HIGH) < 500){return 1;}
  else{return 0;};
}

void loop(){

  if (sensorDist() == 0) {
      analogWrite(bluePin, 0);
      udpDatagram.sdata = 0
  } else {
      analogWrite(bluePin, 15);
      udpDatagram.sdata = 1;
    }

//calc checksum..
  udpDatagram.crc = 0;
  for (int i = 0; i < sizeof(udpDatagram) - 2; i++) {
    udpDatagram.crc += ((uint8_t *)&udpDatagram)[i];
  }
  // Send Packet to UDP server
  udp.beginPacket(udpServer, UDP_PORT);
   int len = udp.write((const uint8_t *)&udpDatagram, sizeof(udpDatagram));
  udp.endPacket();
  delay(1000);

}

```

sorry.. ~q

---

<div class="post-metadata">

**Author:** ![malathisguy](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/malathisguy/32/1225535_2.png) [@malathisguy](https://forum.arduino.cc/u/malathisguy)\
**Post date:** [July 3, 2025, 10:49pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/8 "2025-07-03T22:49:59Z")

</div>

> [@qubits-us](#):
>
> ```arduino
> ...
> int len = udp.write((const uint8_t *)&udpDatagram, sizeof(udpDatagram));
> udp.endPacket();
> ...
> 
> ```

No need to apologize.  
I incorporated the section and reran the code, but still got the same result.

I also added a _Serial.println()_ to the "receiver" (shown below), and nothing is being printed to the Serial other than the static IP.

```arduino
void loop(){
  if (udp.parsePacket()) {
    Serial.println("Found!");
    //new packet..
    int recv = udp.read(buff, sizeof(buff));

```

---

<div class="post-metadata">

**Author:** ![qubits-us](https://avatars.discourse-cdn.com/v4/letter/q/5daacb/32.png) [@qubits-us](https://forum.arduino.cc/u/qubits-us)\
**Post date:** [July 3, 2025, 11:00pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/9 "2025-07-03T23:00:05Z")

</div>

network issue??  
the sender is using dhcp the receiver a static..  
add some code to print the dhcp ip the sender is assigned, it should also be in the 192.168.46.xxx range..  
run a network sniffer to actually see if the packet is getting out..

strange..~q

---

<div class="post-metadata">

**Author:** ![malathisguy](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/malathisguy/32/1225535_2.png) [@malathisguy](https://forum.arduino.cc/u/malathisguy)\
**Post date:** [July 4, 2025, 12:53am UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/10 "2025-07-04T00:53:05Z")

</div>

I've tested it on a couple of different networks (without a network sniffer), and continue to get the same result. I'll work on getting a network sniffer and let you know what I find tomorrow.

---

<div class="post-metadata">

**Author:** ![malathisguy](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/malathisguy/32/1225535_2.png) [@malathisguy](https://forum.arduino.cc/u/malathisguy)\
**Post date:** [July 7, 2025, 11:15pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/11 "2025-07-07T23:15:37Z")

</div>

I finally figured it out! Now, one Arduino can send packets to the other! The sender code needed to contain respectively the following:

```arduino
WiFiServer server(UDP_PORT);
...
server.begin();

```

Below is the final sender code:

```arduino
#include <SPI.h>
#include <WiFiNINA.h>
#include <WiFiUdp.h>
#include "arduino_secrets.h" 

#define bluePin 10
#define trigPin 8
#define echoPin 9

char ssid[] = SECRET_SSID; // WiFi SSID
char pass[] = SECRET_PASS; // WiFi Password
int status = WL_IDLE_STATUS;

IPAddress udpServer(192, 168, 46, 244);
unsigned int UDP_PORT = 2390;

WiFiUDP udp;
WiFiServer server(UDP_PORT);

struct __attribute__ ((packed)) UDPDatagram {
  int16_t sdata; // 16 bit integer data
  uint16_t crc; // crc check
} udpDatagram = { 0, 0 }; // initial values

void setup() {
  Serial.begin(115200);
  pinMode(bluePin, OUTPUT);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  while (!Serial) {;}
  while (status != WL_CONNECTED) {
    status = WiFi.begin(ssid, pass);
    delay(5000);}

  udp.begin(UDP_PORT);
  server.begin();

  Serial.println("I'm Ready!");
}

int sensorDist() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  if (pulseIn(echoPin, HIGH) < 500){return 1;}
  else{return 0;};
}

void loop(){    
  if (sensorDist() == 0) {
    analogWrite(bluePin, 0);
    udpDatagram.sdata = 0;
  } else {
    analogWrite(bluePin, 15);
    udpDatagram.sdata = 1;
  }

  udpDatagram.crc = 0;
  for (int i = 0; i < sizeof(udpDatagram) - 2; i++) {
    udpDatagram.crc += ((uint8_t *)&udpDatagram)[i];
  }

  udp.beginPacket(udpServer, UDP_PORT);
  udp.write((const uint8_t *)&udpDatagram, sizeof(udpDatagram));
  udp.endPacket();
  delay(1000);
}

```

I only added a delay to the _void loop()_ and changed the _UDP\_PORT_'s datatype for the receiver. Below is the final code for it.

```arduino
#include <SPI.h>
#include <WiFiNINA.h>
#include <WiFiUdp.h>
#include "arduino_secrets.h" 

#define greenLED 10

//Network specific variables
char ssid[] = SECRET_SSID; // WiFi SSID
char pass[] = SECRET_PASS; // WiFi Password
int status = WL_IDLE_STATUS;

WiFiUDP udp;
IPAddress ip(192, 168, 46, 244);
IPAddress dns(8, 8, 8, 8);
IPAddress gateway(192, 168, 46, 1);
IPAddress subnet(255, 255, 255, 0);
unsigned int UDP_PORT = 2390;

// UDP Datagram
struct __attribute__ ((packed)) UDPDatagram {
  int16_t sdata; // 16 bit integer data
  uint16_t crc; // crc check
} udpDatagram = { 0, 0 }; // initial values

uint8_t buff[sizeof(UDPDatagram)];

//Setup Function
void setup() {
  Serial.begin(115200);
  pinMode(greenLED, OUTPUT);

  while (!Serial) {;}

  WiFi.config(ip, dns, gateway, subnet);
  while (status != WL_CONNECTED) {
    status = WiFi.begin(ssid, pass);
    delay(5000);}

  udp.begin(UDP_PORT);

  Serial.println("Send in the Packets!");
}

void loop(){
  if (udp.parsePacket()) {
    int recv = udp.read(buff, sizeof(buff));
    if (recv == sizeof(UDPDatagram)) {
      memcpy(&udpDatagram,&buff, sizeof(UDPDatagram));
      if (crcVerify()) {
        if (udpDatagram.sdata == 1 ){
            analogWrite(greenLED, 15);
        } else{
            analogWrite(greenLED, 0);
        }
      }
    }
  }
  delay(100);
}

bool crcVerify() {
  uint16_t crc = 0;
  for (int i = 0; i < sizeof(udpDatagram) - 2; i++) {
    //Serial.print((uint8_t)((uint8_t *)&udpDatagram)[i], HEX);
    //Serial.print(' ');
    crc += ((uint8_t *)&udpDatagram)[i];
  }
  return (crc == udpDatagram.crc);
}

```

The only thing I'm concerned with is how long the program can run for now. I was hoping for it to be 24/7, but that's the least of my problems at this point. Thank you again for all your help! Truly beneficial!

---

<div class="post-metadata">

**Author:** ![system](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/system/32/1140315_2.png) [@system](https://forum.arduino.cc/u/system)\
**Post date:** [January 3, 2026, 11:16pm UTC](https://forum.arduino.cc/t/uno-rev2-wifi-server-client-connection-problems/1393217/12 "2026-01-03T23:16:19Z")

</div>

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.