LED Blink with Given Temp(bpm)

Projects General Guidance
1

**I want to blink the led as i given the Tempo **

The led has to Blink according to the tempo( beat per minute)

Help me to build this project.

2

Where is the tempo coming from ?
Do you want to synchronise the LED blink with a changing tempo or a fixed temp ?

2 Likes
3

Sounds like a metronome. How does your project differ from the projects you can find by searching for "arduino metronome"?

2 Likes
4

Mine this thread:

But yeah, add Arduino to just about any google search and stay busy for hours.

Worst: do that when you get a brilliant million dollar idea. :expressionless:

a7

2 Likes
5

You can start with the Blink Example. The example is a 2-second cycle (2000ms or 30BPM) and of course you can change that.

You simply invert to get the tempo (and convert milliseconds to minutes).

Now, the question is... How do you want to adjust the tempo? With a pot (easy)? With a keypad (a little harder? Something else?

And you do want a numeric display?

1 Like
6

I want to change the tempo using a variable resistor, or push buttons.

7

okay, i will look at it. thank you

8

i want to change the tempo, using variable resistor or push buttons.

9

I dont understand what did you mean at your last two sentences.

10

basically you need to combine
the blink without delay example
the debounce example

or you use a library for that

/*
  Blink a LED
  adopt interval with button press
*/

#include <Noiasca_led.h>               // download library from http://werner.rothschopf.net/microcontroller/202202_tools_led_en.htm
#include <Noiasca_button.h>            // some tools to read buttons

BlinkPin blinkLed {13};                // declare  blinking LED and assign pin
Button button[] {A0, A1};              // button connects pin with GND, "active LOW"

uint16_t interval = 500;               // the current blink intervall
const uint8_t step = 50;               // change of milliseconds for each button press

void setup() {
  Serial.begin(115200);
  blinkLed.begin();   // you have to call the .begin() method for each LED object
  for (auto &obj : button)
  {
    obj.begin();   // you have to call the .begin() method for each button
  }

  // you can set different blink intervals for your LEDs
  blinkLed.setOnInterval(interval);
  blinkLed.setOffInterval(interval);
}

void loop() {
  // read the buttons
  if (button[0].wasPressed())
  {
    Serial.println(F("button 0 was pressed, increase interval"));
    interval += step;
    Serial.print(F("new interval=")); Serial.println(interval);
    blinkLed.setOnInterval(interval);
    blinkLed.setOffInterval(interval);
  }
  if (button[1].wasPressed()) {
    Serial.println(F("button 1 was pressed, decrease interval"));
    if (interval > step) interval -= step;
    Serial.print(F("new interval=")); Serial.println(interval);
    blinkLed.setOnInterval(interval);
    blinkLed.setOffInterval(interval);
  }
  blinkLed.update();  // update the statuts of the led
}

Library from this site: http://werner.rothschopf.net/microcontroller/202202_tools_led_en.htm

11

Hello faisalzed
Keep it simple and stupid. I´ve modified the BLINKWITHOUTDELAY example of the IDE.

/*
  Blink without Delay

  Turns on and off a light emitting diode (LED) connected to a digital pin,
  without using the delay() function. This means that other code can run at the
  same time without being interrupted by the LED code.

  The circuit:
  - Use the onboard LED.
  - Note: Most Arduinos have an on-board LED you can control. On the UNO, MEGA
    and ZERO it is attached to digital pin 13, on MKR1000 on pin 6. LED_BUILTIN
    is set to the correct LED pin independent of which board is used.
    If you want to know what pin the on-board LED is connected to on your
    Arduino model, check the Technical Specs of your board at:
    https://www.arduino.cc/en/Main/Products

  created 2005
  by David A. Mellis
  modified 8 Feb 2010
  by Paul Stoffregen
  modified 11 Nov 2013
  by Scott Fitzgerald
  modified 9 Jan 2017
  by Arturo Guadalupi

  This example code is in the public domain.

  http://www.arduino.cc/en/Tutorial/BlinkWithoutDelay
*/

// constants won't change. Used here to set a pin number:
const int ledPin =  LED_BUILTIN;// the number of the LED pin
constexpr int PotPin {A8};

// Variables will change:
int ledState = LOW;             // ledState used to set the LED

// Generally, you should use "unsigned long" for variables that hold time
// The value will quickly become too large for an int to store
unsigned long previousMillis = 0;        // will store last time LED was updated

// constants won't change:
const long interval = 1000;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);
}

void loop() {
  // here is where you'd put code that needs to be running all the time.

  // check to see if it's time to blink the LED; that is, if the difference
  // between the current time and last time you blinked the LED is bigger than
  // the interval at which you want to blink the LED.
  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= map(analogRead(PotPin),0,1023,100,2000)) {
    // save the last time you blinked the LED
    previousMillis = currentMillis;

    // if the LED is off turn it on and vice-versa:
    if (ledState == LOW) {
      ledState = HIGH;
    } else {
      ledState = LOW;
    }

    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
  }
}

Have a nice day and enjoy coding in C++.

1 Like
12

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.