nix_mehr_frei:
Hrr, keine Besserung! Habe noch einen 47µ Elko über den Spannungsteiler zwischen Masse und +5V drübergenagelt.
Dein DCF-Signal schwabbelt, nicht unbedingt die Stromversorgung des Moduls.
Aufgrund der extrem kurzen Störimpulse im Takt der Netzspannung würde ich mal in Richtung mangelhaft funkentstörter Phasenanschnittsteuerungen und Dimmer im Haus suchen. Also Dimmer (Licht-Dimmer) und Phasenanschnittsteuerungen (Aquarien-/Terrarienheizung? Umwälzpumpe der Heizung?) , die Funkstörungen verursachen, weil die Teile entweder aus einer Zeit vor der EMV-Richtlinie stammen, Kondensatoren aufgrund des Alters kaputtgegangen sind oder die aus dubiosen China-Quellen stammen und kein CE-Zeichen tragen. Einwandfreie Dimmer mit CE-Zeichen und mehr als zwei Meter Abstand zum DCF-Modul sollten eigentlich problemlos sein.
nix_mehr_frei:
Werde mal zum großen blauen C und deren DCF-Modul testen. Wobei das von Pollin ja besser (empfindlicher sein soll) vielleicht isses ja zu empfindlich 
Das mit der Empfindlichkeit halte ich für ein Gerücht. Die Pollin-Module haben einen eingebauten Tiefpass-Filter, der das Signal verzögert, aber viele Störungen bereits im Modul ausfiltert, die vom Conrad-Modul ungefiltert zum Datenausgang durchgeleitet werden. Dadurch sind Pollin-Module meist sogar mit der allerdürftigsten Auswertelogik auswertbar, während Conrad-Module eine hochwertige Auswertelogik erfordern.
Anbei habe ich mal einen Test-Sketch gemacht, der im laufenden Betrieb zwischen “ungefilterten” und “gefiltertem” Signal umgeschaltet werden kann, durch Eingabe von “U” oder “F” im Seriellen Monitor. Falls Du wenigstens mit gefiltertem Signal (F) auswertbare DCF-Impulse bekommst, sollte Udos Auswerteprogramm völlig problemlos funktionieren.
Vielleicht möchtest Du mal den Unterschied ungefiltert/gefiltert beim Signalempfang testen:
#define DCFPIN 8 // Pin für die DCF-Daten
#define LED 13 // Pin für eine Kontroll-LED, 13= Board LED
#define INPUTMODE INPUT_PULLUP // für Pollin-Modul INPUT, für Conrad-Modul INPUT_PULLUP
boolean filterActive=false;
unsigned int hiPulse, loPulse;
boolean filteredState(boolean curVal)
// Lowpass filter
#define N 36
{
static boolean filteredValue;
static byte lowPassVal, lowPassMod;
int i= (N-1)*lowPassVal + curVal*100+lowPassMod;
lowPassVal= i/N;
lowPassMod= i%N;
if (lowPassVal>=67 && !filteredValue) filteredValue=true;
if (lowPassVal<=33 && filteredValue) filteredValue=false;
return filteredValue;
}
boolean pulseComplete(byte curSignal)
{
static boolean lastLogicalSignal;
static unsigned long switchTime;
boolean result=false;
if (curSignal != lastLogicalSignal)
{
long now=millis();
if (curSignal)
{
loPulse=now-switchTime;
result=true;
}
else hiPulse=now-switchTime;
switchTime=now;
lastLogicalSignal=curSignal;
}
return result;
}
void handleSerial()
{
if (Serial.available())
{
char c=Serial.read();
if (c=='F' or c=='f') filterActive=true;
if (c=='U' or c=='u') filterActive=false;
}
}
void setup()
{
Serial.begin(9600);
Serial.println();
Serial.println("DCF Pulse Demo by 'jurs' for German Arduino Forum");
Serial.println("Enter 'U' or 'F' in the Serial Monitor to switch between unfiltered/filtered pulses");
Serial.println();
Serial.println("Filter\tHIGH\tLOW\tPULSE");
pinMode(DCFPIN,INPUTMODE);
pinMode(LED,OUTPUT);
}
void loop()
{
byte state;
state=digitalRead(DCFPIN);
digitalWrite(LED,state);
if (filterActive) state=filteredState(state);
if (pulseComplete(state))
{
if (filterActive) Serial.print("F\t"); else Serial.print("U\t");
Serial.print(hiPulse);
Serial.print('\t');
Serial.print(loPulse);
Serial.print('\t');
Serial.println(hiPulse+loPulse);
}
handleSerial();
delay(1);
}
Ansonsten ist in Fensternähe heutezutage “GPS” eine Alternative zum Empfangen der aktuellen Zeit. Die DCF-Empfangsmodule sind heute so preiswert und so leistungsfähig geworden, dass sie zumindest in Fensternähe von Südost- bis Südwestlage völlig problemlos die Zeit empfangen und preislich dabei kaum teurer als ein DCF-Modul sind. Zum Empfangen der GPS-Zeit wird auch nur ein einziges Satellitensignal benötigt, also nicht mindestens 3 wie für eine GPS-Position, so dass insbesondere in den Abendstunden (bessere Empfangsbedingungen) sogar mitten im Raum die Zeit per GPS empfangen werden kann, wenn man nicht gerade Rollläden vor den Fenstern herunterläßt. GPS sendet nämlich nicht nur die Position, sondern auch die Zeit, und die Zeit ist sogar dann empfangbar, wenn die Empfangsbedingungen für die Positionsbestimmung zu schlecht sind.
