Multiple servos with buttons

[ester_k]

Hi, so, I am new with Arduino and I have problem with this code. I need the first servo to move when the first button is clicked. After clicking the second button, the second servo should move.
The first servo is moving. As it should. But the second servo does not respond to the button. There is probably a small error in the code, maybe I separated the sections wrong?
I am giving you a link to the simulation with the code. I hope someone will be able to help me. Probably only a small code modification is needed, but I don't know what exactly. Thanks for the anwers.
Here is link, just start a simulation and click at buttons. You can view the code in the link or below:

#include <Servo.h>

// constant variables used to set servo angles, in degrees
const int straight = 90; 
const int divergent = 110;

// constant variables holding the ids of the pins we are using
const int buttonpinA = 8;
const int servopinA = 9;
const int buttonpinB = 6;
const int servopinB = 7;

// servo movement step delay, in milliseconds
const int step_delay = 70;

// create a servo object
Servo myservoA;
Servo myservoB;
 
// global variables to store servo position
int pos = straight; // current
int old_pos = pos; // previous

void setup() 
{ 
  // set the mode for the digital pins in use
  pinMode(buttonpinA, INPUT);
  pinMode(buttonpinB, INPUT);
   
  // setup the servo
  myservoA.attach(servopinA);  // attach to the servo on pin 9
  myservoA.write(pos); // set the initial servo position
  myservoB.attach(servopinB);  // attach to the servo on pin 7
  myservoB.write(pos); // set the initial servo position
}

void loop() 
{ 
  int button_state = digitalRead(buttonpinA);
  if(button_state == HIGH){
    
    old_pos = pos;   
    
    pos = pos == straight ? divergent: straight;
       
    
    if(old_pos < pos){   
      
      for(int i = old_pos + 1; i <= pos; i++){  
        myservoA.write(i); 
        delay(step_delay); 
      }
    } else {  
      
      for(int i = old_pos - 1; i >= pos; i--){ 
        myservoA.write(i); 
        delay(step_delay); 
      }
    } 

   int button_state = digitalRead(buttonpinB);
   if(button_state == HIGH){
    
    old_pos = pos;   
    
    
    pos = pos == straight ? divergent: straight;
       
    
    if(old_pos < pos){   
      
      for(int i = old_pos + 1; i <= pos; i++){  
        myservoB.write(i); 
        delay(step_delay); 
      }
    } else {  
      
      for(int i = old_pos - 1; i >= pos; i--){ 
        myservoB.write(i); 
        delay(step_delay); 
      }
    }
    
  } 
}}// end of loop

[touch1337]

Try making different variable names for each section of the code rather than reusing them.
button_state changes to button_a_state and button_b_state, old_pos becomes old_pos_servo1 and old_pos_servo2, etc.

[StefanL38]

Hi Ester,

welcome to the forum.
Running your simulation requires registering at autodesk.
I will definitely not register at autodesk.
autodesk is a company that has a very aggressive marketing strategy to pour into every edge of schools and DIY-projects by offering "get used to our products for free"

There is another simulator that is opensource.
It is called wokwi

here is the WOKWI simulation of your code with a own set of variables for servo A and another set of variables for servo B

Though I guess this is still not that what you want.

I try to write down a precise description of what you probably want

As long as button A is pressed move servo A. If button A is released servo A shall stop at what ever position it is.

at the same time = in parallel
As long as button B is pressed move servo B. If button B is released servo B shall stop at what ever position it is.

This is medium advanced programming by using non-blocking timing

Non blocking timing means
there is only one big loop which is void loop() itself
There are zero function-calls to delay() and there are zero for-loops and zero while-loops
because all three

• delay()
• for-loops
• while-loops

are blocking.
Which means as long as the delay / for / while is executing nothing else can happen.

They way to go there is structured programming

build your own functions

as pseude-code

void moveServoA()
// all the code that makes the servo move back and forth slowly 
// but with non-blocking timing

void moveServoB()
// all the code that makes the servo move back and forth slowly 
// but with non-blocking timing


if (buttonA is pressed) {
  moveServoA()
}

if (buttonB is pressed) {
  moveServoB()
}

To understand non-blocking timing requires a prelimary exercise to understand it
the basic principle is to store snapshots of time and check how much time has passed by since storing the snapshot of time

Example-code for timing based on millis() easier to understand through the use of example-numbers / avoiding delay()

non-blocking timing. Execute code only from time to time. There are a lot of different ways to learn programming. This thread wants to add another approach that is different to the yet existing ones. UPDATE 06.01.2023 if you are mainly interested in applying non-blocking timing you can do a quick read of this short tutorial / demonstration If you are intersted in understanding the details how it works go on reading here. I use an everyday analogon in this post to explain the basic princip…

