Variable in for-loop is acting weird

laura2000 · August 11, 2021, 1:09pm

Hi,
I have a piece of code (see below). When i run the code I get output 1. But in the serial monitor, I never see the word "pointa" or "pointb". I have already found what is causing this. If i set the line offset = 1000*i in comment, the problem is solved. Then i get output 2.

I do not understand how this is possible. Does anyone have an explanation for this?
Thank you in advance.

This is the code:

long offset = 0;
long numberMeausurementsRequest_int = 1200;
String input = "";

void setup() { // wait for serial to start
  Serial.begin(115200);
    while (!Serial) {
  }
  randomSeed(analogRead(0));
}

void loop() { 
for (int i = 0; i<numberMeausurementsRequest_int ;i=i+3){
      offset = 1000*i; // <<-----------------------------------------
      if ((i > 500)&&(i<600)){ 
        Serial.println(String(i) + "pointa");
      }
      else if ((i > 700)&&(i<710)){ 
        Serial.println(String(i) + "pointb");
      }
      else{
        Serial.println(i);
      }
    }
    Serial.println("#");  
}

output 1:

output 2:

JBornstein90 · August 11, 2021, 1:21pm

Can you post the entire code please. I'm curious if you have defined your variables in some conflicting way

anon73444976 · August 11, 2021, 1:29pm

int times int is prone to overflow

anon57585045 · August 11, 2021, 1:30pm

Irrational behaviour of the code is often due to a mistake that is made elsewhere in the code than where you see the symptoms. For example, if you exceed array bounds, unpredictable memory locations can be modified. The effects can be extremely random. That is why we want to see the entire sketch.

gcjr · August 11, 2021, 1:30pm

with warnings turned on i get the following

C:\Tools\Arduino\hardware\arduino\avr\cores\arduino\main.cpp: In function 'main':
C:\stuff\SW\Arduino\_Others\Tst\Tst.ino:12:22: warning: iteration 11 invokes undefined behavior [-Waggressive-loop-optimizations]
         offset = 1000*i; // <<-----------------------------------------
                      ^
