Can't get i2C SSD1306 to display Ultimate GPS data

Hello,
I am completely new to programming so you will have to bear with my stupidity, but I have been trying to make an simple speedometer with an OLED and GPS readings. Using my little knowledge I compiled this code based on the Adafruit Parsing Sketch and my own work with the same OLED. I have managed to get them to work separately but when combined the OLED does not respond whatsoever and only sometimes I’ve got the GPS to work (somehow I lost the code that did work).
Please could you offer some help?

//speed o meter code using OLED, first attempt, using example parsing code from adafruit 

#include <Adafruit_GPS.h>
#include <SoftwareSerial.h>
#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

int OLED_RESET = 4;
Adafruit_SSD1306 display(OLED_RESET);
SoftwareSerial mySerial(3, 2);
Adafruit_GPS GPS(&mySerial);


// Set GPSECHO to 'false' to turn off echoing the GPS data to the Serial console
// Set to 'true' if you want to debug and listen to the raw GPS sentences
#define GPSECHO  true

void setup() {
  // put your setup code here, to run once:
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C); // initialize with the I2C addr 0x3C (for the 128x32)
  display.setTextSize(1); // Set the text size
  display.setTextColor(WHITE); // Set the text color
  display.print("Hello");

// connect at 115200 so we can read the GPS fast enough and echo without dropping chars
  // also spit it out
  Serial.begin(115200);
  delay(5000);
  Serial.println("Adafruit GPS library basic test!");

  // 9600 NMEA is the default baud rate for Adafruit MTK GPS's- some use 4800
  GPS.begin(9600);

  // uncomment this line to turn on RMC (recommended minimum) and GGA (fix data) including altitude
  GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCGGA);
  // uncomment this line to turn on only the "minimum recommended" data
  //GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCONLY);
  // For parsing data, we don't suggest using anything but either RMC only or RMC+GGA since
  // the parser doesn't care about other sentences at this time

  // Set the update rate
  GPS.sendCommand(PMTK_SET_NMEA_UPDATE_1HZ);   // 1 Hz update rate
  // For the parsing code to work nicely and have time to sort thru the data, and
  // print it out we don't suggest using anything higher than 1 Hz

  // Request updates on antenna status, comment out to keep quiet
  GPS.sendCommand(PGCMD_ANTENNA);

  delay(1000);
  // Ask for firmware version
  mySerial.println(PMTK_Q_RELEASE);
}  

uint32_t timer = millis();
void loop() {
  // put your main code here, to run repeatedly:
{
    char c = GPS.read();
  // if you want to debug, this is a good time to do it!
  if ((c) && (GPSECHO))
    Serial.write(c);

  // if a sentence is received, we can check the checksum, parse it...
  if (GPS.newNMEAreceived()) {
    
    // so be very wary if using OUTPUT_ALLDATA and trytng to print out data
    //Serial.println(GPS.lastNMEA());   // this also sets the newNMEAreceived() flag to false

    if (!GPS.parse(GPS.lastNMEA()))   // this also sets the newNMEAreceived() flag to false
      return;  // we can fail to parse a sentence in which case we should just wait for another
  }

  // approximately every 2 seconds or so, print out the current stats
  if (millis() - timer > 2000) {
    timer = millis(); // reset the timer

    Serial.print("\nTime: ");
    if (GPS.hour < 10) { Serial.print('0'); }
    Serial.print(GPS.hour, DEC); Serial.print(':');
    if (GPS.minute < 10) { Serial.print('0'); }
    Serial.print(GPS.minute, DEC); Serial.print(':');
    if (GPS.seconds < 10) { Serial.print('0'); }
    Serial.print(GPS.seconds, DEC); Serial.print('.');
    if (GPS.milliseconds < 10) {
      Serial.print("00");
    } else if (GPS.milliseconds > 9 && GPS.milliseconds < 100) {
      Serial.print("0");
    }
    Serial.println(GPS.milliseconds);
    Serial.print("Date: ");
    Serial.print(GPS.day, DEC); Serial.print('/');
    Serial.print(GPS.month, DEC); Serial.print("/20");
    Serial.println(GPS.year, DEC);
    Serial.print("Fix: "); Serial.print((int)GPS.fix);
    Serial.print(" quality: "); Serial.println((int)GPS.fixquality);
    if (GPS.fix) {
      Serial.print("Location: ");
      Serial.print(GPS.latitude, 4); Serial.print(GPS.lat);
      Serial.print(", ");
      Serial.print(GPS.longitude, 4); Serial.println(GPS.lon);

      Serial.print("Speed (knots): "); Serial.println(GPS.speed);
      Serial.print("Angle: "); Serial.println(GPS.angle);
      Serial.print("Altitude: "); Serial.println(GPS.altitude);
      Serial.print("Satellites: "); Serial.println((int)GPS.satellites);

      
    float velocity;
    velocity = GPS.speed*1.15078;
 

if (GPS.fix) {

  display.setCursor(0,0);
  display.print("Speed");
  display.setCursor(50,0); 
  display.print(velocity,1); 
  display.setCursor(100,0);
  display.print("mph"); 
  display.display(); 
}
}
}
}
}

