Guys,
I am in the process of migrating my home heating system away from a system i originally built on a Picaxe platform a number of years ago into the Arduino Realm.
I have broken many of the functions down and have migrated them across to the Arduino one at a time (i use I2c to communicated backwards and forwards between the Arduino and the Picaxe)
One of the new functions i would like to implement is to be able to take weather forecasts into the system and to then parse that data to add as variables into the heating cycle (the system only does heating in winter at this stage).
It is a Hydronic system and relies on infloor and in wall heating heating - no wall mounted radiators. As such i find the system has a long lag time - thus i would like to be able to look at a weather report in the morning that says something sunny in morning - max temp 23c, cloudy and cold in the afternoon - i would therefore apply additinoal heat in the morning (which may cause a small amount of overshoot of preferred set temperature) in anticipation of additional chill in the afternoon.
Does anyone have any code for querying any of the weather sites that provide at least a 12 hour forecast (i am in Sydney Australia) ???
Craig
The weather underground API may have what you want Loading | Weather Underground particularly Loading | Weather Underground
Weather code.
//////////////////////////////////////////////
// Get XML formatted data from the web.
// 1/6/08 Bob S. - Created
// Assumptions: single XML line looks like:
// <tag>data</tag> or <tag>data
// Include description files for other libraries used (if any)
//
// updated at later dates zoomkat
//////////////////////////////////////////////
#include <SPI.h>
#include <Ethernet.h>
// Define Constants
// Max string length may have to be adjusted depending on data to be extracted
#define MAX_STRING_LEN 20
// Setup vars
char tagStr[MAX_STRING_LEN] = "";
char dataStr[MAX_STRING_LEN] = "";
char tmpStr[MAX_STRING_LEN] = "";
char endTag[3] = {'<', '/', '\0'};
int len;
// Flags to differentiate XML tags from document elements (ie. data)
boolean tagFlag = false;
boolean dataFlag = false;
// Ethernet vars
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
//byte ip[] = { 192, 168, 1, 102 };
byte server[] = { 140, 90, 113, 200 }; // www.weather.gov
// Start ethernet client
EthernetClient client;
void setup()
{
Serial.begin(9600);
Serial.println("Starting WebWx");
Serial.println("connecting...");
//Ethernet.begin(mac, ip);
Ethernet.begin(mac);
delay(1000);
if (client.connect(server, 80)) {
Serial.println("connected");
client.println("GET /xml/current_obs/KRDU.xml HTTP/1.0");
client.println();
delay(2000);
} else {
Serial.println("connection failed");
}
}
void loop() {
// Read serial data in from web:
while (client.available()) {
serialEvent();
}
if (!client.connected()) {
Serial.println();
Serial.println("Disconnected");
Serial.println("==================================");
Serial.println("");
client.stop();
// Time until next update
//Serial.println("Waiting");
for (int t = 1; t <= 15; t++) {
delay(60000); // 1 minute
}
if (client.connect(server, 80)) {
//Serial.println("Reconnected");
client.println("GET /xml/current_obs/KRDU.xml HTTP/1.0");
client.println();
delay(2000);
} else {
Serial.println("Reconnect failed");
}
}
}
// Process each char from web
void serialEvent() {
// Read a char
char inChar = client.read();
//Serial.print(".");
if (inChar == '<') {
addChar(inChar, tmpStr);
tagFlag = true;
dataFlag = false;
} else if (inChar == '>') {
addChar(inChar, tmpStr);
if (tagFlag) {
strncpy(tagStr, tmpStr, strlen(tmpStr)+1);
}
// Clear tmp
clearStr(tmpStr);
tagFlag = false;
dataFlag = true;
} else if (inChar != 10) {
if (tagFlag) {
// Add tag char to string
addChar(inChar, tmpStr);
// Check for </XML> end tag, ignore it
if ( tagFlag && strcmp(tmpStr, endTag) == 0 ) {
clearStr(tmpStr);
tagFlag = false;
dataFlag = false;
}
}
if (dataFlag) {
// Add data char to string
addChar(inChar, dataStr);
}
}
// If a LF, process the line
if (inChar == 10 ) {
/*
Serial.print("tagStr: ");
Serial.println(tagStr);
Serial.print("dataStr: ");
Serial.println(dataStr);
*/
// Find specific tags and print data
if (matchTag("<temp_f>")) {
Serial.print("Temp: ");
Serial.print(dataStr);
}
if (matchTag("<relative_humidity>")) {
Serial.print(", Humidity: ");
Serial.print(dataStr);
}
if (matchTag("<pressure_in>")) {
Serial.print(", Pressure: ");
Serial.print(dataStr);
Serial.println("");
}
// Clear all strings
clearStr(tmpStr);
clearStr(tagStr);
clearStr(dataStr);
// Clear Flags
tagFlag = false;
dataFlag = false;
}
}
/////////////////////
// Other Functions //
/////////////////////
// Function to clear a string
void clearStr (char* str) {
int len = strlen(str);
for (int c = 0; c < len; c++) {
str[c] = 0;
}
}
//Function to add a char to a string and check its length
void addChar (char ch, char* str) {
char *tagMsg = "<TRUNCATED_TAG>";
char *dataMsg = "-TRUNCATED_DATA-";
// Check the max size of the string to make sure it doesn't grow too
// big. If string is beyond MAX_STRING_LEN assume it is unimportant
// and replace it with a warning message.
if (strlen(str) > MAX_STRING_LEN - 2) {
if (tagFlag) {
clearStr(tagStr);
strcpy(tagStr,tagMsg);
}
if (dataFlag) {
clearStr(dataStr);
strcpy(dataStr,dataMsg);
}
// Clear the temp buffer and flags to stop current processing
clearStr(tmpStr);
tagFlag = false;
dataFlag = false;
} else {
// Add char to string
str[strlen(str)] = ch;
}
}
// Function to check the current tag for a specific string
boolean matchTag (char* searchTag) {
if ( strcmp(tagStr, searchTag) == 0 ) {
return true;
} else {
return false;
}
}
Does the US national weather service carry forecasts for Australia though? OP is located in Sydney,Australia.
Thanks Guys,
The XML parser looks great - Not sure if it can be adapted to the Weather Underground data which is JSON but i will give it a go and see if i have any joy
Craig
A quick google shows lots of pre-built json parsers for arduino so you dont have to re-invent the wheel.
rw950431:
Does the US national weather service carry forecasts for Australia though? OP is located in Sydney,Australia.
The point of my post is to show getting weather data from a weather web page. Australia has weather pages of their own. The same methods might be used in the weather underground feed. There is also an application called TextFinder that might be of use.