ESP32 & SD-Card - Can't open/create File

Other Hardware Storage
1

Got an Esp32 DevKit C V2 (ESP32 NodeMCU Module WLAN WiFi Dev Kit C Development Board mit CP2102 – AZ-Delivery) with a bunch of sensors (Luxmeter, DHT11, BMP180, NTC) an RTC and an LCD.

Now i want to create the ability to store some Values on an SD-Card. So i got this 5V SPI SD-Card Reader.

image
image710×509 71.7 KB

Since I have 5V and 3.3V in my Setup there shouldnt be a Problem.

This here is the Setup of the whole Thing

image
image1471×862 12.5 KB

My Code is a bit split up to keep it modular, but here is the explanation.

This is my Setup File. I cleared all the excess Stuff like the LCD or the sensors to keep it simple.

const int SD_CardSelect = 5;    // CS-Pin of the SD-Card
void setup()
{
  // Setup Serial Connection
  Serial.begin(115200);  
  Serial.println("\n----------------------------------------------------------\n");   // Make it easier to see where the current Script starts
  Serial.println("Starting Setup, First LCD");

// Setting up all the other Things  

  // Setup SD-Card
  SD_Setup(SD_CardSelect);

  //Testing
  SD_WriteFile("Data.txt", "TestData");
  
}

To keep it modular I have the SD-Stuff in another File. The baseidea is, that in the Setup it simply connects to the SD-Card. This part works, since it returns "Connected to SD" and prints me the Cardtype 2. To keep the File open for as short as possible, I open it, write to it and close it again. At least thats the Plan. In the SD_WriteFile I can see, that the File does not exist (Even if I create it with my PC ???). "OF1" and "OF2" gets printed, but the File won't open, which is why it returns here.

#include <SD.h>

File thisFile;

bool SD_Setup(int sd_Connection)
{
  if(SD.begin(sd_Connection))
  {
    Serial.println("Connected to SD");

    Serial.println("Card Type: " + (String)SD.cardType());  // Prints 2
    
    return true;
  }
  else{
    Serial.println("Connection to SD failed. \n- Card Inserted?");
    return false;
  }
}


bool SD_WriteFile(String file, String data)
{
  Serial.println("File exists: " + (String)SD.exists(file));

  // Open File for Write
  Serial.println("OF 1");
  thisFile = SD.open(file,FILE_WRITE, true);
  Serial.println("OF 2");

  if(!thisFile)
  {
    Serial.println("Can't open File: " + file);
    return false;  // Return when File not opened
  }

  // Write to File
  Serial.println("WF 1");

  thisFile.print(data);
  
  Serial.println("WF 2");

  thisFile.close();
  Serial.println("CF");
  return true;
}

Any Ideas why this wont work? Using the Example Sketches is kinda harsh since I have no idea, since running the SD_Test Example, it wrote and changed everything correctly.

EDIT: Simulating with Wokwi shows the same error. EPS32-SD_Card.ino - Wokwi Arduino and ESP32 Simulator

1 Like
2

That is a fair plan, but i tend to keep the file object local as well.

Since you posted a snippet, without the line that is actually calling the function that creates the file, i have no idea what you are using as a 'filename' which is relevant.
All filenames are referred to as as a full path starting with a leading '/'
This is the example i have and tested.

#define LED_YELLOW 2
#define LED_BUILTIN 1
#define RXD0 12
#define TXD0 14

#include "FS.h"
#include "SD.h"
#include "SPI.h"

void setup(){
    Serial.begin(115200,SERIAL_8N1,RXD0,TXD0);
    pinMode(LED_YELLOW,OUTPUT);
    pinMode(LED_BUILTIN, OUTPUT);
    digitalWrite(LED_BUILTIN, LOW);  // active LOW 
    digitalWrite(LED_YELLOW, HIGH);  // active LOW
    
    if(!SD.begin()){
        Serial.println("Card Mount Failed");
        return;
    }
    uint8_t cardType = SD.cardType();

    if(cardType == CARD_NONE){
        Serial.println("No SD card attached");
        return;
    }

    Serial.print("SD Card Type: ");
    if(cardType == CARD_MMC){
        Serial.println("MMC");
    } else if(cardType == CARD_SD){
        Serial.println("SDSC");
    } else if(cardType == CARD_SDHC){
        Serial.println("SDHC");
    } else {
        Serial.println("UNKNOWN");
    }

    uint64_t cardSize = SD.cardSize() / (1024 * 1024);
    Serial.printf("SD Card Size: %lluMB\n", cardSize);

    listDir(SD, "/", 0);
    createDir(SD, "/mydir");
    listDir(SD, "/", 0);
    removeDir(SD, "/mydir");
    listDir(SD, "/", 2);
    writeFile(SD, "/hello.txt", "Hello ");
    appendFile(SD, "/hello.txt", "World!\n");
    readFile(SD, "/hello.txt");
    deleteFile(SD, "/foo.txt");
    renameFile(SD, "/hello.txt", "/foo.txt");
    readFile(SD, "/foo.txt");
    testFileIO(SD, "/test.txt");
    Serial.printf("Total space: %lluMB\n", SD.totalBytes() / (1024 * 1024));
    Serial.printf("Used space: %lluMB\n", SD.usedBytes() / (1024 * 1024));
    digitalWrite(LED_YELLOW, LOW);  // active LOW    
    digitalWrite(LED_BUILTIN, HIGH);  // active LOW 
}

