S'il y en a que cela intéresse, quelques simulations sur l'action d'un circuit RC sur l'établissement et la coupure du courant avec le circuit suivant :
J'ai l'habitude de numéroter moi-même les nœuds pour éviter les numérotations "ésotériques" des systèmes automatiques.
La net liste obtenue avec kicad est la suivante :
.subckt bidouilles
.model __X1 VDMOS NCHAN
V100 /100 0 12V
C1 /g 0 1u
R1 /g /e 10k
V1 /e 0 PULSE( 0 5 0 2u 2u 50m 100m )
Rpeltier1 /d /100 2
MX1 /d /g 0 __X1
.ends
Pas terrible pour faire des modifications manuelles, assez surprenant, cela donne un "subckt" c'est-à-dire un sous-circuit : il y a encore des tripatouillages qui se font dans notre dos pour avoir le vrai fichier.
Mon fichier "a.cir"
Important ; un astérisque "*" ou un point virgule ";" servent à mettre un texte en commentaire.
Les graphiques fournis par NGspice ressemblent à ceux de kicad : c'est normal parce que c'est Kicad qui utilise Ngspice.
En manuel, il y a des possibilités de personnalisations que je n'ai pas trouvé accessibles par l'interface graphique Kicad.
Circuit a.cir :
.title Peltier
.include ./IRL520.lib ; permet de simmuler avec l'un
.include ./AO3400.lib ; ou l'autre des transistors
*
.save all
.options savecurrents
*
V1 e 0 PULSE(5 0 0 10u 10u 5s 10s)
R1 e g 10k
C1 g 0 1u
*X1 d g 0 irl520 ; -->mis en commentaire
X1 d g 0 AO3400 ; --> actif
Rpeltier 100 d 2
*
V100 100 0 DC=12
.control
* toutes les courbes sont gardées en mémoire depuis le lancementde la session ngspice
* le plus simple est de vider la mémoire.
destroy all
*Personalisation :
set color0 = white
set color1 = black
tran 10u 6s 4.95s
alter C1 = 10u ; alter permet de changer la valeur d'un composant et cours de simulation
tran 10u 6s 4.95s
*
alter C1 = 50u
tran 10u 6s 4.95s
*
alter C1 = 100u
tran 10u 6s 4.95s
*
plot tran1.V(g) tran2.V(g) tran3.V(g) tran4.V(g) xlabel 'T emps en ' ylabel 'volts '
plot tran1.V(d) tran2.V(d) tran3.V(d) tran4.V(d) xlabel 'T emps en' ylabel 'volts '
plot tran1.@Rpeltier[i] tran2.@Rpeltier[i] tran3.@Rpeltier[i] tran4.@Rpeltier[i] xlabel 'T emps en' ylabel 'ampères'
.endc
.end
Attention le fichier doit se terminer par une ligne vide après le ".end" final !
tran 10u 6s 4.95s
Analyse transitoire avec un pas de calcul max 10 microseconde, temps initial = 0 s, temps final = 6 s et affichage des valeurs seulement à partir de 4,95 s
.include ./IRL520.lib
indique à NGspice de charger le fichier modèle de l'IRL520 dans le répertoire courant (./ = syntaxe Linux).
Documentation NGspice : ngspice tutorial for beginners
Lancement de NGspice dans un terminal :
Au prompt, on écrit le nom du fichier de description :
Mot clé : "source"
ngspice -> source a.cir
Et on obtient : les graphiques demandés. Je ne mets que celui de l'allure du courant dans le peltier.
J'ai utilisé le mot clé "alter" pour lancer des simulations avec des valeurs de C1 différentes tout traçant les courbes dans le même graphique.
La simulation a été faite avec un AO3400 en boitier SOT23.
La même simulation avec un IRL520 en boîtier TO220.
Les temps de retard à l'établissement et à la coupure sont directement dépendants du Vgs threshold du transistor.
L'IRL520 est prévu pour fonctionner avec une commande Vgs = 5 V
L'AO3400 est prévu pour fonctionner avec une commande Vgs = 3.3 V
Le AO3400 est certes en tout petit boîtier CMS SOT23, mais il est plus récent que l'IRL520 (en boîtier TO220) et a un Rdson 10 fois plus faible, ce qui autorise un courant supérieur.
Détails de simulation :
| MosFet |
I peltier |
Tension de déchet (Vds_sat) |
Puissance a dissiper en continu |
| AO3400 |
5,92 A |
0,14 V |
0,8 W |
| IRL520 |
5,34 A |
1,2 V |
6,4 W |
Conclusion 1 : ce n'est pas obligatoirement le plus gros boîtier qui est le plus performant.
Conclusion 2 : au début, ma méthode est moins simple qu'avec une interface graphique, mais seulement au début parce que l'interface graphique ne couvre qu'une partie des possibilités d'un logiciel quel qu'il soit.
Conclusion 3 : les fronts de courant sont-ils suffisamment "adoucis" ? Je ne connais pas ces Peltiers de puissance, je donne juste un moyen de déterminer les fronts.
