Radio TEA5767 Sketch gesucht

Ich suche jemanden der mir einen .ino Sketch fehlerfrei nach .hex kompelieren kann. Ich selber bekomme das nicht auf die Kette. Bezahle gerne etwas dafür. Bitte helft ;-) Tomec123@gmx.de

Wenn der Sketch fehlerfrei ist, macht das der Kompiler allein.

Zeig doch mal, was du hast.

Ich kanns leider nicht hier hochladen, da ich neu hier im Forum bin...

Doch.
Click oben auf das symbol <code> dann kannst Du den text "hier code einfügen" mit Deinem Code erweitern, in dem Du den da einfach rein kopierst.

Bitte beachte das der Code zwischen dem Anfang und Ende der codetags steht.

#include <Wire.h>
#include <TEA5767.h>
#include <LiquidCrystal.h>


LiquidCrystal lcd( 8,  9,  4,  5,  6,  7);
TEA5767 radio = TEA5767();    // Cria o objeto radio


int stb = 200;                // Tempo para estabilizar a sintonia            
int minWait = 100;            // Menor tempo de espera em uma estacao (ms)
int maxWait = 1000;           // Maior tempo de espera em uma estacao (ms)
int wait = minWait;           // Tempo parado em uma estacao
int dw = 100;                 // Taxa de variacao para o tempo de espera em uma estacao (ms)
bool muted = true;            // mute/unmute
short sLevel;                 // Nivel atual do sinal
short minLevel = 6;           // Minimo nivel do sinal aceitavel
float minFreq = 87.1;         // Menor frequencia sintonizavel
float maxFreq = 108.9;        // Maior frequencia sintonizavel
float frequency = minFreq;    // Frequencia atualmente sintonizada
String s;                     // Frequencia da estacao na forma de string
bool stopped = true;          // inicia / para varredura
bool forward = true;          // Varre estacoes para frente
bool backward = false;        // Varre estacoes para tras
float stations[50];           // Vetor de frequencias de estacoes (ate 50 estacoes)
int n_stations;               // Numero de estacoes sintonizadas
int count = 0;                // Variavel contadora


// Esta funcao apresenta o criador do programa
void splashScreen()
{
  lcd.clear();                        
  lcd.setCursor(0,0);
  lcd.print("Spiritmaster");
  lcd.setCursor(0,1);
  lcd.print("by Masterdetektor");
  delay(3000);
}


// Esta função faz o scan inicial das estacoes de radio disponiveis
void scanStations()
{
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Scanning");
  lcd.setCursor(0,1);
  lcd.print("Stations...");
  radio.setMuted(true);               // Muta o radio
  count = 0;                          // Zera o contador de estacoes
  lcd.setCursor(15,1);                // Posiciona o contador de estacoes na tela
  lcd.print(count);                   // Mostra o contador de estacoes sintonizadas
  frequency = minFreq;                // inicia a varredura pela frequencia mais baixa
  while (frequency <= maxFreq)        // Enquanto nao escanear ate a frequencia mais alta
  {
    radio.setFrequency(frequency);    // Ajusta o raidio na primeira frequencia
    delay(stb);                       // Aguarda a estabilizacao da sintonia
    sLevel = radio.getSignalLevel();  // Captura a intensidade do sinal na frequencia atual
    if (sLevel >= minLevel)           // Se o nivel do sinal for aceitavel
    {
      stations[count] = frequency;    // Armazena a frequencia da estacao atual
      count += 1;                     // Increase station counter
      if (count < 10)                 // Enquanto nao atingir 10 estacoes
      {
        lcd.setCursor(15,1);          // Posiciona o cursor na ultima posicao da segunda linha
      }
      else                            // Caso contrario
      {
        lcd.setCursor(14,1);          // Posiciona o cursor na penultima posicao da segunda linha
      }
      lcd.print(count);               // Mostra o contador na tela
    }
    frequency += 0.2;                 // Passa para a proxima frequencia a ser sondada
  }
  n_stations = count;                 // Anota o numero de estacoes encontradas na variavel "n_stations"
  delay(1000);
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Scaning");
  lcd.setCursor(0,1);
  lcd.print("Completed!");
  delay(2000);
  lcd.clear();
  count = 0;                            // Zera o contador de estacoes
  radio.setFrequency(stations[count]);  // Aponta para a primeira estacao sintonizada
  displayData();                        // Mostra os dados da GhostBox
}


