Millis(), an interesting problem

long t1 = 0;
long t2 = 0;
void setup()
{
Serial.begin(9600);
}

void loop()
{
t1 = millis();
t2 = t1 - 1000;
while(t2<t1)
{
t2 = millis();
}

Serial.println(“Hello”);

}

Above is a simple code using millis function in arduino. According to me, it should print “Hello” on serial after a second passes.
However “Hello” keeps printing all the time, there is not a delay of 1 second between 2 prints.
Can anyone try this code and figure out why?

The way it is written, the Serial.print statement will execute every time loop() runs, which is to say continuously. There is no conditional logic to prevent it, the rest of the code has no effect the way it is written.

millis() returns an unsigned long data type, so variables like t1 and t2 should be unsigned long as well. In this case it wouldn't make any difference until the sketch had run for some days, but it's just good form.

How many times does the loop() function run ?

It can only stay in that while loop for one iteration. You immediately assign t2 the current millis() which will obviously make it larger than t1. Looks to me like you should update t1 not t2 in that loop.

You’ve really just programmed your own delay() which isn’t a good way to do this. Read through and understand the blink without delay for the better way to do this.

loop() runs for ever and ever and ........................

Mark

You immediately assign t2 the current millis() which will obviously make it larger than t1.

sp. "larger or (more likely) the same"

Jimmy nailed it.

Once you update t2 with millis() it will always be greater than or equal to t1, so the while loop will only ever run once. Hopefully this is just an academic exercise, because practically, that's an atrocious way of writing a 1 second delay.

Arrch:
Jimmy nailed it.

Once you update t2 with millis() it will always be greater than or equal to t1, so the while loop will only ever run once. Hopefully this is just an academic exercise, because practically, that's an atrocious way of writing a 1 second delay.

I agree, and especially when there is an 'official arduino example sketch' that shows how to properly implement a 1 second interval.

/* Blink without Delay
 
 Turns on and off a light emitting diode(LED) connected to a digital  
 pin, without using the delay() function.  This means that other code
 can run at the same time without being interrupted by the LED code.
 
 The circuit:
 * LED attached from pin 13 to ground.
 * Note: on most Arduinos, there is already an LED on the board
 that's attached to pin 13, so no hardware is needed for this example.
 
 
 created 2005
 by David A. Mellis
 modified 8 Feb 2010
 by Paul Stoffregen
 
 This example code is in the public domain.

 
 http://www.arduino.cc/en/Tutorial/BlinkWithoutDelay
 */

// constants won't change. Used here to 
// set pin numbers:
const int ledPin =  13;      // the number of the LED pin

// Variables will change:
int ledState = LOW;             // ledState used to set the LED
long previousMillis = 0;        // will store last time LED was updated

// the follow variables is a long because the time, measured in miliseconds,
// will quickly become a bigger number than can be stored in an int.
long interval = 1000;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);      
}

void loop()
{
  // here is where you'd put code that needs to be running all the time.

  // check to see if it's time to blink the LED; that is, if the 
  // difference between the current time and last time you blinked 
  // the LED is bigger than the interval at which you want to 
  // blink the LED.
  unsigned long currentMillis = millis();
 
  if(currentMillis - previousMillis > interval) {
    // save the last time you blinked the LED 
    previousMillis = currentMillis;   

    // if the LED is off turn it on and vice-versa:
    if (ledState == LOW)
      ledState = HIGH;
    else
      ledState = LOW;

    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
  }
}

Lefty

Well, that wasn’t an interesting problem, it was an embarrassing one. :blush:

positivelydoped23:
Well, that wasn't an interesting problem, it was an embarrassing one. :blush:

I wouldn't worry too much, you're in very good company! :smiley:

[/quote]

I wouldn’t worry too much, you’re in very good company! :smiley:
[/quote]

Thankyou! Really appreciate the kind of quick replies i get on this forum.

The one thing you've really got to bear in mind if the immense difference in timescales.
One 1/1000th of a second is a tiny amount of time to us, but your Arduino could execute 16000 instructions in that time.