Arduino Pro Micro and multiple MPU6050s

Hello everyone, I am trying to use multiple mpu6050s but I am pretty new to using shift registers and giving each sensor an address from what I see on the forums. I don't have code yet as I'm unsure on how to even code it when adding the different addresses. I am trying to use all mpus at the same time to get their values only.

My current wiring on the pro micro is

1st Mpu6050 to Micro
Vcc -> Vcc
Gnd -> Gnd
SCL -> 3
SDA -> 2
AD0 --> not sure
Temporary choices for 2nd MPU6050 to Micro
Vcc -> Vcc
Gnd -> Gnd
SCL -> 3
SDA -> 2
AD0 -> not sure yet either
I am not sure how to do the 2nd and 3rd one, planning to do 10 but trying to at least figure out how to do the first 2.

Also if anyone know a youtube video or something in which I can further read more about how I can code the I2C part as its relatively new for me

What makes you think you need shift registers.

Generally speaking,
the address pin (if available) of I2C devices can be used as "chip select" pin.
Join all SCL, SDA, VCC, GND pins, and connect the address pin of each device to a digital output pin.
Make one HIGH (or LOW) at the time, and ten talk to that unique/selected I2c address.
Leo..

Hi @BanditSalandit

The level of the MPU6050's AD0 pin input determines its I2C address:

AD0 = 0 (GND) : I2C Address = 0x68
AD0 = 1 (3.3V) : I2C Address = 0x69

(Note: make sure it's pulled to 3.3V, since the MPU6050 isn't 5V tolerant).

This allows two MPU6050's to be used simultaneously on the same bus.

Would I have cast the mpus as objects so I can then call their gyro values individually?
If so how would that look like?

Also what would be the next step to getting 3+?

Hi, @BanditSalandit
Welcome to the forum.

Please read the post at the start of any forum , entitled "How to use this Forum".

This will help with advice on how to present your code and problems.

Can you post a picture of your MPU6050 and or link to where you purchased it?
So we know which module you have.

What is your project?
What are you trying to do with up to 10 IMUs?

Thanks.. Tom.. :smiley: :+1: :coffee: :australia:

My project is making a haptic glove as controller or keyboard input. I have the idea for the code which would be reading the gyro values to determine it's position (2 on each finger or maybe just 1) for 1 glove. Using 2 micros once this prototype works.

The one I'm using

I looked into the project even more on the documentation and I'm confused how I could switch to the 2nd mpu in this code.

1. #include<Wire.h>
2. const int MPU_addr=0x68; // I2C address of the MPU-6050
 //Here I would add const int MPU_addr2=0x69 as its 2nd mpu 
//3rd mpu would be 0x70?
3. int16_t AcX,AcY,AcZ,Tmp,GyX,GyY,GyZ;
//Multiple lines of different variables for each mpu??? ^^^^^^^^
4. void setup(){

5. Wire.begin();
6. Wire.beginTransmission(MPU_addr);
//(Would I add all mpus begin transmission now?)
7. Wire.write(0x6B); // PWR_MGMT_1 register
//(What do I add for additional mpus?)
8. Wire.write(0); // set to zero (wakes up the MPU-6050)   (Does this set all of them 0?)
9. Wire.endTransmission(true);
10. Serial.begin(9600);
11. }

