NRF24L01+ Communications errors

Thesadclown · June 1, 2018, 6:05pm

High, I have a very basic knowledge of code, and I am trying to transfer the press of a button press from an Arduino Uno to an Arduino Mega.

When I have only one button set up the code works perfectly, but as soon as I add a second button into the mix the code outputs randomly the first or second button.

Here is the transmitter code

//transmitter

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
#define btn1 3 //btn1
#define btn2 5 //btn2
RF24 radio(7, 8 ); // CE, CSN
const byte addresses[][6] = {"00002"};
boolean btn1State = 0;
boolean btn2State = 0;
void setup() {
pinMode(btn1, INPUT);
pinMode(btn2, INPUT);
radio.begin();
radio.openWritingPipe(addresses[0]); // 00002
radio.setPALevel(RF24_PA_MIN);
radio.stopListening();

}
void loop() {
btn1State = digitalRead(btn1);
radio.write(&btn1State, sizeof(btn1State));
btn2State = digitalRead(btn2);
radio.write(&btn2State, sizeof(btn2State));
}

Here is the receiver code

//reciever

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
RF24 radio(7, 8 ); // CE, CSN
const byte addresses[][6] = {"00002"};
boolean btn1State = 0;
boolean btn2State = 0;
void setup() {
Serial.begin(9600);
radio.begin();
radio.openReadingPipe(1, addresses[0]); // 00002
radio.setPALevel(RF24_PA_MIN);
radio.startListening();

}
void loop() {
while (!radio.available());
radio.read(&btn1State, sizeof(btn1State));
if (btn1State == HIGH) {
Serial.println("btn1");
}
else {}
radio.read(&btn2State, sizeof(btn2State));
if (btn1State == HIGH) {
Serial.println("btn2");
}
else {}
}

Any help to change the code to make each button output its desired value would be greatly appreciated

knut_ny · June 1, 2018, 6:15pm

The code may be OK.
Those radios fancy a very stable 3.3V to work properly.
They are more reliable with a capacitor soldered onto the modules power pins. 10uF is mentioned in many posts. I had luck with this 'fix'

UKHeliBob · June 1, 2018, 6:31pm

One obvious mistake

radio.read(&btn2State, sizeof(btn2State));
  if (btn1State == HIGH) {           //which button ?
    Serial.println("btn2");
  }

alto777 · June 1, 2018, 8:09pm

All you are sending is the state of the buttons, one after the other after the other after the other after the other, you get the idea.

There is nothing that says which is which. You need a bigger packet - the transmissions do not catch a clue from your variable names.

Looks like now if both buttons are high, you get both listed. If both are low you get nothing. (You could put something in your emprty "else" clauses whilst testing).

If one button is down and the other up, you get continuous message about one of them, a missed packet will start telling you the other one is the one that's pressed.

Add an identifier to the packet. Check it to see which button's state is in the other part of your message. Send a little array of chars, not just one (anonymous!) byte.

a7

Whandall · June 1, 2018, 8:23pm

Or just send one packet consisting of both button states whenever at least one of them changes.

TX

#include <RF24.h>

struct Pack {
  boolean btn1State;
  boolean btn2State;
} packet;

const byte btn1 = 3;
const byte btn2 = 5;
const byte address[6] = {"20000"};

RF24 radio(7, 8 );

void setup() {
  pinMode(btn1, INPUT_PULLUP);
  pinMode(btn2, INPUT_PULLUP);
  radio.begin();
  radio.openWritingPipe(address);
  radio.setPALevel(RF24_PA_MIN);
  radio.enableDynamicPayloads();
}

void loop() {
  boolean sendPacket = false;
  boolean btn1State = digitalRead(btn1);
  boolean btn2State = digitalRead(btn2);
  if (btn1State != packet.btn1State) {
    packet.btn1State = btn1State;
    sendPacket = true;
  }
  if (btn2State != packet.btn2State) {
    packet.btn2State = btn2State;
    sendPacket = true;
  }
  if (sendPacket) {
    radio.write(&packet, sizeof(packet));
  }
}

RX

#include <RF24.h>

struct Pack {
  boolean btn1State;
  boolean btn2State;
} packet;

RF24 radio(7, 8 );

const byte address[] = {"20000"};

void setup() {
  Serial.begin(9600);
  radio.begin();
  radio.openReadingPipe(1, address);
  radio.enableDynamicPayloads();
  radio.setPALevel(RF24_PA_MIN);
  radio.startListening();
}

void loop() {
  if (radio.available()) {
    radio.read(&packet, sizeof(packet));
    Serial.print(F("btn1 is O"));
    Serial.print(packet.btn1State ? F("FF") : F("N"));
    Serial.print(F(", btn2 is O"));
    Serial.println(packet.btn2State ? F("FF") : F("N"));
  }
}

alto777 · June 1, 2018, 11:59pm

Whandall:
Or just send one packet consisting of both button states whenever at least one of them changes.

Yes. In some circumstances you might want to send such a message occasionally even if there is no button change.

a7

Whandall · June 2, 2018, 1:52am

alto777:
In some circumstances you might want to send such a message occasionally even if there is no button change.

You could force at least one packet a second like this:

#include <RF24.h>

struct Pack {
  boolean btn1State;
  boolean btn2State;
} packet = { true, true };

const byte btn1 = 3;
const byte btn2 = 5;
const byte address[6] = {"20000"};

unsigned long lastSend;

RF24 radio(7, 8 );

void setup() {
  pinMode(btn1, INPUT_PULLUP);
  pinMode(btn2, INPUT_PULLUP);
  radio.begin();
  radio.openWritingPipe(address);
  radio.setPALevel(RF24_PA_MIN);
  radio.enableDynamicPayloads();
}