void loop(){

}

void listDir(fs::FS &fs, const char * dirname, uint8_t levels){
    Serial.printf("Listing directory: %s\n", dirname);

    File root = fs.open(dirname);
    if(!root){
        Serial.println("Failed to open directory");
        return;
    }
    if(!root.isDirectory()){
        Serial.println("Not a directory");
        return;
    }

    File file = root.openNextFile();
    while(file){
        if(file.isDirectory()){
            Serial.print("  DIR : ");
            Serial.println(file.name());
            if(levels){
                listDir(fs, file.name(), levels -1);
            }
        } else {
            Serial.print("  FILE: ");
            Serial.print(file.name());
            Serial.print("  SIZE: ");
            Serial.println(file.size());
        }
        file = root.openNextFile();
    }
}

void createDir(fs::FS &fs, const char * path){
    Serial.printf("Creating Dir: %s\n", path);
    if(fs.mkdir(path)){
        Serial.println("Dir created");
    } else {
        Serial.println("mkdir failed");
    }
}

void removeDir(fs::FS &fs, const char * path){
    Serial.printf("Removing Dir: %s\n", path);
    if(fs.rmdir(path)){
        Serial.println("Dir removed");
    } else {
        Serial.println("rmdir failed");
    }
}

void readFile(fs::FS &fs, const char * path){
    Serial.printf("Reading file: %s\n", path);

    File file = fs.open(path);
    if(!file){
        Serial.println("Failed to open file for reading");
        return;
    }

    Serial.print("Read from file: ");
    while(file.available()){
        Serial.write(file.read());
    }
    file.close();
}

void writeFile(fs::FS &fs, const char * path, const char * message){
    Serial.printf("Writing file: %s\n", path);

    File file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }
    if(file.print(message)){
        Serial.println("File written");
    } else {
        Serial.println("Write failed");
    }
    file.close();
}

void appendFile(fs::FS &fs, const char * path, const char * message){
    Serial.printf("Appending to file: %s\n", path);

    File file = fs.open(path, FILE_APPEND);
    if(!file){
        Serial.println("Failed to open file for appending");
        return;
    }
    if(file.print(message)){
        Serial.println("Message appended");
    } else {
        Serial.println("Append failed");
    }
    file.close();
}

void renameFile(fs::FS &fs, const char * path1, const char * path2){
    Serial.printf("Renaming file %s to %s\n", path1, path2);
    if (fs.rename(path1, path2)) {
        Serial.println("File renamed");
    } else {
        Serial.println("Rename failed");
    }
}

void deleteFile(fs::FS &fs, const char * path){
    Serial.printf("Deleting file: %s\n", path);
    if(fs.remove(path)){
        Serial.println("File deleted");
    } else {
        Serial.println("Delete failed");
    }
}

void testFileIO(fs::FS &fs, const char * path){
    File file = fs.open(path);
    static uint8_t buf[512];
    size_t len = 0;
    uint32_t start = millis();
    uint32_t end = start;
    if(file){
        len = file.size();
        size_t flen = len;
        start = millis();
        while(len){
            size_t toRead = len;
            if(toRead > 512){
                toRead = 512;
            }
            file.read(buf, toRead);
            len -= toRead;
        }
        end = millis() - start;
        Serial.printf("%u bytes read for %u ms\n", flen, end);
        file.close();
    } else {
        Serial.println("Failed to open file for reading");
    }


    file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }

    size_t i;
    start = millis();
    for(i=0; i<2048; i++){
        file.write(buf, 512);
    }
    end = millis() - start;
    Serial.printf("%u bytes written for %u ms\n", 2048 * 512, end);
    file.close();
}
3

See the first Codeblock. There it gets called directly in Setup.

Testing your Example later

4

ah yes, well try :

SD_WriteFile("/Data.txt", "TestData");
1 Like
5

tried that in the Sim. Works. Now I only need to check for the real thing :smiley:

6

I ended up doing something like

bool SD_WriteFile(String file, String data)
{
file = "/" + file;

at the beginning of every SD function.

7

That is what I tought about. If i need it everywhere I could at that to the beginning and wont need to remember that.

Somehow most tutorials miss this.

stole your
file = "/" + file;
and it works thank you so much. Struggled with that for 3 Weeks and almost stopped searching for it

8

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.