Unsuccessful uno+ethernet setup

So I guess this is my last resort. I'm pretty new to the whole arduino thing and even newer to trying to set up a basic web server. The setup I am using is the Uno r2 and ethernet R3. Here's what's going on, I used the example ethernet sketchbook for the web server with the mac address and ip as follows:
byte mac[] = { 0x90, 0xA2, 0xDA, 0x03, 0x00, 0xA8 };
IPAddress ip(192, 168, 11, 232); This is a modified version of what I got off the pc when using Verizon Mifi card.
I've tried multiple variations of the ip and still nothing works. I've looked all over the net trying to find answers but with no luck. The only thing I could think that could be wrong would be that I'm using a Dynex network hub instead of a wireless or non-wireless router. Here's what shows up when I type ipconfig/all into my pc when using hub (I'm programming on a mac):
IP Address.....:70.94.93.70
Subnet mask.....:255.255.240.0
Default gateway......:70.94.80.1
DHCP Server......:76.43.0.1
DNS Server......:209.18.47.61
209.18.47.62

I'm stuck guys, any help would be much appreciated!

Client test code below. You will need to figure out your appropriate lan IP address for the arduino and use that in the code.

//zoomkat 12-08-11
//simple client test
//for use with IDE 1.0
//open serial monitor and send an e to test
//for use with W5100 based ethernet shields

#include <SPI.h>
#include <Ethernet.h>

byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED }; //physical mac address
byte ip[] = { 192, 168, 1, 102 }; // ip in lan assigned to arduino
//byte gateway[] = { 192, 168, 1, 1 }; // internet access via router
//byte subnet[] = { 255, 255, 255, 0 }; //subnet mask
byte myserver[] = { 208, 104, 2, 86 }; // zoomkat web page server IP address
EthernetClient client;
//////////////////////

void setup(){

  Ethernet.begin(mac, ip);
  //Ethernet.begin(mac, ip, subnet, gateway);
  Serial.begin(9600); 
  Serial.println("Better client test 12/01/11"); // so I can keep track of what is loaded
  Serial.println("Send an e in serial monitor to test"); // what to do to test
}

void loop(){
  // check for serial input
  if (Serial.available() > 0) //if something in serial buffer
  {
    byte inChar; // sets inChar as a byte
    inChar = Serial.read(); //gets byte from buffer
    if(inChar == 'e') // checks to see byte is an e
    {
      sendGET(); // call sendGET function below when byte is an e
    }
  }  
} 

//////////////////////////

void sendGET() //client function to send/receive GET request data.
{
  if (client.connect(myserver, 80)) {  //starts client connection, checks for connection
    Serial.println("connected");
    client.println("GET /~shb/arduino.txt HTTP/1.0"); //download text
    client.println(); //end of get request
  } 
  else {
    Serial.println("connection failed"); //error message if no client connect
    Serial.println();
  }

  while(client.connected() && !client.available()) delay(1); //waits for data
  while (client.connected() || client.available()) { //connected or data available
    char c = client.read(); //gets byte from ethernet buffer
    Serial.print(c); //prints byte to serial monitor 
  }

  Serial.println();
  Serial.println("disconnecting.");
  Serial.println("==================");
  Serial.println();
  client.stop(); //stop client

}

You need to give the ethernet shield an unused IP address on the network you are connecting it to. So what is the network you are connecting to? I rather doubt its 70.94.9.0/20 - that looks like your ISP's network.

Typically you'd connect it to a local network like 192.168.1.0/24 or 10.0.0.0/16.

Is that a static ip assignment in your computer or assigned by dhcp? Since you listed a dhcp server there, maybe you should try letting it issue your network settings.

if(Ethernet.begin(mac) == 0)
{
   Serial.println("DHCP failed");
   // stay here forever.
   for(;;)
   ;
}
Serial.println("DHCP ok");