Control a lamp using a PIR sensor

I have been working on a code, where I can control my lamp to turn on and off when detect motion. I like it to turn on when it detect motion and when it no longer detect motion it stills is turn on for 5 min before it turns off.
My issue is that the code working fin to detect the motion and also to turn it off after the given time but the lamp is flashing and I cant find the problem. Have tried some difference type of set up (if else, while and switch case) But all end up whit the same problem, the to run the loop it turn the lamp off for a blink of a second which I like to avoid.

//VARS
//the time we give the sensor to calibrate (10-60 secs according to the datasheet)
int calibrationTime = 30;        

//the time when the sensor outputs a low impulse
long unsigned int lowIn;         

//the amount of milliseconds the sensor has to be low 
//before we assume all motion has stopped
long unsigned int pause = 15000;  

boolean lockLow = true;
boolean takeLowTime;  

int pirPin = 3;    //the digital pin connected to the PIR sensor's output
int ledPin = 13;
int ssrPin=12;
int ledredPin=11;

/////////////////////////////
//SETUP
void setup(){
  Serial.begin(9600);
  pinMode(pirPin, INPUT);
  pinMode(ledPin, OUTPUT);
  digitalWrite(pirPin, LOW);
  pinMode(ssrPin,OUTPUT);
  pinMode(ledredPin,OUTPUT);
  digitalWrite(ssrPin,LOW);
  digitalWrite(ledredPin,HIGH);

  //give the sensor some time to calibrate
  Serial.print("calibrating sensor ");
    for(int i = 0; i < calibrationTime; i++){
      Serial.print(".");
      delay(1000);
      }
    Serial.println(" done");
    Serial.println("SENSOR ACTIVE");
    delay(50);
  }

////////////////////////////
//LOOP
void loop(){

     if(digitalRead(pirPin) == HIGH){
       digitalWrite(ledPin, HIGH);   //the led visualizes the sensors output pin state
       digitalWrite(ledredPin,LOW);
       digitalWrite(ssrPin,HIGH);
       
       if(lockLow){  
         //makes sure we wait for a transition to LOW before any further output is made:
         lockLow = false;            
         Serial.println("---");
         Serial.print("motion detected at ");
         Serial.print(millis()/1000);
         Serial.println(" sec"); 
         delay(50);
         }         
         takeLowTime = true;
       }

     if(digitalRead(pirPin) == LOW){   
      
       digitalWrite(ledPin, LOW);  //the led visualizes the sensors output pin state
       digitalWrite(ledredPin,HIGH);
       digitalWrite(ssrPin,LOW);

       if(takeLowTime){
        lowIn = millis();          //save the time of the transition from high to LOW
        takeLowTime = false;       //make sure this is only done at the start of a LOW phase
        }
       //if the sensor is low for more than the given pause, 
       //we assume that no more motion is going to happen
       if(!lockLow && millis() - lowIn > pause){  
           //makes sure this block of code is only executed again after 
           //a new motion sequence has been detected
           lockLow = true;                        
           Serial.print("motion ended at ");      //output
           Serial.print((millis() - pause)/1000);
           Serial.println(" sec");
           delay(50);
           }
       }
  }

Untestec, but try

if(!lockLow && (millis() - lowIn > pause)){

The Original would be evaluated as

if((!lockLow && millis()) - lowIn > pause){

Which does not make much sense

Thank for the reply =) Sorry it doesn’t seems to make much difference it still is turning on and off when there is constant motion.

I think this version will do what you want:

//VARS
//the time we give the sensor to calibrate (10-60 secs according to the datasheet)
const int calibrationTime = 30;        

//the time when the sensor outputs a low impulse
unsigned long LastTimePIRHigh;         

//the amount of milliseconds the sensor has to be low 
//before we assume all motion has stopped
const unsigned long pause = 15000; 

const int pirPin = 3;    //the digital pin connected to the PIR sensor's output
const int ssrPin = 12;
const int ledPin = 13;
const int ledredPin = 11;

/////////////////////////////
//SETUP
void setup(){
  Serial.begin(9600);
  pinMode(pirPin, INPUT);
  digitalWrite(pirPin, LOW);

  pinMode(ledPin, OUTPUT);
  pinMode(ssrPin,OUTPUT);
  pinMode(ledredPin,OUTPUT);
  digitalWrite(ssrPin,LOW);
  digitalWrite(ledredPin,HIGH);

  //give the sensor some time to calibrate
  Serial.print("calibrating sensor ");
  for(int i = 0; i < calibrationTime; i++){
    Serial.print(".");
    delay(1000);
  }
  Serial.println(" done");
  Serial.println("SENSOR ACTIVE");
}

////////////////////////////
//LOOP
void loop() {
  if(digitalRead(pirPin) == HIGH) {
    LastTimePIRHigh = millis();
    digitalWrite(ledPin, HIGH);   //the led visualizes the sensors output pin state
    digitalWrite(ledredPin,LOW);
    if (digitalRead(ssrPin) == LOW) {
      // First time HIGH
      digitalWrite(ssrPin,HIGH);  // Turn on lamp
      Serial.print("Light turned on at ");
      Serial.print(LastTimePIRHigh/1000);
      Serial.println(" seconds.");
    }

  } 
  else { // PIR pin is LOW
    digitalWrite(ledPin, LOW);  //the led visualizes the sensors output pin state
    digitalWrite(ledredPin,HIGH);
    if ((digitalRead(ssrPin) == HIGH) && (millis() - LastTimePIRHigh >= pause)) {
      Serial.print("Motion stopped at ");
      Serial.print(LastTimePIRHigh/1000);
      Serial.println(" seconds.");
      digitalWrite(ssrPin,LOW);
    }
  }
}

Damn I love this forum, always some genius out there to help us newcomers. It seems to work, thank a lot =)