Hi,
This may have been posted before, but "repetition is the mother of learning".
It is possible to send data on serial port in windows just by using the windows-installed components. A simple vb script that reads a text file and sends it to serial port is shown below:
Const ForReading = 1
Const ForWriting = 2
'-------------------------------
' open USB serial port (COMx);
'
' If the serial monitor in Arduino IDE is open, you will get an "access denied" error.
' Just make sure that the serial monitor is closed (so bytes are not sent by the arduino board).
'-------------------------------
Set fso = CreateObject("Scripting.FileSystemObject")
Set com = fso.OpenTextFile("COM4:9600,N,8,1", ForWriting)
'---------------------------------------------
' read content of text file line by line;
' write line to COMx;
'---------------------------------------------
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("C:\docs\quotes.txt", ForReading)
MsgBox("Ready to write file content to COM")
Do While objFile.AtEndOfStream <> True
'--------------------------------------------------
' read a few (10) characters at a time; serial buffer is limited to 32 characters;
' writing a character to eeprom takes about 11 ms (assuming that there is no serial.prints in the loop);
' therefore, after each batch of 10 chars sent to COM, we should wait no less than 110 ms;
' we use 200 to have a margin of safety;
'--------------------------------------------------
strChars = objFile.Read(10)
com.Write(strChars)
WScript.Sleep(200)
Loop
objFile.Close
com.Close()
MsgBox("Finished writing to COM")
I used this script to load an 25LC256 eprom with quotes from a text file, part of my implementation of the "Life clock" project initiated by Mr. BroHogan (see http://www.arduino.cc/cgi-bin/yabb2/YaBB.pl?num=1214682544).
According to the datasheet, the eprom requires a 5 ms delay after each byte written (it takes its time to carve the data onto the silicon). In my writeByte function, I used a delay of 10 ms.
A 32K text file takes about 10 minutes to write to the eprom using this script.