Math Question- I've lost my decimals

Projects Programming
1

Good afternoon-
I'm attempting to do some math in the Arduino language (converting a distance measurement into a percentage). The problem I'm having is that board appears to be rounding and losing my decimals (which means when I convert to a percentage it either chooses zero or 100 with no intermediate values.)

Here's the relevant code:

long longDistance=long(distance);
long longMaxDistance=long(maxDistance);
long ratio=(longDistance/longMaxDistance);
long percent=(ratio*100);
int percentage=(percent);

(Note that I'm converting to an integer for display purposes, but I HOPE I'm doing that after the number becomes a percentage between 0 and 100. I added the first two lines in an attempt to force my numbers to be longs so I don't have an int messing me up.

I added a debugging section:

   Serial.print("distance=");
    Serial.print(distance);
    Serial.print("   maxDistance=");
    Serial.print(maxDistance);
    Serial.print("   ratio=");
    Serial.print(ratio);
    Serial.print("   percent=");
    Serial.print(percent);
    Serial.print("    percentage=");
    Serial.println(percentage);

and the results I get look like this:

distance=12 maxDistance=17 ratio=0 percent=0 percentage=0

Now, I'm not a math whiz, but my calculator tells me that 12/17 is not 0- it should be 0.705, which should get me a percent value of 70.5 and then it should truncate to a percentage of either 70 or 71. Obviously my program is dropping the decimals despite my best efforts to avoid that.

I'm attaching my whole program (which gets the distance from an ultrasonic sensor and passes it to an NRF2401 for remote display, and which also includes some error checking that I'm still fiddling with, and which is commented out) just in case something somewhere else is what is messing me up. THANK YOU for your help!

#include <nRF24L01.h>
#include <printf.h>
#include <RF24.h>
#include <RF24_config.h>

#include <SPI.h>

RF24 radio(7,8); // Activate Radio
byte addresses[][6] = {"1Node","2Node"};
   int count = 0;
const int trigPin = 4;
const int echoPin = 5;
long maxDistance=16;
long oldDistance=0;



void setup() {
 pinMode(trigPin, OUTPUT); // Sets the trigPin as an Output
pinMode(echoPin, INPUT); // Sets the echoPin as an Input
      radio.begin();
        radio.setPALevel(RF24_PA_LOW);
   radio.openWritingPipe(addresses[1]);
    radio.openReadingPipe(1,addresses[0]);
    Serial.begin(9600);
 maxDistance=Measurement(trigPin, echoPin);
        

}

void loop() {
 radio.stopListening();  

long distance = Measurement(trigPin,echoPin);
//if (distance>2000){
//  distance=oldDistance;
//}
//if (distance>maxDistance){
//  maxDistance=distance;
//}
long longDistance=long(distance);
long longMaxDistance=long(maxDistance);
long ratio=(longDistance/longMaxDistance);
long percent=(ratio*100);
int percentage=(percent);
    radio.write(&percentage, sizeof(percentage));
    Serial.print("Message sent:  ");
    Serial.print("distance=");
    Serial.print(distance);
    Serial.print("   maxDistance=");
    Serial.print(maxDistance);
    Serial.print("   ratio=");
    Serial.print(ratio);
    Serial.print("   percent=");
    Serial.print(percent);
    Serial.print("    percentage=");
    Serial.println(percentage);
    oldDistance=distance;
    delay(250);

}
// Pass pins that ultrasonic detector is connected to, returns distance in CM
long Measurement (int localTrigPin, int localEchoPin)
{
    // Clears the trigPin
digitalWrite(localTrigPin, LOW);
delayMicroseconds(2);
// Sets the trigPin on HIGH state for 10 micro seconds
digitalWrite(localTrigPin, HIGH);
delayMicroseconds(10);
digitalWrite(localTrigPin, LOW);
// Reads the echoPin, returns the sound wave travel time in microseconds
long duration = pulseIn(localEchoPin, HIGH);
// Calculating the distance in cm
long cm= duration*0.034/2;
return cm;
}
2

Maybe try floats instead of integer

3

long what?

4

Welcome to the forum.

The integer variables you are using (int and long) can only work with whole numbers, they cannot use or return fractions or numbers after the decimal point.

5

long is an integer type, so if your formulas get non-integer results, the fractional part disappears into thin air.

6

You may try these codes:

void setup()
{
  Serial.begin(9600);
  int distance = 12;
  int maxDistance = 17;

  long longDistance = long(distance); //12
  long longMaxDistance = long(maxDistance);  //17

  float ratio = longDistance / (float)longMaxDistance * 100; //0.705
  //Serial.println(ratio, 2);
  int percentage = round(ratio);//(percent);
  Serial.println(percentage);

}

void loop() 
{
 
}
7

And as it’s clear by now, I didn’t know “long” didn’t keep decimals (I knew int was only integers but incorrectly assumed long had a decimal component). I’ll update to float as soon as I get back to the computer and give it a try. Thanks for the programming lesson :slight_smile:

8

Because 'float' can only retain 6 or 7 significant digits, and the math operations are generally slower, you might be better of keeping things in integers:

int percentage = (distance * 100L) / maxDistance;

I'm assuming that 'distance' and 'maxDistance' are 'int', otherwise there would be no need to promote them to 'long'. When 'distance' is multiplied by the long integer constant '100L' it is automatically 'promoted' to a long integer before the multiply. Assuming 'maxDistance' is at least as large as 'distance' (based on the name) it is safe to assume that the result will be a value between 0 and 100, so even though the result type is 'long int' the result will fit in an 'int'.

By doing the multiply by 100 on the left side of the division we protect two decimal digits from getting lost in the integer division.

9

jstamp:
And as it’s clear by now, I didn’t know “long” didn’t keep decimals (I knew int was only integers but incorrectly assumed long had a decimal component). I’ll update to float as soon as I get back to the computer and give it a try. Thanks for the programming lesson :slight_smile:

long actually is the short form of long int. The int in that could possibly have put you on the right track.