Bn-880 GPS not working?

Projects Programming
1

I've used this GPS before but now when I need it the most it stops working. When I run the demo sketch in the TinyGPSPlus lib it says in serial monitor "No GPS detected: check wiring". I dont think I did anything wrong with the wiring but I've noticed that when I do connect the tx and rx of the GPS to the arduino it stops blinking the blue light. When I flip it, it starts blinking again but it doesn't send anything in the serial monitor. I can tell its working and not the modules fault because I got u-connect and tried it on there and it showed me my location and everything. I even tried different baud rates ranging from 4800 - 115200. Here is my wiring:

GPS Arduino

SDA (pin 1) ---> SDA (A4)
GND (pin 2) ----> GND
TX (pin 3) ----> D3
RX (pin 4) ----> D4
VCC (pin 5) ----> 5v
SCL (pin 6) ----> SCL (A5)

Here is the demo sketch I used:

#include <TinyGPSPlus.h>
#include <SoftwareSerial.h>
/*
   This sample sketch demonstrates the normal use of a TinyGPSPlus (TinyGPSPlus) object.
   It requires the use of SoftwareSerial, and assumes that you have a
   4800-baud serial GPS device hooked up on pins 4(rx) and 3(tx).
*/
static const int RXPin = 4, TXPin = 3;
static const uint32_t GPSBaud = 4800;

// The TinyGPSPlus object
TinyGPSPlus gps;

// The serial connection to the GPS device
SoftwareSerial ss(RXPin, TXPin);

void setup()
{
  Serial.begin(115200);
  ss.begin(GPSBaud);

  Serial.println(F("DeviceExample.ino"));
  Serial.println(F("A simple demonstration of TinyGPSPlus with an attached GPS module"));
  Serial.print(F("Testing TinyGPSPlus library v. ")); Serial.println(TinyGPSPlus::libraryVersion());
  Serial.println(F("by Mikal Hart"));
  Serial.println();
}

void loop()
{
  // This sketch displays information every time a new sentence is correctly encoded.
  while (ss.available() > 0)
    if (gps.encode(ss.read()))
      displayInfo();

  if (millis() > 5000 && gps.charsProcessed() < 10)
  {
    Serial.println(F("No GPS detected: check wiring."));
    while(true);
  }
}

void displayInfo()
{
  Serial.print(F("Location: ")); 
  if (gps.location.isValid())
  {
    Serial.print(gps.location.lat(), 6);
    Serial.print(F(","));
    Serial.print(gps.location.lng(), 6);
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.print(F("  Date/Time: "));
  if (gps.date.isValid())
  {
    Serial.print(gps.date.month());
    Serial.print(F("/"));
    Serial.print(gps.date.day());
    Serial.print(F("/"));
    Serial.print(gps.date.year());
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.print(F(" "));
  if (gps.time.isValid())
  {
    if (gps.time.hour() < 10) Serial.print(F("0"));
    Serial.print(gps.time.hour());
    Serial.print(F(":"));
    if (gps.time.minute() < 10) Serial.print(F("0"));
    Serial.print(gps.time.minute());
    Serial.print(F(":"));
    if (gps.time.second() < 10) Serial.print(F("0"));
    Serial.print(gps.time.second());
    Serial.print(F("."));
    if (gps.time.centisecond() < 10) Serial.print(F("0"));
    Serial.print(gps.time.centisecond());
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.println();
}

Thanks for reading!

3

Hi, @rclare15

Your controller config;

The wiring config;

Tx goes to RX and RX goes to Tx.

TX (pin 3) ----> D4
RX (pin 4) ----> D3

Tom.. :grinning: :+1: :coffee: :australia:

4

Oh yea I did originally do TX to TX but that didn't work.

5

@rclare15 I also had problems with another gps shield only a few days and still hours ago with another module and sim but try other gpio´s like 7 and 8 to communicate instead of the basic rx and tx i/o´s. It worked on my board and I´ve surched for it several days already.