I made a clock for my parents, and I decided to post the code here.
Required hardware:
- DS3231 real-time clock
- LCD 16x2 display (one that does not use I2C)
- A speaker or buzzer for the chimes
- EDIT: And of course an Arduino.
- EDIT: You will also need a few resistors to hook everything up properly.
Optional hardware:
- A toggle switch (to turn Daylight Saving Time on and off)
What it does:
- Displays the date (month/day/year) and time (12 hour format)
- Calculates and displays the day of the week and week number
- Chimes every hour, on the hour (Westminster Chimes)
- When the Daylight Saving Time switch is turned on, it adds 1 hour to the time to be displayed and chimed
What it doesn't do:
- Allow you to set the time manually (you have to re-upload the sketch for that)
The code:
#include "Wire.h"
#include <LiquidCrystal.h>
// Make sure your pin numbers match these!
// RS EN D4 D5 D6 D7
LiquidCrystal lcd( 7, 6, 5, 4, 3, 2);
const byte DST_SWITCH_PIN = 8;
const byte SPEAKER_PIN = 9;
// variables for the current date and time
byte yy=0, mo=1, dd=0, wd=6;
byte hh=0, mi=0, ss=0;
byte hhTwelve = 12;
byte wn=52;
// other helpful variables
bool gotTheTime = false;
byte old_ss = 99, halfSec = 198, old_halfSec = 198;
unsigned long microsNow = 0UL;
unsigned long microsAtLastSecond = 0UL;
bool dstOn = false, old_dstOn = false;
// a buffer for text to be displayed
char buf[20] = "";
void setup() {
pinMode(DST_SWITCH_PIN, INPUT_PULLUP);
pinMode(SPEAKER_PIN, OUTPUT);
Wire.begin();
lcd.begin(16, 2);
// BEGINNING of code for setting the date and time
// If you wish to set the date and time,
// uncomment the following:
/*
// code to precisely set the external real-time clock
Wire.beginTransmission(0x68); // address DS3231
Wire.write(0x00); // select register
// NOTE: before you run this code, you *must*
// change the following numbers to the correct time!
// (plus a few seconds to allow for compilation, etc.)
Wire.write(numberToBcd( 0)); // seconds
Wire.write(numberToBcd(21)); // minutes
Wire.write(numberToBcd( 1)); // hours (use 24-hour format)
Wire.write(numberToBcd( 6)); // day of week (I use Mon=1 .. Sun=7)
Wire.write(numberToBcd( 9)); // day of month
Wire.write(numberToBcd( 4)); // month
Wire.write(numberToBcd(22)); // year (use only two digits)
Wire.endTransmission();
*/
// END of code for setting the date and time
/*
// define special characters for single cell numerals 10 through 12
byte singleCellTen[] = { 18, 21, 21, 21, 21, 21, 18, 0 };
byte singleCellEleven[] = { 9, 27, 9, 9, 9, 9, 9, 0 };
byte singleCellTwelve[] = { 22, 21, 17, 18, 20, 20, 23, 0 };
lcd.createChar(10, singleCellTen);
lcd.createChar(11, singleCellEleven);
lcd.createChar(12, singleCellTwelve);
*/
// play a short tone (for testing the speaker)
tone(SPEAKER_PIN, 1000, 500);
// display a demo pattern (for testing the display)
lcd.setCursor(0, 0); // go to beginning of top line
lcd.print(" Display test ");
lcd.setCursor(0, 1); // go to beginning of bottom line
lcd.print("0123456789 (^_^)");
for (int i = 5; i >= 1; i--) { // countdown from 5 to 1
lcd.setCursor(0, 0); // go to beginning of top line
lcd.print((char)('0' + i)); // print the digit
lcd.setCursor(15, 0); // go to end of top line
lcd.print((char)('0' + i)); // print the digit again
delay(998);
}
}
void loop() {
// first, we (try to) read the time from the RTC
// send request to receive data starting at register 0
Wire.beginTransmission(0x68); // 0x68 is DS3231 device address
Wire.write((byte)0); // start at register 0
Wire.endTransmission();
Wire.requestFrom(0x68, 7); // request seven bytes
gotTheTime = false;
while(Wire.available())
{
ss = bcdToNumber(Wire.read()); // get seconds
mi = bcdToNumber(Wire.read()); // get minutes
hh = bcdToNumber(Wire.read()); // get hours
Wire.read(); // discard the day of the week (we will calculate it ourself)
dd = bcdToNumber(Wire.read()); // get day of month
mo = bcdToNumber(Wire.read()); // get month
yy = bcdToNumber(Wire.read()); // get year
gotTheTime = true;
}
microsNow = micros();
// read the Daylight Saving Time on/off switch
// NOTE: because we are using INPUT_PULLUP, LOW means on, and HIGH means off
dstOn = (digitalRead(DST_SWITCH_PIN) == LOW);
// adjust for Daylight Saving Time if applicable
if (dstOn) {
hh++;
if (hh >= 24) {
hh -= 24;
dd++;
if (dd > daysInMonth(yy, mo)) {
dd = 1;
mo++;
if (mo > 12) {
mo = 1;
yy++;
}
}
}
}
// try to figure out which half-second we are in
// (this is important to making the striking work properly)
if (ss != old_ss) microsAtLastSecond = microsNow;
halfSec = ss * 2;
if ((microsNow - microsAtLastSecond) >= 500000UL) halfSec++;
// calculate day of the week
wd = ymdToWeekday(yy, mo, dd);
// calculate week number
wn = ymdToWeekNumber(yy, mo, dd);
// convert hour to 12-hour format
hhTwelve = hh;
if (hhTwelve > 12) {
hhTwelve -= 12;
}
if (hhTwelve == 0) {
hhTwelve = 12;
}
if (gotTheTime) {
// only if we have successfully read the time
// do we then attempt to indicate the time
if (halfSec != old_halfSec) { // do this only once every half-second
// see if it is time for the clock to strike
if (mi == 0) { // strike on the hour, i.e. when minutes are 0
if (halfSec < 26) {
// play the Westminster Chimes
switch (halfSec) {
case 0: tone(SPEAKER_PIN, 330, 420); break;
case 1: tone(SPEAKER_PIN, 415, 420); break;
case 2: tone(SPEAKER_PIN, 370, 420); break;
case 3: tone(SPEAKER_PIN, 247, 735); break;
case 6: tone(SPEAKER_PIN, 330, 420); break;
case 7: tone(SPEAKER_PIN, 370, 420); break;
case 8: tone(SPEAKER_PIN, 415, 420); break;
case 9: tone(SPEAKER_PIN, 330, 735); break;
case 12: tone(SPEAKER_PIN, 415, 420); break;
case 13: tone(SPEAKER_PIN, 330, 420); break;
case 14: tone(SPEAKER_PIN, 370, 420); break;
case 15: tone(SPEAKER_PIN, 247, 735); break;
case 18: tone(SPEAKER_PIN, 247, 420); break;
case 19: tone(SPEAKER_PIN, 370, 420); break;
case 20: tone(SPEAKER_PIN, 415, 420); break;
case 21: tone(SPEAKER_PIN, 330, 735); break;
default: break;
}
}
else if ((halfSec < (26 + 3 * hhTwelve)) && ((halfSec % 3) == 2)) {
// bong the hours
tone(SPEAKER_PIN, 415, 750);
}
}
}
if ((ss != old_ss) || (dstOn != old_dstOn)) { // only once every second
// update the display to show the current date and time
// build a string of text containing the weekday and the full date
// (Hint: this code makes more sense if you read it vertically)
buf[0] = "BMTWTFSS"[wd];
buf[1] = "aouehrau"[wd];
buf[2] = "dneduitn"[wd];
buf[3] = ' ';
buf[4] = ' ';
buf[5] = ' ';
buf[6] = '0' + (mo/10);
buf[7] = '0' + (mo%10);
buf[8] = '/';
buf[9] = '0' + (dd/10);
buf[10] = '0' + (dd%10);
buf[11] = '/';
buf[12] = '2';
buf[13] = '0';
buf[14] = '0' + (yy/10);
buf[15] = '0' + (yy%10);
buf[16] = 0;
if (buf[6] == '0') buf[6] = ' ';
// display the weekday and full date on the top line
lcd.setCursor(0, 0); // move to beginning of top line
lcd.print(buf); // print the text to the display
// build a string of text containing the week number and the time
buf[0] = 'W';
buf[1] = 'k';
buf[2] = '0' + (wn/10);
buf[3] = '0' + (wn%10);
buf[4] = ' ';
buf[5] = ' ';
buf[6] = '0' + (hhTwelve/10);
buf[7] = '0' + (hhTwelve%10);
buf[8] = ':';
buf[9] = '0' + (mi/10);
buf[10] = '0' + (mi%10);
buf[11] = ':';
buf[12] = '0' + (ss/10);
buf[13] = '0' + (ss%10);
buf[14] = ((hh<12) ? 'a' : 'p');
buf[15] = 'm';
buf[16] = 0;
if (buf[6] == '0') buf[6] = ' ';
// display the week number and the time on the bottom line
lcd.setCursor(0, 1); // move to beginning of bottom line
lcd.print(buf); // print the text to the display
}
}
else {
// if we have failed to read the time,
// then we will end up inside this "else"
// indicate failure to read the time
lcd.setCursor(0, 0); // go to beginning of top line
lcd.print("Error: ");
lcd.setCursor(0, 1); // go to beginning of bottom line
lcd.print("Can\'t read time ");
}
while (micros() - microsNow < 10000) {
// do nothing for about 1/100 of a second
}
// remember these for the next time through loop()
old_ss = ss;
old_halfSec = halfSec;
old_dstOn = dstOn;
}
byte bcdToNumber(byte b) {
// convert BCD (binary-coded decimal) to an ordinary number
byte tens = (b >> 4) & 0xF;
byte ones = b & 0xF;
return (byte)((tens * 10) + ones);
}
byte numberToBcd(byte n) {
// convert a number to binary-coded decimal
byte tens = (n/10);
byte ones = (n%10);
return (byte)((tens << 4) + ones);
}
byte daysInMonth(byte y, byte m) {
// get the number of days in the given month
// y is for the year (0 to 99 for years 2000 through 2099)
// m is for the month (1 to 12)
// reject out-of-range input
if (y > 99) return 0;
if ((m < 1) || (m > 12)) return 0;
// Fourth, eleventh, ninth, and sixth,
// thirty days to each we fix.
if ((m==4)||(m==11)||(m==9)||(m==6)) return 30;
// Every other, thirty-one,
// except the second month alone,
if (m!=2) return 31;
// which hath twenty-eight, in fine,
// till leap-year give it twenty-nine.
if ((y%4)==0) return 29; // leap year
return 28; // not a leap year
}
byte ymdToWeekNumber (byte y, byte m, byte d) {
// get the week number for a given year, month, and day
// NOTE: This function uses two-digit years
// y is a number from 0 (for year 2000) to 99 (for year 2099)
// This function will not work for years outside of this range!
// reject out-of-range dates
if (y > 99) return 0;
if ((m < 1)||(m > 12)) return 0;
if ((d < 1)||(d > 31)) return 0;
// special case first two days of January 2000
if ((y == 0) && (m == 1) && (d <= 2)) return 52;
// (It is useful to know that Jan. 1, 2000 was a Saturday)
// compute adjustment for dates within the year
// If Jan. 1 falls on: Mo Tu We Th Fr Sa Su
// then the adjustment is: 6 7 8 9 3 4 5
byte adj = ((y + 1 + ((y+3)/4)) % 7) + 3;
// compute day of the year (in range 1-366)
int doy = d;
if (m > 1) doy += 31;
if (m > 2) {
if ((y%4)==0) doy += 29;
else doy += 28;
}
if (m > 3) doy += 31;
if (m > 4) doy += 30;
if (m > 5) doy += 31;
if (m > 6) doy += 30;
if (m > 7) doy += 31;
if (m > 8) doy += 31;
if (m > 9) doy += 30;
if (m > 10) doy += 31;
if (m > 11) doy += 30;
// compute week number
byte wknum = (adj + doy) / 7;
// check for boundary conditions
if (wknum < 1) {
// last week of the previous year
// go to previous year and re-compute adjustment
y--;
adj = ((y + 1 + ((y+3)/4)) % 7) + 3;
// check to see whether that year had 52 or 53 weeks
// all years beginning on Thursday have 53 weeks
if (adj==9) return 53;
// leap years beginning on Wednesday have 53 weeks
if ((adj==8) && ((y%4)==0)) return 53;
// other years have 52 weeks
return 52;
}
if (wknum > 52) {
// check to see whether week 53 exists in this year
// all years beginning on Thursday have 53 weeks
if (adj==9) return 53;
// leap years beginning on Wednesday have 53 weeks
if ((adj==8) && ((y%4)==0)) return 53;
// other years have 52 weeks
return 1;
}
return wknum;
}
byte ymdToWeekday(byte y, byte m, byte d) {
// get the day of the week for a given year, month, and day
// NOTE: This function uses two-digit years
// y is a number from 0 (for year 2000) to 99 (for year 2099)
// This function will not work for years outside of this range!
if (y > 99) return 0;
if (d < 1) return 0;
byte l = (((y%4)==0) ? 1 : 0);
byte n = y + (y/4);
switch (m) {
case 1: if (d > 31) return 0; n+=(1-l); break;
case 2: if (d>(28+l)) return 0; n+=(4-l); break;
case 3: if (d > 31) return 0; n+= 4; break;
case 4: if (d > 30) return 0; break;
case 5: if (d > 31) return 0; n+= 2; break;
case 6: if (d > 30) return 0; n+= 5; break;
case 7: if (d > 31) return 0; break;
case 8: if (d > 31) return 0; n+= 3; break;
case 9: if (d > 30) return 0; n+= 6; break;
case 10: if (d > 31) return 0; n+= 1; break;
case 11: if (d > 30) return 0; n+= 4; break;
case 12: if (d > 31) return 0; n+= 6; break;
default: return 0;
}
n += d;
n = ((n + 4) % 7) + 1;
return n; // 1 for Mon, 2 for Tue, ..., 7 for Sun
}
I hope that someone finds this useful.