I need some of your help...
I made a small sketch for testing the ESP8266 WebServer and it does not completely do what I want.
When I open / it displays LED_BUILTIN is off and the button "turn on". Wen I klick "turn on" the LED turns and /off will be loaded. /off displays that the LED is off but it still displays the "turn on" button...
As soon as I klick the button again or press reload the button will be correct.
I tried many things (spent half of the day) but I cannot come to any conclusion.
I need HELP 
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
const char* ssid = "YOUR-SSID";
const char* password = "YOUR-PSK";
const char* ESPHostname = "esp-ws-test";
String LEDState = "off";
String html = "";
ESP8266WebServer WebServer(80);
void setup() {
Serial.begin(74880);
pinMode(LED_BUILTIN, OUTPUT);
digitalWrite(LED_BUILTIN, HIGH);
WiFi.hostname(ESPHostname);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
// Print local IP address and start web server
Serial.println();
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
WebServer.onNotFound([](){
WebServer.send(404, "text/plain", "404 (noop)");
});
WebServer.on("/", []() {
WebServer.send(200, "text/html", html);
});
WebServer.on("/on", []() {
WebServer.send(200, "text/html", html);
LEDState = "on";
digitalWrite(LED_BUILTIN,LOW);
Serial.println(LEDState);
});
WebServer.on("/off", []() {
WebServer.send(200, "text/html", html);
LEDState = "off";
digitalWrite(LED_BUILTIN,HIGH);
Serial.println(LEDState);
});
WebServer.begin();
}
void loop(){
html = "<!DOCTYPE html><html>";
html += "<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">";
html += "<link rel=\"icon\" href=\"data:,\">";
html += "<style>html {font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}";
html += ".button {background-color: #195B6A; border: none; color: white; padding: 16px 40px;";
html += "text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}";
html += ".button2 {background-color: #77878A;}</style></head>";
html += "<body><h1>Internal LED-Switch via WebServer</h1>";
html += "<p>Current LED - State: <b><em>" + LEDState + "</em></b></p>";
if (LEDState == "off") {
html += "<p><a href=\"/on\"><button class=\"button\">Turn ON</button></a></p></body></html>"; // for LEDState = off turn on
} else {
html += "<p><a href=\"/off\"><button class=\"button button2\">Turn OFF</button></a></p></body></html>"; // for LEDState = on turn off
}
WebServer.handleClient(); // start WebServer
}
Web pages do not update magically. You need to DO something to make it update. This is typically done using AJAX or some other asynchronous process to periodically check with the server to see if anything has changed, and update the display if so.
Regards,
Ray L.
Ray,
I like magics although I don't believe in them any longer 
Hitting the button opens a new website either /on or /off but in that newly opened website (let's say /on) the button still displays "off" until I hit it again or until I hit reload. The status of the LED is correctly displayed already at the first time.
Thanks
Florian
you could try to get data with fetch-API and modify the displayed data with Javascript
you will need
- a JavaScript with fetch
- a resource/page on your webserver to provide that data
- identify in the html the areas which should be modified by the JavaScript
based on your name: are you able to read German? if yes, in part 3 of this tutorial it is explained in more detail:
https://werner.rothschopf.net/201809_arduino_esp8266_server_client_0.htm
I couldn't get your code to run on my ESP, so don't know your issue. Below is some example code that has buttons and keeps track of the button/led state. Note that the hi/low is reversed for the LED on my WeMOS development board.
/*********
Rui Santos
Complete project details at http://randomnerdtutorials.com
*********/
// Load Wi-Fi library
#include <ESP8266WiFi.h>
// Replace with your network credentials
const char* ssid = "xxxxxxx";
const char* password = "xxxxxxxxxx";
// Set web server port number to 80
WiFiServer server(80); //ESP-2DF783
// Variable to store the HTTP request
String header;
// Auxiliar variables to store the current output state
String output2State = "off"; //2
String output4State = "off";
// Assign output variables to GPIO pins
const int output2 = 2;
const int output4 = 4;
// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0;
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;
void setup() {
Serial.begin(115200);
// Initialize the output variables as outputs
pinMode(output2, OUTPUT);
pinMode(output4, OUTPUT);
// Set outputs to LOW
digitalWrite(output2, LOW);
digitalWrite(output4, LOW);
// Connect to Wi-Fi network with SSID and password
Serial.print("Connecting to ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
// Print local IP address and start web server
Serial.println("");
Serial.println("WiFi connected.");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
server.begin();
}
void loop(){
WiFiClient client = server.available(); // Listen for incoming clients
if (client) { // If a new client connects,
Serial.println("New Client."); // print a message out in the serial port
String currentLine = ""; // make a String to hold incoming data from the client
currentTime = millis();
previousTime = currentTime;
while (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
currentTime = millis();
if (client.available()) { // if there's bytes to read from the client,
char c = client.read(); // read a byte, then
Serial.write(c); // print it out the serial monitor
header += c;
if (c == '\n') { // if the byte is a newline character
// if the current line is blank, you got two newline characters in a row.
// that's the end of the client HTTP request, so send a response:
if (currentLine.length() == 0) {
// HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
// and a content-type so the client knows what's coming, then a blank line:
client.println("HTTP/1.1 200 OK");
client.println("Content-type:text/html");
client.println("Connection: close");
client.println();
// turns the GPIOs on and off
if (header.indexOf("GET /2/on") >= 0) {
Serial.println("GPIO 2 on");
output2State = "on";
digitalWrite(output2, HIGH);
} else if (header.indexOf("GET /2/off") >= 0) {
Serial.println("GPIO 2 off");
output2State = "off";
digitalWrite(output2, LOW);
} else if (header.indexOf("GET /4/on") >= 0) {
Serial.println("GPIO 4 on");
output4State = "on";
digitalWrite(output4, HIGH);
} else if (header.indexOf("GET /4/off") >= 0) {
Serial.println("GPIO 4 off");
output4State = "off";
digitalWrite(output4, LOW);
}
// Display the HTML web page
client.println("<!DOCTYPE html><html>");
client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
client.println("<link rel=\"icon\" href=\"data:,\">");
// CSS to style the on/off buttons
// Feel free to change the background-color and font-size attributes to fit your preferences
client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
client.println(".button2 {background-color: #77878A;}</style></head>");
// Web Page Heading
client.println("<body><h1>ESP8266 Web Server</h1>");
// Display current state, and ON/OFF buttons for GPIO 2
client.println("<p>GPIO 2 - State " + output2State + "</p>");
// If the output5State is off, it displays the ON button
if (output2State=="off") {
client.println("<p><a href=\"/2/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/2/off\"><button class=\"button button2\">OFF</button></a></p>");
}
// Display current state, and ON/OFF buttons for GPIO 4
client.println("<p>GPIO 4 - State " + output4State + "</p>");
// If the output4State is off, it displays the ON button
if (output4State=="off") {
client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
}
client.println("</body></html>");
// The HTTP response ends with another blank line
client.println();
// Break out of the while loop
break;
} else { // if you got a newline, then clear currentLine
currentLine = "";
}
} else if (c != '\r') { // if you got anything else but a carriage return character,
currentLine += c; // add it to the end of the currentLine
}
}
}
// Clear the header variable
header = "";
// Close the connection
client.stop();
Serial.println("Client disconnected.");
Serial.println("");
}
}