Returning an array

Projects Programming
1

I'm trying to figure out how to return an array from a function.

I can return the array itself with the below code but I can't figure out how to recieve an element from that array.

void setup() {
  // put your setup code here, to run once:
  Serial.begin (115200);
}

void loop() {
  // put your main code here, to run repeatedly:
  int ret = Test();
  Serial.println(ret);
}


int Test(){
  int test[] = {1,2,3};
  return test;
}

Any tips would be appreciated.

2

You can return a struct containing an array, but I don't think you can return an array by itself.

What are you trying to do?

4

Use pointers.

Paul

5

Paul_KD7HB:
Use pointers.

Paul

...but not to an automatic variable within the function returning the pointer.

6

As stated, use pointers. But, then the local variable being returned must be 'static'. Also, you need some way of knowing the array's size in the calling function:

void setup() {
  Serial.begin (115200);
}

void loop() {
  int *returnedArray;
  returnedArray = Test();
  for (uint8_t i = 0; i < 3; i++) {
    Serial.println(returnedArray[i]);
  }
}

int *Test() {
  static int test[] = {1, 2, 3};
  return test;
}
7

As also previously stated, a more common technique would be to allocate the array storage in the calling program and pass a pointer to it (along with array size) to the function:

void setup() {
  Serial.begin (115200);
}

void loop() {
  const uint8_t arraySize = 3;
  int myArray[arraySize];
  test(myArray, arraySize);
  for (uint8_t i = 0; i < 3; i++) {
    Serial.println(myArray[i]);
  }
}

void test(int *theArray, size_t numElements) {
  for (uint8_t i = 0; i < numElements; i++) {
    theArray[i] = i;
  }
}
8

Thanks a million guys. I will give this a shot but I'm sure I won't have any problems now.

9

gfvalvo:
As also previously stated, a more common technique would be to allocate the array storage in the calling program and pass a pointer to it (along with array size) to the function:

void setup() {

Serial.begin (115200);
}

void loop() {
  const uint8_t arraySize = 3;
  int myArray[arraySize];
  test(myArray, arraySize);
  for (uint8_t i = 0; i < 3; i++) {
    Serial.println(myArray[i]);
  }
}

void test(int *theArray, size_t numElements) {
  for (uint8_t i = 0; i < numElements; i++) {
    theArray[i] = i;
  }
}

I do have one more question that will help me understand your code. What dose the "*" mean in front of *theArray? The code does work without it.

Thanks

10

KrafterHD:
I do have one more question that will help me understand your code. What dose the "*" mean in front of *theArray? The code does work without it.

Thanks

The * indicates a pointer.
Without it, the code DOES NOT work.
It won't even compile.

11

KrafterHD:
I do have one more question that will help me understand your code. What dose the "*" mean in front of *theArray? The code does work without it.

Thanks

12

AWOL:
The * indicates a pointer.
Without it, the code DOES NOT work.
It won't even compile.

Now I know. Thank you very much. The code works great and can be easily modified for my needs.

Perehama:
* - Arduino Reference

Great. Thanks. I tried googling it but didnt come up with anything.