void loop() {
  unsigned long topLoop = millis();
  boolean sendPacket = false;
  boolean btn1State = digitalRead(btn1);
  boolean btn2State = digitalRead(btn2);
  if (btn1State != packet.btn1State) {
    packet.btn1State = btn1State;
    sendPacket = true;
  }
  if (btn2State != packet.btn2State) {
    packet.btn2State = btn2State;
    sendPacket = true;
  }
  if (!sendPacket && topLoop - lastSend >= 1000) {
    sendPacket = true;
  }
  if (sendPacket) {
    radio.write(&packet, sizeof(packet));
    lastSend = topLoop;
  }
}

Robin2 · June 2, 2018, 6:42am

Have a look at this Simple nRF24L01+ Tutorial.

If this was my project I would always send all the data in a single message and send messages at regular intervals (perhaps 5 per second) even if the data does not change. That way if the messages fail to arrive the receiving device can know that there is a communication failure.

...R

Thesadclown · June 2, 2018, 8:55pm

Add an identifier to the packet. Check it to see which button's state is in the other part of your message. Send a little array of chars, not just one (anonymous!) byte.

a7

[/quote]

How would I do that?

Thanks for all the help

Robin2 · June 2, 2018, 9:03pm

Thesadclown:
How would I do that?

Have you studied the examples in my tutorial and tried them?

...R

Thesadclown · June 2, 2018, 9:33pm

Robin2:
Have you studied the examples in my tutorial and tried them?

...R

I have read through your examples, but am confused.

Thesadclown · June 2, 2018, 9:41pm

Robin2:
Have you studied the examples in my tutorial and tried them?

...R

I have read through your examples, but am confused.
In my situation, I want a series of buttons to transmit from the RX and influence a series of IF statements on the TX. In your code I can see that it will Serial print a message, but I am unsure as to where I would place the IF statements for the two buttons and where I would place the IF statements to make the RX do the desired effect.

Sorry about the previous post, I posted before I meant to

Thesadclown · June 2, 2018, 10:04pm

Whandall:
You could force at least one packet a second like this:
#include <RF24.h>

struct Pack {
boolean btn1State;
boolean btn2State;
} packet = { true, true };

const byte btn1 = 3;
const byte btn2 = 5;
const byte address[6] = {"20000"};

unsigned long lastSend;

RF24 radio(7, 8 );

void setup() {
pinMode(btn1, INPUT_PULLUP);
pinMode(btn2, INPUT_PULLUP);
radio.begin();
radio.openWritingPipe(address);
radio.setPALevel(RF24_PA_MIN);
radio.enableDynamicPayloads();
}

void loop() {
unsigned long topLoop = millis();
boolean sendPacket = false;
boolean btn1State = digitalRead(btn1);
boolean btn2State = digitalRead(btn2);
if (btn1State != packet.btn1State) {
packet.btn1State = btn1State;
sendPacket = true;
}
if (btn2State != packet.btn2State) {
packet.btn2State = btn2State;
sendPacket = true;
}
if (!sendPacket && topLoop - lastSend >= 1000) {
sendPacket = true;
}
if (sendPacket) {
radio.write(&packet, sizeof(packet));
lastSend = topLoop;
}
}

I have been messing around with this and it has gotten me the farthest so far
Do you have any Ideas on how I could transfer the serial print so that me pressing a btn1 would light one LED and pressing btn2 would light a second LED?

Thanks a ton for all the help

Whandall · June 2, 2018, 10:10pm

LED Rx

#include <RF24.h>

struct Pack {
  boolean btn1State;
  boolean btn2State;
} packet;

RF24 radio(7, 8 );

const byte address[] = {"20000"};
const byte led1Pin = 4;
const byte led2Pin = 5;

void setup() {
  pinMode(led1Pin, OUTPUT);
  pinMode(led2Pin, OUTPUT);
  Serial.begin(9600);
  radio.begin();
  radio.openReadingPipe(1, address);
  radio.enableDynamicPayloads();
  radio.setPALevel(RF24_PA_MIN);
  radio.startListening();
}

void loop() {
  if (radio.available()) {
    radio.read(&packet, sizeof(packet));
    digitalWrite(led1Pin, !packet.btn1State);
    digitalWrite(led2Pin, !packet.btn2State);
  }
}

Thesadclown · June 3, 2018, 12:19am

I want to thank all of you so much, I spent 4 weeks trying to teach myself how to do this, and you helped me make a working code in 2 days.

Thanks again for all the help

TomGeorge · June 3, 2018, 12:59am

Hi,
How have you got your buttons wired to the controller.

If when you press the button, the controller input gets pulled HIGH, have you got a 10k resistor between the controller input and ground to pull the input LOW when the button is open circuit?

Thanks.. Tom..

Thesadclown · June 3, 2018, 1:10am

Basically there is 5 volts to one side of the switch while the other has a wire running to the arduino and on that side of the switch there is also a 10k pull down resistor to keep the arduino reading nothing when the button is not pressed

Attached is a drawing of the button schematic

Topic		Replies	Views
nrf24l01 wireless help.. Programming	4	1216	May 5, 2021
nrf24l01+ - I can't make it work with 2 buttons and 2 LEDs Programming	25	2426	May 6, 2021
(NRF24L01) 2 button state issue Programming	4	1122	May 6, 2021
2 button signals using nRF24L01 General Guidance	2	1766	May 5, 2021
nRF24 help please Networking, Protocols, and Devices	22	871	September 26, 2021

NRF24L01+ Communications errors

Related topics