C:\stuff\SW\Arduino\_Others\Tst\Tst.ino:11:22: note: within this loop
     for (int i = 0; i<numberMeausurementsRequest_int ;i=i+3){
                      ^

the computation is done as an int and therefore exceeds 32768. not sure why this causes the problem

replacing with

offset = 1000L*i;

seems to fix it.

laura2000 · August 11, 2021, 1:45pm

The full code is below. To test the code, enter "START1000" in the serial monitor.

// ------ this program print fake data to the serial monitor ------

long offset = 0;
long pulseTime1 = 0;
long pulseTime2 = 0;
long pulseTime3 = 0;

int chort = 100;
int medium = 300;
int lang = 600;

long numberMeausurementsRequest_int = 1200;

String input = "";

void setup() {
  Serial.begin(115200);
    while (!Serial) {
    ; // wait for serial port to connect.
  }
  randomSeed(analogRead(0));
}


void loop() { 
  char input_serial_str[10];
  int idx = 0;
//--------- detect the word "START" and take the numbers after that word -- (this part is working)-----------
  while (Serial.available() == 0) {} // wait for user input
  input = Serial.readString();
  if (input[0] == 'S' && input[1] == 'T'&& input[2] == 'A'&& input[3] == 'R' && input[4] == 'T'){
    
    String numberMeasurementsRequest = "";
    long numberMeausurementsRequest_int = 0;
    for (int x = 5; x< input.length()-1; x++){
      numberMeasurementsRequest = numberMeasurementsRequest + input[x];
    }
    numberMeausurementsRequest_int = numberMeasurementsRequest.toInt();
    Serial.println(numberMeausurementsRequest_int); 
    
// -----------------------------------------------------------------------------------------------

// -------print to the serial monitor ----(this part is not working)------------------------------
    // eerste soort pulsen -_-__-____
    for (int i = 0; i<numberMeausurementsRequest_int ;i=i+3){
      offset = 1000*i;
      pulseTime1 = offset +3;
      pulseTime2 = pulseTime1 + chort;
      pulseTime3 = pulseTime2 + medium;
      if ((i > 500)&&(i<600)){ 
        Serial.println(String(i) + "pointa");
        Serial.println(String(random(235,255)) + ";" + String(pulseTime1)); // amplitude + ";" + time
        Serial.println(String(random(200,210)) + ";" + String(pulseTime2));
        Serial.println(String(random(235,255)) + ";" + String(pulseTime3));
      }
      else if ((i > 700)&&(i<710)){ 
        Serial.println(String(i) + "pointb");
        Serial.println(String(random(235,255)) + ";" + String(pulseTime1)); // amplitude + ";" + time
        Serial.println(String(random(200,210)) + ";" + String(pulseTime2));
        Serial.println(String(random(235,255)) + ";" + String(pulseTime3));
      }
      else{
        Serial.println(i);
        Serial.println(String(random(174,199)) + ";" + String(pulseTime1));
        Serial.println(String(random(200,210)) + ";" + String(pulseTime2));
        Serial.println(String(random(174,199)) + ";" + String(pulseTime3));
      }
    }
    Serial.println("#");   
    input = "";
  } 
}

laura2000 · August 11, 2021, 1:47pm

@gcjr Thank you. Now it works.

johnwasser · August 11, 2021, 2:29pm

Looks like a compiler error. Is integer overflow supposed to be "undefined behavior"?!?

JBornstein90 · August 11, 2021, 2:51pm

Also true. At least In this case, the variable definition of int (times int) resulted in a value overflow, so I am glad to see that I helped the issue and it has been resolved.

anon57585045 · August 11, 2021, 3:20pm

Perhaps, if it can not be predicted at compile time, e.g. consider

long j = 1000 * i;

vs.

long j = 1000 * 1000;

???

johnwasser · August 11, 2021, 3:43pm

But it WAS predicted at compile time.

/Users/john/Documents/Arduino/sketch_aug11b/sketch_aug11b.ino:11:19: warning: iteration 33 invokes undefined behavior [-Waggressive-loop-optimizations]
     offset = 1000 * i;
              ~~~~~^~~

void setup()
{
  Serial.begin(115200);
  while (!Serial) {}
  delay(200);

  unsigned long offset;

  for (int i = 0; i < 100; i++)
  {
    offset = 1000 * i;
  }
}

void loop() {}

What is the 'undefined behavior' in 'iteration 33' if not the integer overflow when 1000 is multiplied by 33?

anon57585045 · August 11, 2021, 4:57pm

Yeah, in this case the 'for' loop parameters guarantee that 'i' will exceed 32. I wonder what would happen if not? For example, if 'i' were the product of some complex calculation?

alto777 · August 11, 2021, 6:09pm

It is in C.

a7

johnwasser · August 11, 2021, 7:51pm

Looks like C++, too.
https://en.cppreference.com/w/c/language/operator_arithmetic
I hadn't thought about the various ways of storing signed numbers.

If I change 'i' from 'int' to 'unsigned' the compiler doesn't bother to warn that 'iteration 66 invokes integer overflow' even though it was happy to point out 'iteration 33 invokes undefined behavior'.

alto777 · August 11, 2021, 8:52pm

That's because overflow in unsigned integers is not undefined beviuour!

It is well defined and often exploited, and probably something one can be forgiven for expecting to be the same w/ signed ints.

And maybe in 99.44 it is OK.

The only fault would be a compiler that failed to issue the warning, or we who fly close to the sun with warnings turnt off or just ignored.

a7

SteveThackery · August 11, 2021, 9:02pm

Indeed, isn't this the very thing that allows us to handle micros() and millis() rollovers?

system · December 9, 2021, 9:02pm

This topic was automatically closed 120 days after the last reply. New replies are no longer allowed.