Show 11 digit number on 7-segment displays

petemanzel · November 18, 2022, 2:47pm

Hello,

i have build a big 7 segment Display made of 11 "SparkFun 7-Segment Display 6.5"" they are all equiped with the " SparkFun Large Digit Driver" with the TPIC6C596 IC.

It is running fine untill I increment the number of digits over the 8th digit. As soon as I try to show 9 or more digits, the digits start to behave strange. No more counting. Some sporadic numbers.

What am I doing wrong?

Thanks for any help!

This is my code so far:

//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
byte segmentClock = 6;
byte segmentLatch = 5;
byte segmentData = 7;

//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=

char snumber[10];

void setup()
{
  Serial.begin(9600);
  Serial.println("Large Digit Driver Example");

  pinMode(segmentClock, OUTPUT);
  pinMode(segmentData, OUTPUT);
  pinMode(segmentLatch, OUTPUT);

  digitalWrite(segmentClock, LOW);
  digitalWrite(segmentData, LOW);
  digitalWrite(segmentLatch, LOW);
}

unsigned long long number = 12345678901;

void loop()
{
  showNumber(number); //Test pattern
  number = number + 16;
  number %= 100000000000; //Reset x after 99999999999
  
  sprintf(snumber, "%llu", number);
  Serial.println(snumber); //For debugging
  
  delay(100);
}

//Takes a number and displays 11 numbers. Displays absolute value (no negatives)
void showNumber(float value)
{
  unsigned long long number = abs(value); //Remove negative signs and any decimals

  for (byte x = 0 ; x < 11 ; x++)
  {
    unsigned long long remainder = number % 10;

    postNumber(remainder, false);

    number /= 10;
  }

  //Latch the current segment data
  digitalWrite(segmentLatch, LOW);
  digitalWrite(segmentLatch, HIGH); //Register moves storage register on the rising edge of RCK
}

//Given a number, or '-', shifts it out to the display
void postNumber(byte number, boolean decimal)
{
  //    -  A
  //   / / F/B
  //    -  G
  //   / / E/C
  //    -. D/DP

#define a  1<<0
#define b  1<<6
#define c  1<<5
#define d  1<<4
#define e  1<<3
#define f  1<<1
#define g  1<<2
#define dp 1<<7

  byte segments;

  switch (number)
  {
    case 1: segments = b | c; break;
    case 2: segments = a | b | d | e | g; break;
    case 3: segments = a | b | c | d | g; break;
    case 4: segments = f | g | b | c; break;
    case 5: segments = a | f | g | c | d; break;
    case 6: segments = a | f | g | e | c | d; break;
    case 7: segments = a | b | c; break;
    case 8: segments = a | b | c | d | e | f | g; break;
    case 9: segments = a | b | c | d | f | g; break;
    case 0: segments = a | b | c | d | e | f; break;
    case ' ': segments = 0; break;
    case 'c': segments = g | e | d; break;
    case '-': segments = g; break;
  }

  if (decimal) segments |= dp;

  //Clock these bits out to the drivers
  for (byte x = 0 ; x < 8 ; x++)
  {
    digitalWrite(segmentClock, LOW);
    digitalWrite(segmentData, segments & 1 << (7 - x));
    digitalWrite(segmentClock, HIGH); //Data transfers to the register on the rising edge of SRCK
  }
}

jfjlaros · November 18, 2022, 4:22pm

This array should have a size of at least 12 if you use sprintf to print an 11-digit number

b707 · November 18, 2022, 4:36pm

why this parameter is float?
Float number has limited accuracy. Use long long number instead

jremington · November 18, 2022, 4:46pm

On AVR-based Arduinos, float values are limited to at most 7 decimal digits of accuracy and type double is not supported (treated as four byte float).

petemanzel · November 18, 2022, 5:44pm

Thank you all.

This solved my problem:

As long long everything works perfectly.

One more thing. I changed the array size to 12.
But my serialmonitor output is empty.

b707 · November 18, 2022, 5:49pm

Where is the truth - have you solved everything

or nothing works?

petemanzel · November 18, 2022, 6:03pm

Sorry for that misunderstanding!

The output on the 7-segment displays works perfectly as mentioned.
The output on my serialmonitor is not working as it should.
On the serialmonitor I get the Setup-message: Serial.println("Large Digit Driver Example");

