'class WiFiClass' has no member named 'softAP' error

Development Tools IDE 1.x
1

Hey guys,
Unfortunately when I want to compile the WIFI example of the Arduino IDE , I receive this error :
'class WiFiClass' has no member named 'softAP'
Here is the code:

#include "WiFi.h"
 
const char *ssid = "MyESP32AP";
const char *password = "testpassword";
 
void setup() {
 
  Serial.begin(115200);
  WiFi.softAP(ssid, password);
 
  Serial.println();
  Serial.print("IP address: ");
  Serial.println(WiFi.softAPIP());
 
}
 
void loop() {}

I wanted to set up esp32 module for AP and STA mode but basically I faced with this error in the beginning.

2

Hi
I think we need to include more libraries......

#include <WiFi.h>
#include <WiFiClient.h>
#include <WiFiAP.h>

the IDE for ESP32 AP examples : " WiFiAccessPoint.ino "

/*
  WiFiAccessPoint.ino creates a WiFi access point and provides a web server on it.

  Steps:
  1. Connect to the access point "yourAp"
  2. Point your web browser to http://192.168.4.1/H to turn the LED on or http://192.168.4.1/L to turn it off
     OR
     Run raw TCP "GET /H" and "GET /L" on PuTTY terminal with 192.168.4.1 as IP address and 80 as port

  Created for arduino-esp32 on 04 July, 2018
  by Elochukwu Ifediora (fedy0)
*/

#include <WiFi.h>
#include <WiFiClient.h>
#include <WiFiAP.h>

#define LED_BUILTIN 2   // Set the GPIO pin where you connected your test LED or comment this line out if your dev board has a built-in LED

// Set these to your desired credentials.
const char *ssid = "yourAP";
const char *password = "yourPassword";

WiFiServer server(80);


void setup() {
  pinMode(LED_BUILTIN, OUTPUT);

  Serial.begin(115200);
  Serial.println();
  Serial.println("Configuring access point...");

  // You can remove the password parameter if you want the AP to be open.
  WiFi.softAP(ssid, password);
  IPAddress myIP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(myIP);
  server.begin();

  Serial.println("Server started");
}

void loop() {
  WiFiClient client = server.available();   // listen for incoming clients

  if (client) {                             // if you get a client,
    Serial.println("New Client.");           // print a message out the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        if (c == '\n') {                    // if the byte is a newline character

          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println();

            // the content of the HTTP response follows the header:
            client.print("Click <a href=\"/H\">here</a> to turn ON the LED.<br>");
            client.print("Click <a href=\"/L\">here</a> to turn OFF the LED.<br>");

            // The HTTP response ends with another blank line:
            client.println();
            // break out of the while loop:
            break;
          } else {    // if you got a newline, then clear currentLine:
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }

        // Check to see if the client request was "GET /H" or "GET /L":
        if (currentLine.endsWith("GET /H")) {
          digitalWrite(LED_BUILTIN, HIGH);               // GET /H turns the LED on
        }
        if (currentLine.endsWith("GET /L")) {
          digitalWrite(LED_BUILTIN, LOW);                // GET /L turns the LED off
        }
      }
    }
    // close the connection:
    client.stop();
    Serial.println("Client Disconnected.");
  }
}
3

I don't think so. just tried this

#include <WiFi.h>
const char* ssid     = "ESP32-AP";
const char* password = "AB123XY";

void setup() {
  Serial.begin(115200);
  WiFi.softAP(ssid, password);
  IPAddress IP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(IP);
}

void loop() {}

and it compiled fine.

Are you sure you picked an ESP32 as the board type? did you install ESP32 dev tools?

4

Tnx for the response, I have compiled your code and still have the same issue.
Could you please tell more about the picking esp32 as the board and also dev tools?

5

Actually I want to connect it with Arduino Uno , here is the thing/

6

Arduino Uno does not offer Wi-Fi.... ➜ will not work
you need to buy an ESP32 or ESP8266 or a WiFi enabled Arduino MKR board

7

I Already bought esp32 and have connected to uno using IxT pins ,

8

why do you need the UNO for? just use the ESP32 as your microcontroller

9

because I have several outputs and I need 'em. I'm using ESP32-01 module

10

Hi
Is there the ESP32-01 module?
Please post a link for me to see this ESP32-01.
thanks

11

here is the link

12

Hi
This ESP01 is ESP8266-01, not is ESP32.

13

so you have a tutorial

what are you trying to do?

14

Sorry For late reply, I was out for several days,
I want to make communication between my Arduino uno and some other devices through Wifi Module, that's the reason.

15

the ESP01 is pretty outdated... I would pick a more capable board.

16

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.