best regards Stefan

[ester_k]

Hi, thank you for telling me about Wokwi. As I said, I am pretty new in this community.
My explanation of the problem was poorly written. Sorry about that. Here is a more understandable version:
In Wokwi, I made a diagram for moving one servo using a button. When you press the button, the servo will move a little. When you press the button again, the servo will return to the previous position. When you run the simulation, the code does exactly what I need (here is link).
All I need is how to do the code if I need to have multiple servos with their own button powered by one Arduino.
For example: If I press button A, servo A will move. If I press button B, servo B will move regardless of what position servo A is in.
I want to use a breadboard for power and grounding (as on picture).

[gcjr]

@ester_k

But the second servo does not respond to the button.

the more properly formatted (indented) code shows that the 2nd button is read within the condition for the 1st button

void loop()
{
    int button_state = digitalRead(buttonpinA);
    if(button_state == HIGH){
        old_pos = pos;
        pos = pos == straight ? divergent: straight;
        if(old_pos < pos){
            for(int i = old_pos + 1; i <= pos; i++){
                myservoA.write(i);
                delay(step_delay);
            }
        } else {
            for(int i = old_pos - 1; i >= pos; i--){
                myservoA.write(i);
                delay(step_delay);
            }
        }
        int button_state = digitalRead(buttonpinB);
        if(button_state == HIGH){
            old_pos = pos;
            pos = pos == straight ? divergent: straight;
            if(old_pos < pos){
                for(int i = old_pos + 1; i <= pos; i++){
                    myservoB.write(i);
                    delay(step_delay);
                }
            } else {
                for(int i = old_pos - 1; i >= pos; i--){
                    myservoB.write(i);
                    delay(step_delay);
                }
            }
        }
    }
}// end of loop

[StefanL38]

For the independant operation of both servos the whole code must follow the non-blocking paradigma.

Non-blocking means:
the most outer loop which is

void loop() {
//top of loop
// any kind of code (can be THOUSANDs of lines of code)
// bottom of loop
}

must run down completely at high speed from
//top of loop
down to
// bottom of loop

to make sure that this is running down fast
all lines of code inbetween must be finished fast

This can be achieved by a coding-structure that makes sure to
quickly jump into a sub-function and quickly jump out again

void loop() {
  myFunctionOne(); // quickly jump in / quickly jump out 
  myFunctionTwo(); // quickly jump in / quickly jump out 
  //....
  myFunction10(); // quickly jump in quickly jump out 
}

Not all code shall be executed at all times.
This means code-execution is made conditional

void myFunctionOne() {
  if (ExecutionConditionONE == true) {
    // execute code
  }
  else {
    //doNothing
  }
  
}


void myFunctionTwo() {
  if (ExecutionConditionTwo == true) {
    // execute code
  }
  else {
    //doNothing
  }
  
}

for-loops and while-loops must be avoided completely

counting variables up/down is done bye each new call of the sub-functions

void myFunctionOne() {
  if (ExecutionConditionONE == true) {
    posA = posA + 1; 
  }
  else {
    //doNothing
  }
  
}

remember: loop() is looping at high speed all the time
This means the sub-function is called over an over again through void loop()
instead of a for-loop

Now changing the servo-position slowly requires non-blocking timing
which is explained here

Example-code for timing based on millis() easier to understand through the use of example-numbers / avoiding delay()

non-blocking timing. Execute code only from time to time. There are a lot of different ways to learn programming. This thread wants to add another approach that is different to the yet existing ones. UPDATE 06.01.2023 if you are mainly interested in applying non-blocking timing you can do a quick read of this short tutorial / demonstration If you are intersted in understanding the details how it works go on reading here. I use an everyday analogon in this post to explain the basic princip…

[ester_k]

When I added your code (I hope I have permission?) I got this error message. I don't know Arduino well, so I don't know exactly what that means. I am giving a link to the simulation here.

[ester_k]

Thanks, I will try to read everything and get better at programming.

[gcjr]

@ester_k

When I added your code

i simply posted a portion of your code properly formatted so that you could see that the 2nd button code was inside the condition for the first.

i had hoped you would see that this explains your problem and would know how to correct it by moving it out from inside the 1st button condition. do you need help?

[StefanL38]

Your WOKWI-simualtion has ver ynicely placed components

The error in the wowki-simulation is caused by the missing
void setup()-function.

Take a look into this tutorial:

at least at the first 6 chapters.

Arduino Programming Course

It is easy to understand and has a good mixture between explaining important concepts and example-codes to get you going. So give it a try and report your opinion about this tutorial.

best regards Stefan

[ester_k]

