Button debouncing using bit shifting

[DaveX]

@AlexA

I read somewhere that the sketch I posted was introduced by Jack Ganssle in his article about button debouncing Debouncing, hardware and software, part 2.

The relevant Jack Ganssle code is:

// from https://www.ganssle.com/debouncing-pt2.htm
// Idea courtesy Ganssle Group. Called from a 5ms timer,
// the debounced state only ever changes when the pin
// has been stable for 40ms. Initialize debounced_state
// to whatever is  "inactive" for the system (HIGH or LOW)
//
uint8_t DebouncePin(uint8_t pin)
{
  static  uint8_t debounced_state = LOW;
  static  uint8_t candidate_state = 0;
  candidate_state = candidate_state << 1 | digitalRead(pin);
  if  (candidate_state == 0xff)
    debounced_state = HIGH;
  else  if (candidate_state == 0x00)
    debounced_state = LOW;
  return  debounced_state;
}

without this strange end condition:

@AlexA

  return (btnState == 0xFFF0);

that was highlighted in:

@sterretje

Note that the state will never become 0xFFF0.

Note:
0xFFFF and 0x0000 (the last line in each block) will be repeated endlessly till the button changes from pressed to released or vice versa.

The awkward value of using 0xFFF0 as the end condition is that it sort of does the work of state change detection--in a bounce-free release, there's only one iteration where 0xFFF0 matches the record of history. If there is a bounce on release, the release would not match and be ignored.

Jack Ganssle's code does debouncing, not the uncertain falling-edge-detection that the OP's code attempts.

If the goal is clean edge detection, consider rate-limiting the edge detection:

@johnwasser

const byte ButtonPin = 2;
const unsigned long DebounceTime = 30;

boolean ButtonWasPressed;  // Defaults to 'false'
unsigned long ButtonStateChangeTime = 0; // Debounce timer

void setup()
{
  pinMode (ButtonPin, INPUT_PULLUP);  // Button between Pin and Ground
}

void loop()
{
  unsigned long currentTime = millis();

  boolean buttonIsPressed = digitalRead(ButtonPin) == LOW;  // Active LOW

  // Check for button state change and do debounce
  if (buttonIsPressed != ButtonWasPressed &&
      currentTime - ButtonStateChangeTime > DebounceTime)
  {
    // Button state has changed
    ButtonStateChangeTime = currentTime;
    ButtonWasPressed = buttonIsPressed;

    if (ButtonWasPressed)
    {
      // Button was just pressed
    }
    else
    {
      // Button was just released
    }
  }
}