But no number is showing up. I see the empty lines scrolling.

Thanks

jremington · November 18, 2022, 6:16pm

Post the revised code, using code tags.

petemanzel · November 18, 2022, 6:23pm

Here it is:

//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
byte segmentClock = 6;
byte segmentLatch = 5;
byte segmentData = 7;

//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=

char snumber[12];

void setup()
{
  Serial.begin(9600);
  Serial.println("Large Digit Driver Example");

  pinMode(segmentClock, OUTPUT);
  pinMode(segmentData, OUTPUT);
  pinMode(segmentLatch, OUTPUT);

  digitalWrite(segmentClock, LOW);
  digitalWrite(segmentData, LOW);
  digitalWrite(segmentLatch, LOW);
}

unsigned long long number = 74152676000 ;

void loop()
{
  showNumber(number); //Test pattern
  number = number + 16;
  number %= 100000000000; //Reset x after 99999999999
  
  sprintf(snumber, "%llu", number);
  Serial.println(snumber); //For debugging
  
  delay(100);
}

//Takes a number and displays 11 numbers. Displays absolute value (no negatives)
void showNumber(long long value)
{
  unsigned long long number = abs(value); //Remove negative signs and any decimals

  for (byte x = 0 ; x < 11 ; x++)
  {
    unsigned long long remainder = number % 10;

    postNumber(remainder, false);

    number /= 10;
  }

  //Latch the current segment data
  digitalWrite(segmentLatch, LOW);
  digitalWrite(segmentLatch, HIGH); //Register moves storage register on the rising edge of RCK
}

//Given a number, or '-', shifts it out to the display
void postNumber(byte number, boolean decimal)
{
  //    -  A
  //   / / F/B
  //    -  G
  //   / / E/C
  //    -. D/DP

#define a  1<<0
#define b  1<<6
#define c  1<<5
#define d  1<<4
#define e  1<<3
#define f  1<<1
#define g  1<<2
#define dp 1<<7

  byte segments;

  switch (number)
  {
    case 1: segments = b | c; break;
    case 2: segments = a | b | d | e | g; break;
    case 3: segments = a | b | c | d | g; break;
    case 4: segments = f | g | b | c; break;
    case 5: segments = a | f | g | c | d; break;
    case 6: segments = a | f | g | e | c | d; break;
    case 7: segments = a | b | c; break;
    case 8: segments = a | b | c | d | e | f | g; break;
    case 9: segments = a | b | c | d | f | g; break;
    case 0: segments = a | b | c | d | e | f; break;
    case ' ': segments = 0; break;
    case 'c': segments = g | e | d; break;
    case '-': segments = g; break;
  }

  if (decimal) segments |= dp;

  //Clock these bits out to the drivers
  for (byte x = 0 ; x < 8 ; x++)
  {
    digitalWrite(segmentClock, LOW);
    digitalWrite(segmentData, segments & 1 << (7 - x));
    digitalWrite(segmentClock, HIGH); //Data transfers to the register on the rising edge of SRCK
  }
}

jremington · November 18, 2022, 6:25pm

Check whether the Arduino version of sprintf supports long longs. It does not support floats, for example.

Seems a bit silly to declare "remainder" as long long, since it can never be greater than 9.

    unsigned long long remainder = number % 10;

jfjlaros · November 18, 2022, 6:34pm

I suspect that this type is not supported in the sprintf version of avr-libc.

You can check this here.

[edit]

Here is a print function that might be useful.

oqibidipo · November 18, 2022, 6:42pm

Indeed it is not. You could use this ulltoa() function:

system · May 17, 2023, 6:42pm

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.

Topic		Replies	Views
9 digit numbers and words on 7 segment using large digit driver from Sparkfun General Guidance	12	2169	May 5, 2021
tpic6c596 sparkfun breakout to control 4 digits large 7 segment display LEDs and Multiplexing	2	3161	May 6, 2021
Sparkfun 4 digit 7-segment display help Troubleshooting	7	2420	May 6, 2021
TPIC6C596D 6 digit 7 segment display Programming	9	854	May 14, 2022
Counter up/down with Tpic6c596 shift register General Guidance	9	2957	May 5, 2021

Show 11 digit number on 7-segment displays

Related topics