Troubleshooting BLE

mfusco · January 24, 2025, 10:43pm

Hi,

I am in need of assistance troubleshooting BLE. I have tried a combination of boards (ESP32 and Giga) and have not been able to get the slightly modified basic example to work (no connection established). Below is the central and peripheral code:

#include <ArduinoBLE.h>

// variables for button
int incomingByte = 0;

void setup() {
  Serial.begin(9600);
  while (!Serial);

  // configure the button pin as input
  pinMode(buttonPin, INPUT);

  // initialize the Bluetooth® Low Energy hardware
  BLE.begin();

  Serial.println("Bluetooth® Low Energy Central - LED control");

  // start scanning for peripherals
  BLE.scanForUuid("19B10001-E8F2-537E-4F6C-D104768A1214");
}

void loop() {
  // check if a peripheral has been discovered
  BLEDevice peripheral = BLE.available();

  if (peripheral) {
    // discovered a peripheral, print out address, local name, and advertised service
    Serial.print("Found ");
    Serial.print(peripheral.address());
    Serial.print(" '");
    Serial.print(peripheral.localName());
    Serial.print("' ");
    Serial.print(peripheral.advertisedServiceUuid());
    Serial.println();

    if (peripheral.localName() != "LED") {
      return;
    }

    // stop scanning
    BLE.stopScan();

    controlLed(peripheral);

    // peripheral disconnected, start scanning again
    BLE.scanForUuid("19b10000-e8f2-537e-4f6c-d104768a1214");
  }
}

void controlLed(BLEDevice peripheral) {
  // connect to the peripheral
  Serial.println("Connecting ...");

  if (peripheral.connect()) {
    Serial.println("Connected");
  } else {
    Serial.println("Failed to connect!");
    return;
  }

  // discover peripheral attributes
  Serial.println("Discovering attributes ...");
  if (peripheral.discoverAttributes()) {
    Serial.println("Attributes discovered");
  } else {
    Serial.println("Attribute discovery failed!");
    peripheral.disconnect();
    return;
  }

  // retrieve the LED characteristic
  BLECharacteristic ledCharacteristic = peripheral.characteristic("19b10001-e8f2-537e-4f6c-d104768a1214");

  if (!ledCharacteristic) {
    Serial.println("Peripheral does not have LED characteristic!");
    peripheral.disconnect();
    return;
  } else if (!ledCharacteristic.canWrite()) {
    Serial.println("Peripheral does not have a writable LED characteristic!");
    peripheral.disconnect();
    return;
  }

  while (peripheral.connected()) {
      if (Serial.available() > 0) {
        incomingByte = Serial.read();

        if (incomingByte != 10) {
          Serial.print("byte: ");
          Serial.println(incomingByte, DEC);

          if (incomingByte == 49) ledCharacteristic.writeValue((byte)0x01);
          else ledCharacteristic.writeValue((byte)0x00);
        }
      }
  }

  Serial.println("Peripheral disconnected");
}

#include <ArduinoBLE.h>

BLEService ledService("19B10000-E8F2-537E-4F6C-D104768A1214"); // Bluetooth® Low Energy LED Service

