How many stepper motors arduino uno can support

Projects General Guidance
1

Hi,

How many bipolar stepper motors (4 wire) can Arduino Uno supports?

Which motor driver is best for Arduino Uno for controlling stepper motors?

Can I use Analog pins to control the stepper motor?

If I use the A4988 motor driver, is it possible to connect 10 stepper motors with Arduino UNO, regardless of all running simultaneously? I am just asking we can connect them to operate them sequentially.

Total 14+6 pins. 20/2=10 stepper motors each with two pins?

2

Depends on the stepper motor and the required motor coil current.

Yes.

You are going to need a pretty healthy power supply for 20 steppers.

1 Like
3

A4988 uses STEP and DIR.
I think that 10 stepper motors will work. It is possible, but you should not do that. You need pin 0 and 1 to send debug messages to the Serial Monitor.

The Arduino Stepper library is not for the STEP and DIR signals.
There is a AccelStepper library, but it does not use interrupts, it runs in the loop(). It will only work well without delays in the sketch.
The AccelStepper library can control each stepper motor at the same time. There is also a MultiStepper option, to make the same motion with multiple steppers.

There are other libraries, and there are also boards that takes commands from the Arduino and drive the stepper motors.
There is also a Marlin project. It is used in 3D printers. I don't know how the stepper motor software is implemented.

This is a rough sketch to test 10 stepper motors with the AccelStepper library using ten A4988 drivers:

// Using the AccelStepper library.
// AccelStepper: https://www.airspayce.com/mikem/arduino/AccelStepper/
//               Copyright (C) 2009 Mike McCauley
//

#include <AccelStepper.h>

// Define the objects with pin numbers
AccelStepper stepper[10] =
{
  AccelStepper(AccelStepper::DRIVER, 0, 1),
  AccelStepper(AccelStepper::DRIVER, 2, 3),
  AccelStepper(AccelStepper::DRIVER, 4, 5),
  AccelStepper(AccelStepper::DRIVER, 6, 7),
  AccelStepper(AccelStepper::DRIVER, 8, 9),
  AccelStepper(AccelStepper::DRIVER, 10, 11),
  AccelStepper(AccelStepper::DRIVER, 12, 13),
  AccelStepper(AccelStepper::DRIVER, A5, A4),
  AccelStepper(AccelStepper::DRIVER, A3, A2),
  AccelStepper(AccelStepper::DRIVER, A1, A0),
};

unsigned long previousMillis;
const unsigned long interval = 1000UL;

void setup()
{  
  // Set limits for the stepper motors.
  for( int i=0; i<10; i++)
  {
    stepper[i].setMaxSpeed(200.0);
    stepper[i].setAcceleration(100.0);
  }

  // Move all the steppers to a certain position
  // The steppers will only move with the .run() call,
  // so these are just initial values.
  for( int i=0; i<10; i++)
  {
    stepper[i].moveTo(i * 100);
  }
}

void loop()
{
  unsigned long currentMillis = millis();
  if( currentMillis - previousMillis >= interval)
  {
    previousMillis = currentMillis;

    // random move a random stepper to a random position
    int i = random(0, 11);
    long steps = random(-100,100);
    stepper[i].move(steps);
  }

  // The library needs to update the steppers as many times as possible.
  for( int i=0; i<10; i++)
  {
    stepper[i].run();
  }
}

The simulator Wokwi can simulate the A4988.
The sketch in Wokwi:

If you want to continue with my Wokwi project, then you have to log in (it is free) and make a copy of my project (in the menu: "Save a copy.").

1 Like
4

4-wire steppers sounds like the 28BYJ48.
I managed to control 48 of them with a Nano (Uno), using three pins only,
and 150 at max speed was theoretically possible.
I used TPIC6B595 shift registers as port expanders, one per two motors.
Leo..

2 Likes
5

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.