2D dynamic boolean array

hi, I want make a 2D dynamic boolean array, but I'm not sure with this code .I need add indexes gradually. example - define array [2][2] and later expand to array [5][3]

 array = ( boolean** )malloc( first_index*sizeof( boolean* ) );
 array[first_index] = ( boolean* )malloc(second_index*sizeof(boolean ) );

Sorry for my english

An example of how to allocate and deallocate memory for 2-D arrays. But: See Footnote.

void setup()
{
    Serial.begin(9600);
}


int counter = 0;
void loop()
{
    // Pointer to pointer will be used to implement 2-D dynamically allocated array
    int **iarray;

    int nrows = 2;
    int ncols = 3;
    
    // Allocate an "array" of pointers for the rows
    iarray = (int**)malloc(nrows*sizeof(iarray[0]));
    if (!iarray) {
        Serial.print("Couldn't allocate memory for rows.");
        return;
    }


    // For each row, allocate an "array" of ints.
    for (int i = 0; i < nrows; i++) {
        iarray[i] = (int *)malloc(ncols*sizeof(iarray[0][0]));
        if (!iarray[i]) {
            Serial.print("Couldn't allocate memory for row ");
            Serial.println(i);
            return; // Actually you should de-allocate memory for all
                    // of the rows that did get allocated and then
                    // de-allocate memory for iarray.
        }
        for (int j = 0; j < ncols; j++) {
            iarray[i][j] = counter + j + ncols*i; // Put something different in each one
        }
    }
    for (int i = 0; i < nrows; i++) {
        Serial.print("Row ");Serial.print(i);Serial.print(": ");
        for (int j = 0; j < ncols; j++) {
            Serial.print("  ");Serial.print(iarray[i][j]);
        }
        Serial.println();
    }
    Serial.println();

    // De-allocate storage for each of the rows
    for (int i = 0; i < nrows; i++) {
        free(iarray[i]);
    }

    // Deallocate storage for the array of row pointers
    free(iarray);
    // After previous memory has been cleared, you can reallocate with
    // whatever values of nrows and ncols you want (subject to "heap"
    // size limits).
    ++counter;
    delay(1000);
}

Output:


[color=#0000ff]Row 0:   0  1  2
Row 1:   3  4  5

Row 0:   1  2  3
Row 1:   4  5  6

Row 0:   2  3  4
Row 1:   5  6  7

Row 0:   3  4  5
Row 1:   6  7  8

Row 0:   4  5  6
Row 1:   7  8  9
.
.
.
[/color]

This is just an illustration of how to do it. In your loop() you would deallocate the storage then assign new values to nrows and ncols and go through the allocation steps again. I might even write a function to allocate storage for nrows and ncols and another function to deallocate them. I’ll leave that up to you.

Regards,

Dave
Footnote:
This example is (I believe) perfectly valid C and C++ code.

However…

I am very reluctant to use dynamic memory allocation in any embedded system that I expect to run forever. Why do I have misgivings? Lack of garbage collection in the standard library function malloc(). That’s why.

It is possible to allocate and deallocate memory (repeatedly) in such a way that there is enough memory in the heap to do the job but it is fragmented so that that not enough contiguous memory is available to finish it.

I mean, if the application is supposed to do something and quit, that’s one thing, but if it is supposed to run forever and you don’t know ahead of time how much memory you actually need, then, you are really, really (really) asking for trouble. For simple cases, you might convince yourself that such fragmentation will not occur, but…

That’s just an opinion (my opinion), and it’s worth exactly what you want it to be worth.

I programing a robot to "High school competition".His task is mapped a "room". He use array to save information about room as square site. False - square is clear True - is there a block The informatioun about squares will be save in array under indexes [x][y] but I must used negative coordinates. I use 4-quadrants this means 4x 2D array...

I have idea use one array with offset zero because if I use array [100][100] and as zero is 50.The "room" can be long 7,5m*2 (one square is 15cm) which is enough But I'd solved it universally and more elegant.

Again, sorry for the English, perhaps it will possible to understand :D

array [100][100]

But a 100x100 array has 10,000 elements. That won't fit into any of the chips used in Arduino systems.

Sorry.

Regards,

Dave

ou epic fail xD so 36x36 zero is 18 and this is 2,7m on every side I test robot with this and later...

A boolean still has 8 bits.

http://arduino.cc/en/Reference/BooleanVariables

(Each boolean variable occupies one byte of memory.)

That boolean has enough room to hold information about 8 squares. Proper indexing would allow you to store information about the room in a 1D array, and in less space, if stored bit-by-bit.

http://en.wikipedia.org/wiki/Bit_array http://en.wikipedia.org/wiki/Bitfield

http://michael.dipperstein.com/bitlibs/index.html http://michael.dipperstein.com/bitlibs/#bitarray

The bitarray library in the last two links might be worthwhile to look at the source code, it's not an Arduino library.

I am very reluctant to use dynamic memory allocation in any embedded system that I expect to run forever. Why do I have misgivings? Lack of garbage collection in the standard library function malloc(). That's why.

It is possible to allocate and deallocate memory (repeatedly) in such a way that there is enough memory in the heap to do the job but it is fragmented so that that not enough contiguous memory is available to finish it.

I mean, if the application is supposed to do something and quit, that's one thing, but if it is supposed to run forever and you don't know ahead of time how much memory you actually need, then, you are really, really (really) asking for trouble. For simple cases, you might convince yourself that such fragmentation will not occur, but...

That's just an opinion (my opinion), and it's worth exactly what you want it to be worth.

not to mention that even if you did everything right it is still really tough to figure out just how much memory you are allocating. And if you do know, why does it need to be dynamic?

[The robot's] task is mapped a "room". He use array to save information about room as square site.

They make SD card shields for arduino and it sounds like you may need to store a lot of data (>8k). It may be worth it to think of a linear data format that can be parsed later and store it to an SD card since they are cheap, easy, and give virtually unlimited storage.

No I didnt use arduino board. I made own board but I can use bluetooh for send data to PC or any device ... I use this robot in "test arena" c. 4x4square and for test the functionality of the algorithm in larger areas can be used bluetooh.

ah i see. In that case you can go to town with malloc() (in the pc's code). ;D

I searched and found this Flash | Arduiniana can I use it to solved my problem? is it usable solution?

can I use it to solved my problem?

If the array is static (a fixed size), yes.

c. 15kB is enought I can presume define large static array . for my demonstration is it good.For the function of the algorithm in the larger areas I will use the Bluetooth. Thanx