// Bluetooth® Low Energy LED Switch Characteristic - custom 128-bit UUID, read and writable by central
BLEByteCharacteristic switchCharacteristic("19B10001-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);

const int ledPin = LED_BUILTIN; // pin to use for the LED

void setup() {
  Serial.begin(9600);
  while (!Serial);

  // set LED pin to output mode
  pinMode(ledPin, OUTPUT);

  // begin initialization
  if (!BLE.begin()) {
    Serial.println("starting Bluetooth® Low Energy module failed!");

    while (1);
  }

  // set advertised local name and service UUID:
  BLE.setLocalName("LED");
  BLE.setAdvertisedService(ledService);

  // add the characteristic to the service
  ledService.addCharacteristic(switchCharacteristic);

  // add service
  BLE.addService(ledService);

  // set the initial value for the characeristic:
  switchCharacteristic.writeValue(0);

  // start advertising
  BLE.advertise();

  Serial.println("BLE LED Peripheral");
}

void loop() {
  // listen for Bluetooth® Low Energy peripherals to connect:
  BLEDevice central = BLE.central();

  // if a central is connected to peripheral:
  if (central) {
    Serial.print("Connected to central: ");
    // print the central's MAC address:
    Serial.println(central.address());

    // while the central is still connected to peripheral:
    while (central.connected()) {
      // if the remote device wrote to the characteristic,
      // use the value to control the LED:
      if (switchCharacteristic.written()) {
        if (switchCharacteristic.value()) {   // any value other than 0
          Serial.println("LED on");
          digitalWrite(ledPin, HIGH);         // will turn the LED on
        } else {                              // a 0 value
          Serial.println(F("LED off"));
          digitalWrite(ledPin, LOW);          // will turn the LED off
        }
      }
    }

    // when the central disconnects, print it out:
    Serial.print(F("Disconnected from central: "));
    Serial.println(central.address());
  }
}

MrY · January 24, 2025, 11:46pm

Here is a BLE scanner that works on the ESP32.

/*
   Based on Neil Kolban example for IDF: https://github.com/nkolban/esp32-snippets/blob/master/cpp_utils/tests/BLE%20Tests/SampleScan.cpp
   Ported to Arduino ESP32 by Evandro Copercini
*/

#include <BLEDevice.h>
#include <BLEUtils.h>
#include <BLEScan.h>
#include <BLEAdvertisedDevice.h>

int scanTime = 5;  //In seconds
BLEScan *pBLEScan;

class MyAdvertisedDeviceCallbacks : public BLEAdvertisedDeviceCallbacks {
  void onResult(BLEAdvertisedDevice advertisedDevice) {
    Serial.printf("Advertised Device: %s \n", advertisedDevice.toString().c_str());
  }
};

void setup() {
  Serial.begin(115200);
  Serial.println("Scanning...");

  BLEDevice::init("");
  pBLEScan = BLEDevice::getScan();  //create new scan
  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks());
  pBLEScan->setActiveScan(true);  //active scan uses more power, but get results faster
  pBLEScan->setInterval(100);
  pBLEScan->setWindow(99);  // less or equal setInterval value
}

void loop() {
  // put your main code here, to run repeatedly:
  BLEScanResults *foundDevices = pBLEScan->start(scanTime, false);
  Serial.print("Devices found: ");
  Serial.println(foundDevices->getCount());
  Serial.println("Scan done!");
  pBLEScan->clearResults();  // delete results fromBLEScan buffer to release memory
  delay(2000);
}

The code you posted looks like it is for the Giga and I don't think it will compile for the ESP32.

MrY · January 25, 2025, 12:24am

Here is a link to the code I wrote for the ESP32 that creates a peripheral.

The central that communicates with it is a Python application.

The user's guide for the application may be viewed here

cattledog · January 25, 2025, 12:36am

 // start scanning for peripherals
  BLE.scanForUuid("19B10000-E8F2-537E-4F6C-D104768A1214");

You have an error in the central code. You want to start scanning for the service uuid and not the characteristic uuid.

I have your peripheral sketch running on an ESP32 and the central on a Nano33BLE.

With the !Serial command, you will need both monitors open.
The monitor on the central is best set with no line ending.
The two sketches are working properly.

EDIT:
I have also switched the two devices around, and can run the sketches with the peripheral on the Nanol33BLE and the Central on the ESP32.

@MrY
The ArduinoBLE library is ported to the esp32. It is not necessary to use the BLE library bundled with the exp32 core. It may be preferable to use the exp32 core library and its syntax on an esp32, but ArduinoBLE will work on an esp32.

mfusco · January 26, 2025, 5:17pm

@cattledog Thank you for your response. Could you please cite the incorrect code and what it should be? From the looks of my code, it appears that I am scanning for the service UUID.

cattledog · January 26, 2025, 5:46pm

In setup() for the central you are not scanning for the service UUID. I posted the error and the correction in post #4.

mfusco · January 27, 2025, 8:31pm

I was able to get it working briefly but after awhile the connection stopped establishing. Is there something wrong with the code below?

#include <ArduinoBLE.h>

int incomingByte = 0;

void setup() {
  Serial.begin(9600);
  while (!Serial);

  // initialize the Bluetooth® Low Energy hardware
  BLE.begin();

  Serial.println("Bluetooth® Low Energy Central - LED control");

  // start scanning for peripherals
  BLE.scanForUuid("19B10000-E8F2-537E-4F6C-D104768A1214");
} 

void loop() {
  // check if a peripheral has been discovered
  BLEDevice peripheral = BLE.available();

  if (peripheral) {
    // discovered a peripheral, print out address, local name, and advertised service
    Serial.print("Found ");
    Serial.print(peripheral.address());
    Serial.print(" '");
    Serial.print(peripheral.localName());
    Serial.print("' ");
    Serial.print(peripheral.advertisedServiceUuid());
    Serial.println();

    if (peripheral.localName() != "LED") {
      return;
    }

    // stop scanning
    BLE.stopScan();

    controlLed(peripheral);

    // peripheral disconnected, start scanning again
    BLE.scanForUuid("19B10000-E8F2-537E-4F6C-D104768A1214");
  }
}

