Air quality sensor sending data to iPhone app

[pietro-b21]

Hi. I would like to build an outdoor air quality monitor that can send data via Bluetooth or wifi to an app for iOS that I will code to receive and display the data.

• I need some suggestions concerning what material to buy. More specifically what would be a good choice for the sensor considering I would like to measure mainly CO2, particulate and VOC (temperature and humidity are a plus).
• Also, I have already an ESP8233 module and would like to know if it is a good option to pair it with the sensor and send data to the iPhone app.
• Suggestions are also welcome as far as the sending and receiving data part is concerned, especially if there is some material and documentation on how to develop such features with swift.

[Nick_Pyner]

You appear to be having some language problems. I assume you mean an ESP8266. These are microcontrollers in their own right, rather than merely a "module" and, depending on the version, may be all you need. If it has insufficient i/o for all your sensor connections, you can probably replace it with one that has sufficient, like the NodeMCU, for just a few dollars.

A Beginner's Guide to the ESP8266

[hammy]

The difficulty will be the iPhone app part - how will you write that ?

There are a few examples out there with communication to phones from the 8266 - google !!

[srnet]

Where exactly is the air quality sensor going to be ?

Will it always be in range of your WiFi or close enough to the iPhone for Bluetooth to work ?

[pietro-b21]

Yes, my bad, I definitely mean the ESP8266.

[pietro-b21]

The sensor will likely stay on my balcony. I was also thinking that maybe a better alternative than sending data directly between the esp8266 and the iPhone, it would maybe be better to send the data to a server and retrieve them from there. They would be available even when I am not around and maybe it's also an easier solution to implement, rather than having a direct data stream.

[pietro-b21]

I have coded so far a very simple app in Swift and deployed a nodeJS server on Heroku to which I am trying to send some dummy data.
I am currently working on the code for the ESP8266 board and trying to post a JSON object to the server.
My problem is that I am not posting anything or I am posting a wrong JSON object, as Heroku logs show a 500 error and I am getting an empty object on the serial monitor.
My understanding is that I am hitting the server correctly, but either the format of the JSON object is wrong or I am missing something in my post method.

Could you please check my code and help me find a solution?

Here is my code:

#include <ArduinoJson.h>
#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClientSecure.h> 
#include <WiFiClient.h> 

const char *host = "appname.herokuapp.com";
const char* serverName = "https://appname.herokuapp.com";
const char* ssid = "*******"; 
const char* password = "*******";

void setup() {
  Serial.begin(9600);

  WiFi.begin(ssid, password);
  Serial.println("Connecting");
  while(WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to WiFi network with IP Address: ");
  Serial.println(WiFi.localIP());
}

void loop() {

  if(WiFi.status()== WL_CONNECTED) {
      std::unique_ptr<BearSSL::WiFiClientSecure>client(new BearSSL::WiFiClientSecure);
      client->setInsecure();
     
      HTTPClient https;

      DynamicJsonDocument doc(512);
      JsonObject object = doc.to<JsonObject>();
      object["temperature"] = 30;
      String data;
      serializeJsonPretty(object, data);

      Serial.println(data);

      https.addHeader("Content-Type", "application/json; charset=UTF-8");
      https.addHeader("Host:", host);

      if (https.begin(*client, serverName)) {
          Serial.print("[HTTPS] POST...\n");
          int httpCode = https.POST(data);

          if (httpCode > 0) {
            Serial.printf("[HTTPS] POST... code: %d\n", httpCode);
            
            if (httpCode == HTTP_CODE_OK || httpCode == HTTP_CODE_MOVED_PERMANENTLY) {
              String payload = https.getString();
              Serial.println(payload);

            } else {
              Serial.printf("[HTTPS] POST... failed, error: %s\n", https.errorToString(httpCode).c_str());
            }

          } else  {
            Serial.printf("[HTTPS] POST... failed, error: %s\n", https.errorToString(httpCode).c_str());
          }
          https.end();

    } else {
      Serial.printf("[HTTPS] Unable to connect\n");
    } 
  }
  delay(5000);
}

[pietro-b21]

I have solved the issue by moving the "POST" method out of the if statement. This is my solution:

void loop() {

  if(WiFi.status()== WL_CONNECTED) {

    std::unique_ptr<BearSSL::WiFiClientSecure>client(new BearSSL::WiFiClientSecure);
    client->setInsecure();
 
    HTTPClient https;

    DynamicJsonDocument doc(512);
    JsonObject object = doc.to<JsonObject>();
      
    object["temperature"] = 32;

    String data;
    serializeJsonPretty(object, data);

    Serial.println(data);

    https.begin(*client, serverName);
    https.addHeader("Content-Type", "application/json; charset=UTF-8");       
      
    int httpCode = https.POST(data);

    if (httpCode == 200) {
      Serial.println("POST succeeded with code:");
      Serial.println(httpCode);
      
    } else if (httpCode != 200) {
      Serial.println("POST failed with code:");
      Serial.println(httpCode);

    } else {
      Serial.println("Unknown error");
    }

    String payload = https.getString();
    Serial.println(payload);

    https.end();
  }
  delay(10000);
}