My gut feeling is I should be using a SPI OLED to solve this problem but I am working on a budget so if there is anyway this could work please help!

There is no need to swap to an SPI OLED, cant see why that would help myself.

Its essential when working on projects like this that you can show that the seperate bits of hardware work independantly and reliably. That the parts 'used' to work wont help much, you need to know now. There are normally example programs in the examples folder of the libraries you are using.

You did not say which Arduino you are using.

If you want a working speedo program, I have one that prints the speed in large characters on the SSD1306 or SH1106 OLED.

OLED uses the U8G2 which provides a flicker free screen update.

GPS uses the TinyGPS++ library which makes NMEA parsing a lot easier and works with most GPSs too.

srnet:
If you want a working speedo program, I have one that prints the speed in large characters on the SSD1306 or SH1106 OLED.

OLED uses the U8G2 which provides a flicker free screen update.

GPS uses the TinyGPS++ library which makes NMEA parsing a lot easier and works with most GPSs too.

Forgot to say it is an Arduino Uno so could well be a memory problem. Use of different libraries could be really helpful! Is it possible for you to send me more on this?
Thanks in advance

Try this, runs on a 8Mhz 3.3V Prp Mini, adjust GPS pins to suit;

/*******************************************************************************************************
  Programs for Arduino - Copyright of the author Stuart Robinson - 12/10/20

  This program is supplied as is, it is up to the user of the program to decide if the program is
  suitable for the intended purpose and free from errors.
*******************************************************************************************************/


/*******************************************************************************************************
  Program Operation -  This program uses a GPS to indicate speed, should work with most GPSs. Speed update
  rate approx once per second. GPS characters are output to serial monitor when checking for update from
  GPS. Prints speed in large text on an SSD1306 or SH1106 OLED.

  Serial monitor baud rate is set at 115200.
*******************************************************************************************************/

#include <TinyGPS++.h>                             //get library here > http://arduiniana.org/libraries/tinygpsplus/
TinyGPSPlus gps;                                   //create the TinyGPS++ object

#define RXpin A3                                   //pin number for GPS RX input into Arduino - TX from GPS
#define TXpin A2                                   //pin number for GPS TX output from Arduino- RX into GPS

#include <SoftwareSerial.h>
SoftwareSerial GPSserial(RXpin, TXpin);

#include <U8g2lib.h>                               //get library here > https://github.com/olikraus/u8g2
#include <Wire.h>

U8G2_SSD1306_128X64_NONAME_1_HW_I2C disp(U8G2_R0, U8X8_PIN_NONE);   //use this line for 0.96" SSD1306 OLED
//U8G2_SH1106_128X64_NONAME_1_HW_I2C disp(U8G2_R0, U8X8_PIN_NONE);  //use this line for 1.3" SH1106 OLED