void controlLed(BLEDevice peripheral) {
  // connect to the peripheral
  Serial.println("Connecting ...");

  if (peripheral.connect()) {
    Serial.println("Connected");
  } else {
    Serial.println("Failed to connect!");
    return;
  }

  // discover peripheral attributes
  Serial.println("Discovering attributes ...");
  if (peripheral.discoverAttributes()) {
    Serial.println("Attributes discovered");
  } else {
    Serial.println("Attribute discovery failed!");
    peripheral.disconnect();
    return;
  }

  // retrieve the LED characteristic
  BLECharacteristic ledCharacteristic = peripheral.characteristic("19b10001-e8f2-537e-4f6c-d104768a1214");

  if (!ledCharacteristic) {
    Serial.println("Peripheral does not have LED characteristic!");
    peripheral.disconnect();
    return;
  } else if (!ledCharacteristic.canWrite()) {
    Serial.println("Peripheral does not have a writable LED characteristic!");
    peripheral.disconnect();
    return;
  }

  while (peripheral.connected()) {
      if (Serial.available() > 0) {
        incomingByte = Serial.read();
        
        if (incomingByte == 119 || incomingByte == 115 || incomingByte == 97 || incomingByte == 100)
          ledCharacteristic.writeValue(incomingByte);
      }
  }

  Serial.println("Peripheral disconnected");
}

#include <ArduinoBLE.h>

BLEService ledService("19B10000-E8F2-537E-4F6C-D104768A1214"); // Bluetooth® Low Energy LED Service