All right, there is my last try. I didn't understand the code too much. So, now I will read tutorials and try to understand programming better. If someone could show me how to make my code look correct, that would be very helpful. However, thank you for your time and have a nice day.

[gcjr]

consider

# include <Servo.h>

const int ButtonpinA = 8;
const int ButtonpinB = 6;

const int servopinA = 9;
const int servopinB = 7;

// constant variables used to set servo angles, in degrees
const int Straight = 90;
const int Divergent = 110;

// servo movement step delay, in milliseconds
const int step_delay = 70;

// create a servo object
Servo myservoA;
Servo myservoB;

#define Nservo 2

int pos    [Nservo] = { Straight, Straight };
int posOld [Nservo] = { Straight, Straight };

byte ButPins [] = { ButtonpinA, ButtonpinB };
byte butState [sizeof (ButPins)];

// -----------------------------------------------------------------------------
void setup ()
{
    Serial.begin (9600);

    for (unsigned b = 0; b < sizeof(ButPins); b++)  {
        pinMode (ButPins [b], INPUT_PULLUP);
        butState [b] = digitalRead (ButPins [b]);
    }

    // setup the servo
    myservoA.attach (servopinA);  // attach to the servo on pin 9
    myservoA.write (pos [0]); // set the initial servo position

    myservoB.attach (servopinB);  // attach to the servo on pin 7
    myservoB.write (pos [1]); // set the initial servo position
}

// -----------------------------------------------------------------------------
void loop ()
{
    int  dir;
    for (unsigned b = 0; b < sizeof(ButPins); b++)  {
        byte but = digitalRead (ButPins [b]);
        if (butState [b] != but)  {
            butState [b] = but;

            if (LOW == but)  {
                pos [b]    = Straight == pos [b] ? Divergent : Straight;
                dir        = (pos [b] - posOld [b]) > 0 ? 1 : -1;

                for (int i = posOld [b]; i != pos [b]; i += dir)  {
                    if (0 == b)
                        myservoA.write (i);
                    else
                        myservoB.write (i);
                    delay (step_delay);
                }
                posOld [b] = pos [b];
            }
        }
    }
}

[StefanL38]

@gcjr
have you ever considered for a few seconds that a code with that stage of sophistication is already wayyy above the head of a real beginner?

have you ever considered that presenting a to heavy to understand code can be frustrating?

have you ever considered that with this really poor and short comments this code

IS

hard to understand for a real beginner??!!

Is your main aim to chase away all young people that are interested in learning coding
except the real nerdy ones that love most to read the hardest to understand code?

If you aren't aware of that you are that forum-member that has the biggest

experts blindness for beginner difficulties

that I have yet encountered

[gcjr]

what do you think is so difficult?

[StefanL38]

using arrays without explaining them
using the "?"-operator without explaining it

the compactness of code like this line

for (unsigned b = 0; b < sizeof(ButPins); b++)

or this part

if (LOW == but)  {
                pos [b]    = Straight == pos [b] ? Divergent : Straight;
                dir        = (pos [b] - posOld [b]) > 0 ? 1 : -1;

                for (int i = posOld [b]; i != pos [b]; i += dir)  {
                    if (0 == b)
                        myservoA.write (i);
                    else
                        myservoB.write (i);

@ester_k

your last attempt to make it work is missing the void setup-function
and has two functions void loop()

each and every Arduino-Sketch requires to have
exact one function

void setup() {
}

and exact one function

void loop() {
}

You made a good decision to learn more about the basics.

I modifyed your WOKWI-code so that it is working now.
It works in a blocking manner
as long as the code is executing a for-loop the code outside this for-loop is not eecuted
of course because you are in a for-loop which runs down from start to finish

sketch.ino copy - Wokwi Arduino and ESP32 Simulator

best regards Stefan

[b707]

@StefanL38

using arrays without explaining them
using the "?"-operator without explaining it

Both are not really difficult and are easy to find in any textbook.

@StefanL38

or this part

if (LOW == but)  {
                pos [b]    = Straight == pos [b] ? Divergent : Straight;
                dir        = (pos [b] - posOld [b]) > 0 ? 1 : -1;

                for (int i = posOld [b]; i != pos [b]; i += dir)  {
                    if (0 == b)
                        myservoA.write (i);
                    else
                        myservoB.write (i);

and this part is almost entirely taken from the own OP code!
Do not underestimate beginners, I think OP will understand this as well as you

And in general, you should not make the task too easy for beginners, otherwise they will generally forget how to think

[ester_k]

Alright guys, I have to thank you for your help. You helped me a lot, especially @StefanL38. I promise to read all the tutorials and try to get better at programming. I still have a lot to learn, but I believe I will make progress. And also thanks for making the code workable, now I can look for my mistakes.
Have a great day and thank you again.