float GPSSpeed;                                    //Speed of GPS, mph

uint32_t startGetFixmS;
uint32_t endFixmS;


void loop()
{
  if (gpsWaitFix(5))
  {
    Serial.println();
    Serial.println();
    Serial.print(F("Fix time "));
    Serial.print(endFixmS - startGetFixmS);
    Serial.println(F("mS"));

    GPSSpeed = gps.speed.mph();

    Serial.print(F("Speed,"));
    Serial.print(GPSSpeed, 1);
    Serial.println();

    displayscreen1();            //print GPS data on display
    startGetFixmS = millis();    //have a fix, next thing that happens is checking for a fix, so restart timer
  }
  else
  {
    Serial.println();
    Serial.println();
    Serial.print(F("Timeout - No GPS Fix "));
    Serial.print( (millis() - startGetFixmS) / 1000 );
    Serial.println(F("s"));
  }
}


bool gpsWaitFix(uint16_t waitSecs)
{
  //waits a specified number of seconds for a fix, returns true for good fix

  uint32_t endwaitmS;
  uint8_t GPSchar;

  Serial.print(F("Wait GPS Fix "));
  Serial.print(waitSecs);
  Serial.println(F(" seconds"));

  endwaitmS = millis() + (waitSecs * 1000);

  while (millis() < endwaitmS)
  {
    if (GPSserial.available() > 0)
    {
      GPSchar = GPSserial.read();
      gps.encode(GPSchar);
      Serial.write(GPSchar);
    }

    if (gps.location.isUpdated() && gps.altitude.isUpdated() && gps.speed.isUpdated())
    {
      endFixmS = millis();                                //record the time when we got a new GPS update
      return true;
    }
  }

  return false;
}


void displayscreen1()
{
  disp.firstPage();
  do {
    disp.setCursor(25, 15);
    disp.print(F("Speedo"));
    disp.setCursor(10, 45);
    disp.print(GPSSpeed, 1);
    disp.print(F(" mph"));
  } while ( disp.nextPage() );
}


void displayscreen2()
{
  disp.firstPage();
  do {
    disp.setCursor(25, 15);
    disp.print(F("Speedo"));
    disp.setCursor(15, 45);
    disp.print(F("No GPS fix"));
  } while ( disp.nextPage() );
}


void setup()
{
  delay(1000);
  Serial.begin(115200);
  GPSserial.begin(9600);

  disp.begin();
  disp.setFont(u8g2_font_lubB14_tr);                         //use a large character font
  disp.clear();
  displayscreen2();
  disp.print(F("Display Ready"));

  Serial.println(F("72A_GPS_Speedo_With_Display Starting"));
  Serial.println();

  startGetFixmS = millis();
}

srnet:
Try this, runs on a 8Mhz 3.3V Prp Mini, adjust GPS pins to suit;

/*******************************************************************************************************

Programs for Arduino - Copyright of the author Stuart Robinson - 12/10/20

This program is supplied as is, it is up to the user of the program to decide if the program is
 suitable for the intended purpose and free from errors.
*******************************************************************************************************/

/*******************************************************************************************************
 Program Operation -  This program uses a GPS to indicate speed, should work with most GPSs. Speed update
 rate approx once per second. GPS characters are output to serial monitor when checking for update from
 GPS. Prints speed in large text on an SSD1306 or SH1106 OLED.

Serial monitor baud rate is set at 115200.
*******************************************************************************************************/

#include <TinyGPS++.h>                             //get library here > TinyGPS++ | Arduiniana
TinyGPSPlus gps;                                   //create the TinyGPS++ object

#define RXpin A3                                   //pin number for GPS RX input into Arduino - TX from GPS
#define TXpin A2                                   //pin number for GPS TX output from Arduino- RX into GPS

#include <SoftwareSerial.h>
SoftwareSerial GPSserial(RXpin, TXpin);

#include <U8g2lib.h>                               //get library here > GitHub - olikraus/u8g2: U8glib library for monochrome displays, version 2
#include <Wire.h>