// Esta funcao mostra informacoes sobre a estacao sintonizada
void displayData()
{
  s = String(stations[count]);     // Get station frequency
  lcd.setCursor(0,0);              // Ajusta a posicao do display para mostrar a frequencia
  if (stations[count] < 100)       // Se a frequencia da estacao for menor do que 100 MHz
  {
    lcd.print(" ");                // Ajusta a posicao para
    lcd.setCursor(1,0);            // mostrar a frequencia da estacao
  }
  lcd.print(s);                    // Mostra a frquencia da estacao
  lcd.setCursor(6,0);
  lcd.print("MHz");
  lcd.setCursor(12,0);             // Ajusta a posicao do display para muted / unmuted
  if (muted == true)               // Se estiver no modo "mudo"
  {
    lcd.print("Mute");   // Mostra "Mute"
  }
  else                   // Se nao estiver no modo mudo
  {
    lcd.print("    ");   // Mostra "    "
  }
  lcd.setCursor(0,1);
  if (wait < 1000)       // Ajusta a posicao do display para tempo de espera < 1000ms
  {
    lcd.print(" ");
    lcd.setCursor(1,1);
  }
  lcd.print(wait);       // Mostra o tempo de espera
  lcd.setCursor(4,1);    // Ajusta a posicao do display para mostrar a unidade de tempo (ms)
  lcd.print("ms");       // Mostra "ms"
  lcd.setCursor(7,1);    // Ajusta a posicao do display para "Stop" / "Scan"
  if (stopped == true)
  {
    lcd.print("Stop");
  }
  else
  {
    lcd.print("Scan");
  }
  lcd.setCursor(13,1);  // Ajusta a posicao do display para a direcao da varredura "-->" / "<--"
  if (forward == true)
  {
    lcd.print("-->");
  }
  else
  {
    lcd.print("<--");
  }
}


// Faz a varredura da proxima estacao para frente
void goNextRadio()
{
  if (count < n_stations-2)
  {
    count += 1;
  }
  else
  {
    count = 0;
  }
  radio.setFrequency(stations[count]);   // Sintoniza a estacao
  delay(stb);                            // Aguarda estabilizar a sintonia
}


// Faz a varredura da proxima estacao para tras
void goPreviousRadio()
{
  if (count > 0)
  {
    count -= 1;
  }
  else
  {
    count = n_stations - 1;
  }
  radio.setFrequency(stations[count]);   // Sintoniza a estacao
  delay(stb);                            // Aguarda estabilizar a sintonia
}


void setup() {
  delay(1000);
  Wire.begin();
  lcd.begin(16,2);
  splashScreen();    // Mostra a tela de Splash
  scanStations();    // Busca as estacoes disponiveis 
}


int x;
void loop() {
  x = analogRead(0);
  if (stopped == true)
  {
    //---------------------------------------//
    if (x < 60) {
      // "Right" button
      // Varre as estacoes para frente
      backward = false;
      forward = true;
      delay(stb);
    }

    //---------------------------------------//
    if (x >= 60 and x < 200) {
      // "Up" button
      // Aumenta o tempo de espera em uma estacao
      if ((wait + dw) <= maxWait)
      {
        wait += dw;
      }
      delay(stb);
    }

    //---------------------------------------//
    if (x >= 200 and x < 400){
      // "Down" button
      // Diminui o tempo de espera em uma estacao
      if ((wait - dw) >= minWait)
      {
        wait -= dw;
      }
      delay(stb);
    }

    //---------------------------------------//
    if (x >= 400 and x < 600){
      // "Left" button
      // Varre as estacoes para tras
      forward = false;
      backward = true;
      delay(stb);
    }
  }

  else
  {
    if (forward == true)
    {
      goNextRadio();      // Busca uma estacao para frente
    }
    if (backward == true)
    {
      goPreviousRadio();   // Busca uma estacao para tras
    }
    displayData();   // Mostra as informacoes do aparelho
    delay(wait);     // Aguarda um tempo na estacao sintonizada
  }

  //---------------------------------------//
  if (x >= 600 and x < 800){
    // "Select" Button
    // Este botao inicia / interrompe uma varredura
    if (stopped == false) // Se estiver fazendo uma varredura
    {
      muted = true;    // Mute
      stopped = true;  // Interrompe a varredura 
    }
    else               // Se nao estiver fazendo uma varredura
    {
      muted = false;   // Unmute
      stopped = false; // Inicia a varredura
    }
    radio.setMuted(muted); // Mute/Unmute o radio
    delay(stb);
  }

  displayData();   // Mostra as informacoes do aparelho
}

Und, warum kannst du es nicht übersetzen lassen?
Welche Fehlermeldungen?
Für welchen Arduino?
Hast du die richtige TEA5767 library?