12. void loop(){

13. Wire.beginTransmission(MPU_addr);
14. Wire.write(0x3B); // starting with register 0x3B (ACCEL_XOUT_H)
15. Wire.endTransmission(false);
16. Wire.requestFrom(MPU_addr,14,true); // request a total of 14 registers
17. AcX=Wire.read()<<8|Wire.read(); // 0x3B (ACCEL_XOUT_H) & 0x3C (ACCEL_XOUT_L)
//Confused here from lines 13-17 on how to add the 2nd mpu

Hi @BanditSalandit

If you require more than two MP6050's on the Pro Micro then you'll need to use an I2C multiplexer, like this one: https://learn.adafruit.com/adafruit-tca9548a-1-to-8-i2c-multiplexer-breakout?view=all.

You just need to double up on everything, two MPU6050 addresses, as well as variables to store the results.

Using I2C, I often find it helpful to include these wrapper functions:

void writeByte(uint8_t address, uint8_t subAddress, uint8_t data)
{
  Wire.beginTransmission(address);  // Initialize the Tx buffer
  Wire.write(subAddress);           // Put slave register address in Tx buffer
  Wire.write(data);                 // Put data in Tx buffer
  Wire.endTransmission();           // Send the Tx buffer
}

uint8_t readByte(uint8_t address, uint8_t subAddress)
{
  uint8_t data; // `data` will store the register data   
  Wire.beginTransmission(address);         // Initialize the Tx buffer
  Wire.write(subAddress);                  // Put slave register address in Tx buffer
  Wire.endTransmission(false);             // Send the Tx buffer, but send a restart to keep connection alive
  Wire.requestFrom(address, (uint8_t) 1);  // Read one byte from slave register address 
  data = Wire.read();                      // Fill Rx buffer with result
  return data;                             // Return data read from slave register
}

void readBytes(uint8_t address, uint8_t subAddress, uint8_t count, uint8_t* dest)
{  
  Wire.beginTransmission(address);   // Initialize the Tx buffer
  Wire.write(subAddress);            // Put slave register address in Tx buffer
  Wire.endTransmission(false);       // Send the Tx buffer, but send a restart to keep connection alive
  uint8_t i = 0;
        Wire.requestFrom(address, count);  // Read bytes from slave register address 
  while (Wire.available()) {
        dest[i++] = Wire.read(); }         // Put read results in the Rx buffer
}

This simplfies the code, for example to access the MPU6050 gyroscope data:

void readGyroData(uint8_t address, int16_t &gx, int16_t &gy, int16_t &gz)
{
  uint8_t rawData[6];  // x/y/z gyro register data stored here
  readBytes(address, GYRO_XOUT_H, 6, &rawData[0]);  // Read the six raw data registers sequentially into data array
  gx = (int16_t)((rawData[0] << 8) | rawData[1]) ;  // Turn the MSB and LSB into a signed 16-bit value
  gy = (int16_t)((rawData[2] << 8) | rawData[3]) ;  
  gz = (int16_t)((rawData[4] << 8) | rawData[5]) ; 
}

and the accelerometer:

void readAccelData(uint8_t address, int16_t &ax, int16_t &ay, int16_t &az)
{
  uint8_t rawData[6];  // x/y/z accel register data stored here
  readBytes(address, ACCEL_XOUT_H, 6, &rawData[0]); // Read the six raw data registers into data array
  ax = (int16_t)((rawData[0] << 8) | rawData[1]) ;  // Turn the MSB and LSB into a signed 16-bit value
  ay = (int16_t)((rawData[2] << 8) | rawData[3]) ;  
  az = (int16_t)((rawData[4] << 8) | rawData[5]) ; 
}

You can then call on these functions, specifying which MPU6050s you're accessing in the loop():

#define MPU_ADDRESS_1 0x68              // MPU6050 addresses
#define MPU_ADDRESS_2 0x69

int16_t gx1, gy1, gz1, ax1, ay1, az1;   // Define MPU6050 result variables
int16_t gx2, gy2, gz2, ax2, ay2, az2;

void setup() 
{
  // Initialisation code goes here..,  
}

void loop()
{
  // ... 
  readGyroData(MPU_ADDRESS_1, gx1, gy1, gz1);   // Read gyro data from MPU6050 1
  readGyroData(MPU_ADDRESS_2, gx2, gy2, gz2);   // Read gyro data from MPU6050 2
  readAccelData(MPU_ADDRESS_1, ax1, ay1, az1);  // Read accelerometer data from MPU6050 1
  readAccelData(MPU_ADDRESS_2, ax2, ay2, az2);  // Read accelerometer data from MPU6050 2
  //
  // Process the gyro and accelerometer data... gx1, gy1, etc...
  //
}

@BanditSalandit By the way, GYRO_XOUT_H and ACCL_XOUT_H are MPU6050 register definitions:

#define ACCEL_XOUT_H     0x3B
#define GYRO_XOUT_H      0x43

Thank you so much for the help, your explanations are very clear. For the mpu6050 register definitions only 1 set has to be defined for all mpus?

Hi @BanditSalandit

Yes, that's right. There only needs to be one set of register defintions. For the MPU6050, I just use these, (although I only use a few of them):

// Define registers per MPU6050, Register Map and Descriptions, Rev 4.2, 08/19/2013 6 DOF Motion sensor fusion device
// Invensense Inc., www.invensense.com
// See also MPU-6050 Register Map and Descriptions, Revision 4.0, RM-MPU-6050A-00, 9/12/2012 for registers not listed in 
// above document; the MPU6050 and MPU-9150 are virtually identical but the latter has an on-board magnetic sensor
//
#define XGOFFS_TC        0x00 // Bit 7 PWR_MODE, bits 6:1 XG_OFFS_TC, bit 0 OTP_BNK_VLD                 
#define YGOFFS_TC        0x01                                                                          
#define ZGOFFS_TC        0x02
#define X_FINE_GAIN      0x03 // [7:0] fine gain
#define Y_FINE_GAIN      0x04
#define Z_FINE_GAIN      0x05
#define XA_OFFSET_H      0x06 // User-defined trim values for accelerometer
#define XA_OFFSET_L_TC   0x07
#define YA_OFFSET_H      0x08
#define YA_OFFSET_L_TC   0x09
#define ZA_OFFSET_H      0x0A
#define ZA_OFFSET_L_TC   0x0B
#define SELF_TEST_X      0x0D
#define SELF_TEST_Y      0x0E    
#define SELF_TEST_Z      0x0F
#define SELF_TEST_A      0x10
#define XG_OFFS_USRH     0x13  // User-defined trim values for gyroscope; supported in MPU-6050?
#define XG_OFFS_USRL     0x14
#define YG_OFFS_USRH     0x15
#define YG_OFFS_USRL     0x16
#define ZG_OFFS_USRH     0x17
#define ZG_OFFS_USRL     0x18
#define SMPLRT_DIV       0x19
#define CONFIGURATION    0x1A
#define GYRO_CONFIG      0x1B
#define ACCEL_CONFIG     0x1C
#define FF_THR           0x1D  // Free-fall
#define FF_DUR           0x1E  // Free-fall
#define MOT_THR          0x1F  // Motion detection threshold bits [7:0]
#define MOT_DUR          0x20  // Duration counter threshold for motion interrupt generation, 1 kHz rate, LSB = 1 ms
#define ZMOT_THR         0x21  // Zero-motion detection threshold bits [7:0]
#define ZRMOT_DUR        0x22  // Duration counter threshold for zero motion interrupt generation, 16 Hz rate, LSB = 64 ms
#define FIFO_EN          0x23
#define I2C_MST_CTRL     0x24   
#define I2C_SLV0_ADDR    0x25
#define I2C_SLV0_REG     0x26
#define I2C_SLV0_CTRL    0x27
#define I2C_SLV1_ADDR    0x28
#define I2C_SLV1_REG     0x29
#define I2C_SLV1_CTRL    0x2A
#define I2C_SLV2_ADDR    0x2B
#define I2C_SLV2_REG     0x2C
#define I2C_SLV2_CTRL    0x2D
#define I2C_SLV3_ADDR    0x2E
#define I2C_SLV3_REG     0x2F
#define I2C_SLV3_CTRL    0x30
#define I2C_SLV4_ADDR    0x31
#define I2C_SLV4_REG     0x32
#define I2C_SLV4_DO      0x33
#define I2C_SLV4_CTRL    0x34
#define I2C_SLV4_DI      0x35
#define I2C_MST_STATUS   0x36
#define INT_PIN_CFG      0x37
#define INT_ENABLE       0x38
#define DMP_INT_STATUS   0x39  // Check DMP interrupt
#define INT_STATUS       0x3A
#define ACCEL_XOUT_H     0x3B
#define ACCEL_XOUT_L     0x3C
#define ACCEL_YOUT_H     0x3D
#define ACCEL_YOUT_L     0x3E
#define ACCEL_ZOUT_H     0x3F
#define ACCEL_ZOUT_L     0x40
#define TEMP_OUT_H       0x41
#define TEMP_OUT_L       0x42
#define GYRO_XOUT_H      0x43
#define GYRO_XOUT_L      0x44
#define GYRO_YOUT_H      0x45
#define GYRO_YOUT_L      0x46
#define GYRO_ZOUT_H      0x47
#define GYRO_ZOUT_L      0x48
#define EXT_SENS_DATA_00 0x49
#define EXT_SENS_DATA_01 0x4A
#define EXT_SENS_DATA_02 0x4B
#define EXT_SENS_DATA_03 0x4C
#define EXT_SENS_DATA_04 0x4D
#define EXT_SENS_DATA_05 0x4E
#define EXT_SENS_DATA_06 0x4F
#define EXT_SENS_DATA_07 0x50
#define EXT_SENS_DATA_08 0x51
#define EXT_SENS_DATA_09 0x52
#define EXT_SENS_DATA_10 0x53
#define EXT_SENS_DATA_11 0x54
#define EXT_SENS_DATA_12 0x55
#define EXT_SENS_DATA_13 0x56
#define EXT_SENS_DATA_14 0x57
#define EXT_SENS_DATA_15 0x58
#define EXT_SENS_DATA_16 0x59
#define EXT_SENS_DATA_17 0x5A
#define EXT_SENS_DATA_18 0x5B
#define EXT_SENS_DATA_19 0x5C
#define EXT_SENS_DATA_20 0x5D
#define EXT_SENS_DATA_21 0x5E
#define EXT_SENS_DATA_22 0x5F
#define EXT_SENS_DATA_23 0x60
#define MOT_DETECT_STATUS 0x61
#define I2C_SLV0_DO      0x63
#define I2C_SLV1_DO      0x64
#define I2C_SLV2_DO      0x65
#define I2C_SLV3_DO      0x66
#define I2C_MST_DELAY_CTRL 0x67
#define SIGNAL_PATH_RESET  0x68
#define MOT_DETECT_CTRL   0x69
#define USER_CTRL        0x6A  // Bit 7 enable DMP, bit 3 reset DMP
#define PWR_MGMT_1       0x6B // Device defaults to the SLEEP mode
#define PWR_MGMT_2       0x6C
#define DMP_BANK         0x6D  // Activates a specific bank in the DMP
#define DMP_RW_PNT       0x6E  // Set read/write pointer to a specific start address in specified DMP bank
#define DMP_REG          0x6F  // Register in DMP from which to read or to which to write
#define DMP_REG_1        0x70
#define DMP_REG_2        0x71
#define FIFO_COUNTH      0x72
#define FIFO_COUNTL      0x73
#define FIFO_R_W         0x74
#define WHO_AM_I_MPU6050 0x75 // Should return 0x68 or 0x69 depending on AD0