// Bluetooth® Low Energy LED Switch Characteristic - custom 128-bit UUID, read and writable by central
BLEByteCharacteristic switchCharacteristic("19B10001-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);

const int ledPin = LED_BUILTIN; // pin to use for the LED

void setup() {
  Serial.begin(9600);
  while (!Serial);

  // set LED pin to output mode
  pinMode(ledPin, OUTPUT);

  // begin initialization
  if (!BLE.begin()) {
    Serial.println("starting Bluetooth® Low Energy module failed!");

    while (1);
  }

  // set advertised local name and service UUID:
  BLE.setLocalName("LED");
  BLE.setAdvertisedService(ledService);

  // add the characteristic to the service
  ledService.addCharacteristic(switchCharacteristic);

  // add service
  BLE.addService(ledService);

  // set the initial value for the characeristic:
  switchCharacteristic.writeValue(0);

  // start advertising
  BLE.advertise();

  Serial.println("BLE LED Peripheral");
}

void loop() {
  // listen for Bluetooth® Low Energy peripherals to connect:
  BLEDevice central = BLE.central();

  // if a central is connected to peripheral:
  if (central) {
    Serial.print("Connected to central: ");
    // print the central's MAC address:
    Serial.println(central.address());

    // while the central is still connected to peripheral:
    while (central.connected()) {
      // if the remote device wrote to the characteristic,
      // use the value to control the LED:
      if (switchCharacteristic.written()) {
        if (switchCharacteristic.value() == 119) {   // any value other than 0
          Serial.println("LED on");
          digitalWrite(ledPin, HIGH);         // will turn the LED on
        } else {                              // a 0 value
          Serial.println(F("LED off"));
          digitalWrite(ledPin, LOW);          // will turn the LED off
        }
      }
    }

    // when the central disconnects, print it out:
    Serial.print(F("Disconnected from central: "));
    Serial.println(central.address());
  }
}

mfusco · January 29, 2025, 12:39am

Just following up to see if anyone knows how I can resolve this.

cattledog · January 29, 2025, 1:59am

These two posted codes are working with my Nano33 BLE units.
I don't think the F macro is of value.

mfusco · January 30, 2025, 12:59am

Any further recommended troubleshooting steps for ESP32 boards? Additionally, when uploading the code to Giga boards I get this error:

/Users/marcofusco/Documents/Arduino/libraries/ArduinoBLE/src/BLECharacteristic.h:79:7: note: candidate: int BLECharacteristic::writeValue(int32_t, bool)
   int writeValue(int32_t value, bool withResponse = true);
       ^~~~~~~~~~

Using library ArduinoBLE at version 1.3.7 in folder: /Users/marcofusco/Documents/Arduino/libraries/ArduinoBLE 
exit status 1

Compilation error: call of overloaded 'writeValue(int&)' is ambiguous

cattledog · January 30, 2025, 1:12am

Post the complete code. The previous code was using a ByteCharacteristic

mfusco · January 30, 2025, 1:18am

Here is the code:

#include <ArduinoBLE.h>

int incomingByte = 0;

void setup() {
  Serial.begin(9600);
  while (!Serial);

  // initialize the Bluetooth® Low Energy hardware
  BLE.begin();

  Serial.println("Bluetooth® Low Energy Central - LED control");

  // start scanning for peripherals
  BLE.scanForUuid("19B10000-E8F2-537E-4F6C-D104768A1214");
} 

void loop() {
  // check if a peripheral has been discovered
  BLEDevice peripheral = BLE.available();

  if (peripheral) {
    // discovered a peripheral, print out address, local name, and advertised service
    Serial.print("Found ");
    Serial.print(peripheral.address());
    Serial.print(" '");
    Serial.print(peripheral.localName());
    Serial.print("' ");
    Serial.print(peripheral.advertisedServiceUuid());
    Serial.println();

    if (peripheral.localName() != "LED") {
      return;
    }

    // stop scanning
    BLE.stopScan();

    controlLed(peripheral);

    // peripheral disconnected, start scanning again
    BLE.scanForUuid("19B10000-E8F2-537E-4F6C-D104768A1214");
  }
}

void controlLed(BLEDevice peripheral) {
  // connect to the peripheral
  Serial.println("Connecting ...");

  if (peripheral.connect()) {
    Serial.println("Connected");
  } else {
    Serial.println("Failed to connect!");
    return;
  }

  // discover peripheral attributes
  Serial.println("Discovering attributes ...");
  if (peripheral.discoverAttributes()) {
    Serial.println("Attributes discovered");
  } else {
    Serial.println("Attribute discovery failed!");
    peripheral.disconnect();
    return;
  }

  // retrieve the LED characteristic
  BLECharacteristic ledCharacteristic = peripheral.characteristic("19b10001-e8f2-537e-4f6c-d104768a1214");

  if (!ledCharacteristic) {
    Serial.println("Peripheral does not have LED characteristic!");
    peripheral.disconnect();
    return;
  } else if (!ledCharacteristic.canWrite()) {
    Serial.println("Peripheral does not have a writable LED characteristic!");
    peripheral.disconnect();
    return;
  }

  while (peripheral.connected()) {
      if (Serial.available() > 0) {
        incomingByte = Serial.read();
        
        if (incomingByte == 119 || incomingByte == 115 || incomingByte == 97 || incomingByte == 100)
          ledCharacteristic.writeValue(incomingByte);
      }
  }

  Serial.println("Peripheral disconnected");
}

cattledog · January 30, 2025, 2:06am

I must not have noticed the change I made to your sketch when I was running it the other day.

//int incomingByte = 0;
byte incomingByte = 0;

With this change the code compiles without an error at this line.
ledCharacteristic.writeValue(incomingByte);

mfusco · January 30, 2025, 2:24am

Thank you. The code uploads now, however I'm not able to establish a connection with a combination of multiple different boards.

mfusco · February 1, 2025, 3:13am

Just following up for a solution to resolve this.

cattledog · February 1, 2025, 6:56am

Can you connect to the peripheral with a phone app like LightBlue or nrfConnect?
If so, does the stay connected longer than your central app?

cattledog · February 1, 2025, 5:20pm

I have run your two sketches and they stayed connected for over 12 hours. An esp32 was the peripheral, and a Nano 33 is the central.

I have two open instances of the ide, and the connection process may be more reliable if you start the peripheral sketch first, and open the monitor for it. Then the Central can find and connect to it when its monitor is opened.

system · July 31, 2025, 5:20pm

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.

Topic		Replies	Views
ESP32 BLE Bluetooth Examples Confuse Me Programming	12	3682	July 20, 2025
Establish BLE connection with phone and nano esp32 Nano ESP32	24	6194	March 3, 2024
Sending information two ways with Arduino Nano BLE Sense Nano 33 BLE Sense	12	195	September 2, 2025
Bluetooth LE Serial terminal link, ESP32S3 to Android Phone General Guidance	15	763	August 19, 2025
ESP32-S3 Bluetooth projects now won't compile 3rd Party Boards	16	699	February 2, 2026

Troubleshooting BLE

Related topics