I want to store some parameters in my project to a memory, I can retrieve after a power cycle/reset. What functions do I use? Is it simple to explain, or can someone give me link to tutorial, please?
You can use the Arduino's [u]EEPROM[/u], which like the flash memory (which stores the program) is non-volatile memory.
What kind of memory you have? is it volatile? How many bits?
DVDoug: Thanks for the reply I will look this up.
BillHo: I am using Arduino Uno, and move my project to a nano after testing. Will also use functions in a mega 2560. So, whatever memory comes stock with those basic boards without any modifications.
Sounds like you want eeprom then. See the product pages (or datasheet for the microcontroller) to check the exact amount of eeprom memory available (different micros have different amounts of eeprom, same as other types of memory), and the link above for info on how to read and write it.
I won't be recording video files to the eeprom, just want to store a few bytes, maybe 10 at the most.
You may like to learning more on the memories of an Arduino
and you may work on some of the example like this on how to use EEPROM
/***
EEPROM Update method
Stores values read from analog input 0 into the EEPROM.
These values will stay in the EEPROM when the board is
turned off and may be retrieved later by another sketch.
If a value has not changed in the EEPROM, it is not overwritten
which would reduce the life span of the EEPROM unnecessarily.
Released using MIT licence.
***/
#include <EEPROM.h>
/** the current address in the EEPROM (i.e. which byte we're going to write to next) **/
int address = 0;
void setup() {
/** EMpty setup **/
}
void loop() {
/***
need to divide by 4 because analog inputs range from
0 to 1023 and each byte of the EEPROM can only hold a
value from 0 to 255.
***/
int val = analogRead(0) / 4;
/***
Update the particular EEPROM cell.
these values will remain there when the board is
turned off.
***/
EEPROM.update(address, val);
/***
The function EEPROM.update(address, val) is equivalent to the following:
if( EEPROM.read(address) != val ){
EEPROM.write(address, val);
}
***/
/***
Advance to the next address, when at the end restart at the beginning.
Larger AVR processors have larger EEPROM sizes, E.g:
- Arduno Duemilanove: 512b EEPROM storage.
- Arduino Uno: 1kb EEPROM storage.
- Arduino Mega: 4kb EEPROM storage.
Rather than hard-coding the length, you should use the pre-provided length function.
This will make your code portable to all AVR processors.
***/
address = address + 1;
if (address == EEPROM.length()) {
address = 0;
}
/***
As the EEPROM sizes are powers of two, wrapping (preventing overflow) of an
EEPROM address is also doable by a bitwise and of the length - 1.
++address &= EEPROM.length() - 1;
***/
delay(100);
}
/*
* EEPROM Read
*
* Reads the value of each byte of the EEPROM and prints it
* to the computer.
* This example code is in the public domain.
*/
#include <EEPROM.h>
// start reading from the first byte (address 0) of the EEPROM
int address = 0;
byte value;
void setup() {
// initialize serial and wait for port to open:
Serial.begin(9600);
while (!Serial) {
; // wait for serial port to connect. Needed for native USB port only
}
}
void loop() {
// read a byte from the current address of the EEPROM
value = EEPROM.read(address);
Serial.print(address);
Serial.print("\t");
Serial.print(value, DEC);
Serial.println();
/***
Advance to the next address, when at the end restart at the beginning.
Larger AVR processors have larger EEPROM sizes, E.g:
- Arduno Duemilanove: 512b EEPROM storage.
- Arduino Uno: 1kb EEPROM storage.
- Arduino Mega: 4kb EEPROM storage.
Rather than hard-coding the length, you should use the pre-provided length function.
This will make your code portable to all AVR processors.
***/
address = address + 1;
if (address == EEPROM.length()) {
address = 0;
}
/***
As the EEPROM sizes are powers of two, wrapping (preventing overflow) of an
EEPROM address is also doable by a bitwise and of the length - 1.
++address &= EEPROM.length() - 1;
***/
delay(500);
}
You can only write to the EEPROM about 100,000 times. While that sounds a lot you can easily exceed this in a few minutes with bad code. So you need to limit the number of times you update this stored value.
BillHO: Thanks for the examples, they are straight forward and easy to undertand.
Grumpy_Mike: Thanks for the warning. I'm really clumsy with my mistakes, this information is useful.