Sketch uses 9992 bytes (30%) of program storage space. Maximum is 32256 bytes.
Global variables use 698 bytes (34%) of dynamic memory, leaving 1350 bytes for local variables. Maximum is 2048 bytes.

Für Uno R3 kompiliert unter Nutzung dieser Library.

sketch_feb12a.ino.hex (27,5 KB)

Edith sagt:
Ach so, vielleicht sollte ich noch kurz erzählen wie ich das hinbekommen habe:
Irgendeine TEA5767-Lib in der IDE installiert, kompiliert, Fehler gefunden: Methode getSignalLevel() fehlt. Suche in der bevorzugten Suchmaschine nach "Arduino TEA5767 getSignalLevel`. Beim ersten Treffer das Header-File angeschaut, die Methode ist vorhanden, installiert, kompiliert - fertig.

Ich bin heute nicht so schnell :slight_smile:

WoW, Ihr seit wirklich Cracks...das bekomme ich so nicht hin. Ich bin eher der Hardware Typ...mit Software bin ich leicht überfordert da zu alt ;-)
Hardware Arduino Uno R3, Fehlermeldungen...viel zu viele um das zu checken...mag sein das es auch daran liegt das ich Linux nutze...

Diese meine persönliche Meinung wirst Du jetzt vielleicht nicht gern hören:

Weder das Alter noch die Nutzung von Linux sind Hindernisse, die ein gewisses Grundverständnis von Software unmöglich machen. Das Arduino-Universum bietet dafür recht gute Voraussetzungen - wenn man denn will.
/Meinung Ende

Aber jeder setzt für sich selbst die Prioritäten und das akzeptiere ich selbstverständlich.

Herzlichen Dank, hab es installiert und es scheint zu laufen. Kann es aber erst Morgen testen wenn das TAE5767 Modul da ist...bin sehr gespannt. 1000 Dank für die Hilfe

Du hast recht, aber leider fehlt mir tatsächlich ein wenig die Zeit um dazu zu lernen...in 5-6 Jahren vielleicht, dann bin ich in Rente ;-).
Vielen Dank

Junger Tupfer. :wink: :wink:
Wenn Du 5 Jahre bis zur Rente hast, dann bist Du in meinem Alter. Es sei Du hast kein Abitur; dann bist Du jünger.

Hier tummeln sich ziemlich einige Erfahrenere (nach Jahren) User herum.

Grüße Uwe

Jahrgang 63, kein Abitur, dafür mit 16 direkt in die Lehre... ;-)

Junger Hupfer :rofl: :joy:. Als Du noch in der Grundschule (damals 'Volksschule') warst, habe ich schon Programme in Algol und Fortran geschrieben. Ok, der eine kommt früher zum programmieren, der andere später und die meisten gar nicht. Aber das Alter ist definitiv kein Kriterium :smiling_face_with_sunglasses:.

Vielen Dank Euch hier im Forum. Hat geklappt und ich habe es nun auch geschafft die .Ino selber zu kompellieren. Wieder ein klein wenig was gelernt. Nun habe ich noch eine kleine Frage zum Programmtext...der Entwickler hat da einen großen Denkfehler drin...er läßt das TAE Modul zunächst alle verfügbaren Sender Scannen und speichern. Diese gespeicherten Sender werden anschließend immer wiederholt (in einstellbaren Zeiträumen). Das wiederspricht aber der eigentlichen Funktion einer Spiritbox die ja alle verfügbaren Frequenzen (innerhalb der FM Grenzen) abtastet. Wie könnte man das realisieren?

Programmablauf zeichnen oder ein Statediagramm zeichnen aus dem hervorgeht wann was geschehen soll. Wenn klar ist wie etwas ablaufen soll, kann man an die Programmierung denken.

Das passiert einmalig im Setup().

scanStations();

in den Loop() holen und dort an der richtigen Stelle unterbringen.

Was genau da passiert hängt ab von einem Wert, der analog eingelesen wird:

void loop() {
  x = analogRead(0);
...

Wenn Du mitteilst, was Du eigentlich vorhast (Radio, Radiosender-Scanner ...) und wie aktuell Deine Schaltung aussieht lässt sich evtl. mehr sagen.

Die Library bringt mit "StationFinder" und "StationFinder-NewVersion" auch noch zwei Beispiele mit, die statt über LCD den seriellen Monitor nutzen und darüber auch steuerbar sind.

Die Schaltung ist ein Uno R3, ein Keypad Shield und ein TAE5767 Modul. Das Programm soll schlicht und einfach alle Frequenzen im Loop abtasten (vorwärts oder rückwärts) und für eine kurze Zeit (100-1000ms) "reinhören". Das ist es schon. Also "random" so wie man heut so schön sagt ;-)