variazione frequenza pwm arduino uno

Salve a tutti, Anticipo che non sono alle prime armi con arduino ... Leggevo su internet che c'è la possibilità di modificare la frequenza delle uscite pwm dell'arduino (http://www.mauroalfieri.it/elettronica/frequenza-pwm-arduino-duty-cycle.html) ma sinceramente non ho capito come fare... So che l'uscita 11 dell' arduino lavora ad una frequenza defoult di 488Hz, come posso fare per aumentarla? o almeno è possibile? Grazie

Basta che aggiungi il codice al tuo sketch e nel tuo setup() la richiami.

Personalmente non l'ho mai usata ma ti basterebbe:

void setup() {
  // Modifichiamo la frequenza da 31250Hz / 64 = 488 Hz 
  // a 31250Hz / 8 = 3904 Hz
  // Questa riga di codice cambia il prescaler del timer0 sul pin 5 da 64 default a 8
  setPwmFrequency(5, 8); 
}

void loop(){
  // quello che vuoi fare con il tuo segnale pwm con frequenza moltiplicata di 8
}

/**
 * Divides a given PWM pin frequency by a divisor.
 *
 * The resulting frequency is equal to the base frequency divided by
 * the given divisor:
 *   - Base frequencies:
 *      o The base frequency for pins 3, 9, 10, and 11 is 31250 Hz.
 *      o The base frequency for pins 5 and 6 is 62500 Hz.
 *   - Divisors:
 *      o The divisors available on pins 5, 6, 9 and 10 are: 1, 8, 64,
 *        256, and 1024.
 *      o The divisors available on pins 3 and 11 are: 1, 8, 32, 64,
 *        128, 256, and 1024.
 *
 * PWM frequencies are tied together in pairs of pins. If one in a
 * pair is changed, the other is also changed to match:
 *   - Pins 5 and 6 are paired on timer0
 *   - Pins 9 and 10 are paired on timer1
 *   - Pins 3 and 11 are paired on timer2
 *
 * Note that this function will have side effects on anything else
 * that uses timers:
 *   - Changes on pins 3, 5, 6, or 11 may cause the delay() and
 *     millis() functions to stop working. Other timing-related
 *     functions may also be affected.
 *   - Changes on pins 9 or 10 will cause the Servo library to function
 *     incorrectly.
 *
 * Thanks to macegr of the Arduino forums for his documentation of the
 * PWM frequency divisors. His post can be viewed at:
 *   http://www.arduino.cc/cgi-bin/yabb2/YaBB.pl?num=1235060559/0#4
 */
void setPwmFrequency(int pin, int divisor) {
  byte mode;
  if(pin == 5 || pin == 6 || pin == 9 || pin == 10) {
    switch(divisor) {
      case 1: mode = 0x01; break;
      case 8: mode = 0x02; break;
      case 64: mode = 0x03; break;
      case 256: mode = 0x04; break;
      case 1024: mode = 0x05; break;
      default: return;
    }
    if(pin == 5 || pin == 6) {
      TCCR0B = TCCR0B & 0b11111000 | mode;
    } else {
      TCCR1B = TCCR1B & 0b11111000 | mode;
    }
  } else if(pin == 3 || pin == 11) {
    switch(divisor) {
      case 1: mode = 0x01; break;
      case 8: mode = 0x02; break;
      case 32: mode = 0x03; break;
      case 64: mode = 0x04; break;
      case 128: mode = 0x05; break;
      case 256: mode = 0x06; break;
      case 1024: mode = 0x7; break;
      default: return;
    }
    TCCR2B = TCCR2B & 0b11111000 | mode;
  }
}

Bada bene che in giro non è specificato se ti serve una libreria per poter scrivere in TCCR2B la chiave della funzione è quella, l'ultima riga di codice della funzione.

Se non compila prova ad importare la libreria Timer.

Grazie mille per la risposta gremlinc5…
Appena avrò 10 minuti di tempo libero provo e ti faccio sapere com’è andata.