U8G2_SSD1306_128X64_NONAME_1_HW_I2C disp(U8G2_R0, U8X8_PIN_NONE);   //use this line for 0.96" SSD1306 OLED
//U8G2_SH1106_128X64_NONAME_1_HW_I2C disp(U8G2_R0, U8X8_PIN_NONE);  //use this line for 1.3" SH1106 OLED

float GPSSpeed;                                    //Speed of GPS, mph

uint32_t startGetFixmS;
uint32_t endFixmS;

void loop()
{
 if (gpsWaitFix(5))
 {
   Serial.println();
   Serial.println();
   Serial.print(F("Fix time "));
   Serial.print(endFixmS - startGetFixmS);
   Serial.println(F(“mS”));

GPSSpeed = gps.speed.mph();

Serial.print(F(“Speed,”));
   Serial.print(GPSSpeed, 1);
   Serial.println();

displayscreen1();            //print GPS data on display
   startGetFixmS = millis();    //have a fix, next thing that happens is checking for a fix, so restart timer
 }
 else
 {
   Serial.println();
   Serial.println();
   Serial.print(F("Timeout - No GPS Fix "));
   Serial.print( (millis() - startGetFixmS) / 1000 );
   Serial.println(F(“s”));
 }
}

bool gpsWaitFix(uint16_t waitSecs)
{
 //waits a specified number of seconds for a fix, returns true for good fix

uint32_t endwaitmS;
 uint8_t GPSchar;

Serial.print(F(“Wait GPS Fix “));
 Serial.print(waitSecs);
 Serial.println(F(” seconds”));

endwaitmS = millis() + (waitSecs * 1000);

while (millis() < endwaitmS)
 {
   if (GPSserial.available() > 0)
   {
     GPSchar = GPSserial.read();
     gps.encode(GPSchar);
     Serial.write(GPSchar);
   }

if (gps.location.isUpdated() && gps.altitude.isUpdated() && gps.speed.isUpdated())
   {
     endFixmS = millis();                                //record the time when we got a new GPS update
     return true;
   }
 }

return false;
}

void displayscreen1()
{
 disp.firstPage();
 do {
   disp.setCursor(25, 15);
   disp.print(F(“Speedo”));
   disp.setCursor(10, 45);
   disp.print(GPSSpeed, 1);
   disp.print(F(" mph"));
 } while ( disp.nextPage() );
}

void displayscreen2()
{
 disp.firstPage();
 do {
   disp.setCursor(25, 15);
   disp.print(F(“Speedo”));
   disp.setCursor(15, 45);
   disp.print(F(“No GPS fix”));
 } while ( disp.nextPage() );
}

void setup()
{
 delay(1000);
 Serial.begin(115200);
 GPSserial.begin(9600);

disp.begin();
 disp.setFont(u8g2_font_lubB14_tr);                         //use a large character font
 disp.clear();
 displayscreen2();
 disp.print(F(“Display Ready”));

Serial.println(F(“72A_GPS_Speedo_With_Display Starting”));
 Serial.println();

startGetFixmS = millis();
}

Thank you so much! I’ve downloaded the libraries but am a little unsure how to write the constructor line. I think this is the one I need. How would I write it if SCL → A5, SDA → A4, and reset → 4?

//U8G2_SSD1306_128X32_UNIVISION_F_SW_I2C u8g2(U8G2_R0, /* clock=*/ SCL, /* data=*/ SDA, /* reset=*/ U8X8_PIN_NONE);

You dont need to change anything in the program apart from changing the allocations for the GPS pins.

Why did you think you needed to change the U8G2 constructor ?

srnet:
You dont need to change anything in the program apart from changing the allocations for the GPS pins.

Why did you think you needed to change the U8G2 constructor ?

Sorry I was overthinking things! Managed to get it working (still need to go outside to check for sure). Thanks for the code, this will be really useful to start a different project I was planning with some more components.