Le code pour l'ESP est assez trivial, je l'ai pour ESP32 "de base", je n'ai pas de S3 sous la main mais c'est le même principe.
Vous créez un serveur BLE, vous lui donnez un petit nom et ce code publie une caractéristique.
Dans l'app sur l'iPhone vous clickez sur le petit symbole bluetooth rouge en haut à droite.
ça ouvre un panneau où on voit tous les périphériques BLE autour de vous. Dans la liste vous retrouvez le nom de votre serveur (dans mon code ESP32_REMOTE) pour vous connecter
et tapez sur Tap to connect
une fois que c'est fait vous êtes connecté et vous voyez votre ESP32 sélectionné en haut de la liste
vous sélectionnez la petite flèche bleu en haut à gauche pour revenir à la télécommande
On voit que l'on est connecté grace au symbole bluetooth qui est devenu bleu maintenant.
Sur mon interface on voit que j'ai un D-Pad qui s'appelle d0 en haut et un joystick en bas qui s'appelle d1
dans mon code d'exemple si je clique la flèche vers le haut du D-pad je vois
Flux HEX : 01 64 30 02 35 31 32 2C 31 30 32 33 03 (13 octets)
ID : d0, valeurs = 512,1023
le flux hexadécimal c'est le message reçu de la télécommande et en dessous je le décode
l'identifiant de l'objet qui me parle c'est d0 et les valeurs envoyées c'est 512,1023
les valeurs correspondent aux (X,Y) de mon d-Pad avec (0,0) en bas à gauche et (1023, 1023) en haut à droite. Donc quand je lis (512,1023) je sais que le X est au milieu et le Y en haut donc c'est la flèche vers le haut
quand je relâche le bouton je reçois
Flux HEX : 01 64 30 02 35 31 32 2C 35 31 32 03 (12 octets)
ID : d0, valeurs = 512,512
on voit que c'est toujours l'objet d0 qui parle et qui me dit que les coordonnées sont (512, 512) donc on est "au centre" (plus rien d'appuyé).
si je bouge maintenant le joystick en dessous, on reçoit des messages successifs
par exemple
Flux HEX : 01 64 31 02 35 33 37 2C 35 34 35 03 (12 octets)
ID : d1, valeurs = 537,545
Flux HEX : 01 64 31 02 37 32 33 2C 36 39 39 03 (12 octets)
ID : d1, valeurs = 723,699
Flux HEX : 01 64 31 02 35 35 34 2C 35 34 39 03 (12 octets)
ID : d1, valeurs = 554,549
Flux HEX : 01 64 31 02 35 31 39 2C 35 31 38 03 (12 octets)
ID : d1, valeurs = 519,518
Flux HEX : 01 64 31 02 35 31 33 2C 35 31 32 03 (12 octets)
ID : d1, valeurs = 513,512
Flux HEX : 01 64 31 02 35 31 32 2C 35 31 32 03 (12 octets)
ID : d1, valeurs = 512,512
on voit que c'est l'objet d1 qui parle et on reçoit les coordonnées (x,y) là aussi mais avec une granularité totale sur l'intervalle [0, 1023] en X et en Y. On voit aussi que dans le dernier message les coordonnées sont 512,512 ➜ j'ai relâché le joystick et il est retournée au centre.
L'appli est paramétrable donc vous pouvez créer différents objets ou interfaces.
Dans le code vous verrez aussi un callback qui vous dit quand une télécommande se connecte et se déconnecte .
le code de test
/* ============================================
code is placed under the MIT license
Copyright (c) 2023 J-M-L
For the Arduino Forum : https://forum.arduino.cc/u/j-m-l
——— Decoding MicroBlue messages on ESP32 ———
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.
===============================================
*/
#include <BLEDevice.h>
#include <BLEUtils.h>
#include <BLEServer.h>
#define SERVICE_UUID "6e400001-b5a3-f393-e0a9-e50e24dcca9e"
#define CHARACTERISTIC_UUID "6e400002-b5a3-f393-e0a9-e50e24dcca9e"
BLECharacteristic* caracteristiqueReception;
class CallbacksServeur : public BLEServerCallbacks {
void onConnect(BLEServer* serveur) {
Serial.println("Client BLE connecté");
}
void onDisconnect(BLEServer* serveur) {
Serial.println("Client BLE déconnecté");
serveur->getAdvertising()->start();
}
};
class CallbacksReception : public BLECharacteristicCallbacks {
void onWrite(BLECharacteristic* characteristic) {
size_t longueur = characteristic->getLength();
if (longueur == 0) return;
char buffer[longueur];
memcpy(buffer, reinterpret_cast<char*>(characteristic->getData()), longueur);
if (buffer[0] != 0x01 || buffer[longueur - 1] != 0x03) return; // message incorrect
char* sepPtr = reinterpret_cast<char*>(memchr(buffer, 0x02, longueur)); // on cherche le séparateur
if (sepPtr == nullptr) return; // message incorrect
// Affichage HEX
Serial.print("Flux HEX : ");
for (size_t i = 0; i < longueur; i++) {
if (buffer[i] < 16) Serial.write('0');
Serial.print(buffer[i], HEX);
Serial.write(' ');
}
Serial.print('(');
Serial.print(longueur);
Serial.println(" octets)");
// Décodage du message
// [0x01][ID][0x02][Value…][0x03]
// ID = identifiant de l’objet
// Value = chaîne ASCII de longueur variable
// avec le D-pad ou le joystick ce sont les coordonnées sous format entier X,Y
// avec les coordonnées entre 0 (gauche ou bas) et 1023 (droite ou haut))
*sepPtr = '\0'; // on replace le séparateur par un nul
buffer[longueur - 1] = '\0'; // on remplace le marqueur de fin par un nul
char* identifiant = buffer + 1; // adresse du début de l'ID
char* valeurs = sepPtr + 1; // adresse du début des coordonnées
Serial.print("ID : "); Serial.print(identifiant);
Serial.print(", valeurs = "); Serial.println(valeurs);
}
};
void setup() {
Serial.begin(115200);
BLEDevice::init("ESP32_REMOTE");
BLEServer* serveur = BLEDevice::createServer();
serveur->setCallbacks(new CallbacksServeur());
BLEService* service = serveur->createService(SERVICE_UUID);
caracteristiqueReception = service->createCharacteristic(CHARACTERISTIC_UUID, BLECharacteristic::PROPERTY_WRITE | BLECharacteristic::PROPERTY_WRITE_NR);
caracteristiqueReception->setCallbacks(new CallbacksReception());
service->start();
BLEAdvertising* publicite = BLEDevice::getAdvertising();
publicite->addServiceUUID(SERVICE_UUID);
publicite->start();
}
void loop() {}
vous voyez dans la classe qui reçoit les message que j'ai une c-string id et une c-string valeurs il suffit de faire un strcmp() pour tester quel est le nom de l'objet qui parle et un sscanf() pour extraire les coordonnées x et y des valeurs et ensuite vous vous en servez pour vos moteurs ou ce que vous voulez.
Quand vous voulez vous déconnecter, vous cliquez sur le petit logo bluetooth bleu en haut à droite, ça vous ramène au panneau de connexion et vous cliquez la croix rouge à côté du nom de votre appareil
et c'est tout 
plus d'infos sur l'API BLE dans le code : arduino-esp32/libraries/BLE at master · espressif/arduino-esp32 · GitHub