Arduino Giga use QSPI flash and wifi together

efs95 · January 3, 2024, 8:35am

Hello everyone,
I wanted to ask if anyone had success using the 16mb QSPI flash while also using the WiFi.

I managed to put a file on the flash storage (as described here https://docs.arduino.cc/tutorials/giga-r1-wifi/cheat-sheet#flash) and I am also able to read it, as long as the wifi is NOT in use. For that I use the following script:

#include "QSPIFBlockDevice.h"
#include "MBRBlockDevice.h"
#include "FATFileSystem.h"

void setup() {
  // put your setup code here, to run once:
  while(!Serial) {};

  Serial.println("Start setup");

  QSPIFBlockDevice root;
  mbed::FATFileSystem ota("ota");
  mbed::MBRBlockDevice ota_data(&root, 2);

  Serial.println("Try to mount:");

  ota.mount(&ota_data);

  Serial.println("All setup, start reading...");

  FILE* f = fopen("/ota/myFile.txt", "r");
  Serial.print("Errno: ");
  Serial.println(errno);
  Serial.print("Opened file: ");
  Serial.println((int)f);

  const int bufferSize = 512;
  char buffer[bufferSize];
  int size = 0;
  do {
    size = fread(buffer, 1, bufferSize, f);
    Serial.write(buffer, size);
  } while(size == bufferSize);

  fclose(f);
  ota.unmount();
}

void loop() {
  // put your main code here, to run repeatedly:
}

However when I try to read from the filesystem when I also use the WiFi, then I am unable to open the file, the file pointer is zero. The WiFi Network does get created successfully. Since the WiFi Firmware seems to be also stored on the flash, I assume there is some kind of problem with trying to access the flash twice? Sadly I am not sure how to fix it. My Sketch (does not work):

#include "QSPIFBlockDevice.h"
#include "MBRBlockDevice.h"
#include "FATFileSystem.h"

#include <SPI.h>
#include <WiFi.h>

char ssid[] = "myNetwork";  // your network SSID (name)
char pass[] = "myPassword";  // your network password (use for WPA, or use as key for WEP)
int keyIndex = 0;           // your network key index number (needed only for WEP)

int status = WL_IDLE_STATUS;

void setup() {
  // put your setup code here, to run once:
  while(!Serial) {};

  // print the network name (SSID);
  Serial.print("Creating access point named: ");
  Serial.println(ssid);

  status = WiFi.beginAP(ssid, pass);

  if (status != WL_AP_LISTENING) {
      Serial.println("Creating access point failed");
      // don't continue
      while (true)
      ;
  }

  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your WiFi IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print where to go in a browser:
  Serial.print("To see this page in action, open a browser to http://");
  Serial.println(ip);


  Serial.println("Start setup");

  QSPIFBlockDevice root;
  mbed::FATFileSystem ota("ota");
  mbed::MBRBlockDevice ota_data(&root, 2);

  Serial.println("Try to mount:");

  ota.mount(&ota_data);

  Serial.println("All setup, start reading...");

  FILE* f = fopen("/ota/myFile.txt", "r");
  Serial.print("Errno: ");
  Serial.println(errno);
  Serial.print("Opened file: ");
  Serial.println((int)f);

  const int bufferSize = 512;
  char buffer[bufferSize];
  int size = 0;
  do {
    size = fread(buffer, 1, bufferSize, f);

    Serial.write(buffer, size);
  } while(size == bufferSize);

  fclose(f);
  ota.unmount();
}

void loop() {
  // put your main code here, to run repeatedly:
}

My Questions:

Did anyone already read a file from the flash storage while using the WiFi? If yes could you provide me with some tips about how to do it?
Does anyone know if my first sketch (which does work because WiFi is not used) uses the API as intended? Sadly I did not find any examples, so it is my best guess on how to do things but I am not quite sure.

Thank you!

With kind regards
efs95

anon6971307 · January 3, 2024, 1:34pm

Hi, take a look at the Arduino_Portenta_OTA library GitHub - arduino-libraries/Arduino_Portenta_OTA: OTA on the Arduino Portenta. It uses WiFi to download new sketches to the QSPI from a file server.
As I understand it, WiFi and OTA have separate partitions. Check out the QSPI format example for details ArduinoCore-mbed/libraries/STM32H747_System/examples/QSPIFormat/QSPIFormat.ino at ff3334d06daffe01479eb2a975f93dfa0af3ae95 · arduino/ArduinoCore-mbed · GitHub

efs95 · January 4, 2024, 2:58pm

Hello Steve,

thank you for your help!
When creating the sketch I did already take a look at the QSPIFormat example, however the link to the Arduino Portenta OTA Library was new for me.
With that I managed to solve the problem:

In the sketch above I did create a
QSPIFBlockDevice root;
in the same way as the QSPIFormat example also does it. This does work fine as long as the wifi is not used in parallel. It seems as there can only be one BlockDevice for the flash storage, so as soon as the wifi is used (which has its firmware on the flash storage), the BlockDevice does already exist and can not be created again (it actually doesnt throw an error when creating, however it is impossible to do any file interactions).
The right way to deal with that seems to be the way the Portenta OTA library does do it:
mbed::BlockDevice* raw_qspi = mbed::BlockDevice::get_default_instance();
With this pointer the access to the Flash storage works fine, the file does get read successfully (no matter if wifi does get used or not).

Thank you very much for providing this helpful link!
With kind regards
efs95

PS: The corrected example script:

#include "QSPIFBlockDevice.h"
#include "MBRBlockDevice.h"
#include "FATFileSystem.h"

#include <SPI.h>
#include <WiFi.h>

char ssid[] = "myNetwork";  // your network SSID (name)
char pass[] = "myPassword";  // your network password (use for WPA, or use as key for WEP)
int keyIndex = 0;           // your network key index number (needed only for WEP)

int status = WL_IDLE_STATUS;

void setup() {
  // put your setup code here, to run once:
  while(!Serial) {};

  // print the network name (SSID);
  Serial.print("Creating access point named: ");
  Serial.println(ssid);

  status = WiFi.beginAP(ssid, pass);

  if (status != WL_AP_LISTENING) {
      Serial.println("Creating access point failed");
      // don't continue
      while (true)
      ;
  }

  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your WiFi IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print where to go in a browser:
  Serial.print("To see this page in action, open a browser to http://");
  Serial.println(ip);


  Serial.println("Start setup");

  mbed::BlockDevice* raw_qspi = mbed::BlockDevice::get_default_instance();	// <- This line changed, use of the already existing BlockDevice
  mbed::FATFileSystem ota("ota");
  mbed::MBRBlockDevice ota_data(raw_qspi, 2);					// Use the BlockDevice specified above

  Serial.println("Try to mount:");

  ota.mount(&ota_data);

  Serial.println("All setup, start reading...");

  FILE* f = fopen("/ota/myFile.txt", "r");
  Serial.print("Errno: ");
  Serial.println(errno);
  Serial.print("Opened file: ");
  Serial.println((int)f);

  const int bufferSize = 512;
  char buffer[bufferSize];
  int size = 0;
  do {
    size = fread(buffer, 1, bufferSize, f);

    Serial.write(buffer, size);
  } while(size == bufferSize);

  fclose(f);
  ota.unmount();
}

void loop() {
  // put your main code here, to run repeatedly:
}

JoeHuber · November 29, 2024, 9:31pm

efs95 And thanks to your help I figured out a similar and even more basic issue I was having.

The QSPI FLASH must be formatted and partitioned before the WiFi OTA updater will work. This basic requirement isn't mentioned in the WiFi OTA Updater documentation and you get a -3 error when it tries to access the FLASH file system.

So for the benefit of others here's the necessary sequence.

Run File > Examples > STM32H747_System > QSPIFormat (Partition scheme 1 is good.)
Run File > Examples > STM32H747_System > WiFiFirmwareUpdater (Do this second otherwise it gets deleted when you Format and Partition
Now run the OTA updater code.

This sequence is slightly different than that given in the Flash section of the Cheat Sheet but it leaves you with a functioning WiFi vs the cheat sheet having overwritten it.

schnoberts · March 25, 2025, 7:10pm

I found that I didn’t have to use WiFi to get this issue . For me it seems to be a product of the new mcuboot based bootloader which accesses the static qspi instance during the boot . As far as I can tell none of the examples have been updated to reflect this.

Found the same issue today in the debugger trying to work out why my qspi code failed after a bootloader update.

JoeHuber · March 27, 2025, 11:28pm

It seems the Arduino folks may we working to resolve this.

Topic		Replies	Views
Problems using the NOR flash for storage GIGA R1 WiFi	3	841	February 3, 2025
Issue Integrating QSPI Flash Memory with WiFi on Arduino: Failed to Mount WiFi Firmware Filesystem GIGA R1 WiFi	1	129	July 11, 2024
Accessing the QSPI Flash on the Giga GIGA R1 WiFi	5	1590	November 19, 2024
Giga Wifi and QSPIF user space - works GIGA R1 WiFi	0	77	January 23, 2025
Giga R1 Wifi firmware mounting failure & crashing on writing to Fashl GIGA R1 WiFi	4	198	March 9, 2025

Arduino Giga use QSPI flash and wifi together

Related topics