ESP32: cannot connect to NTP server with fixed IP

Hi
I usually use the sketch from here to get the time via NTP. But when I use a fixed IP for my ESP32, the connexion to the NTP server doesn’t work anymore.

Here is the modified sketch: the fixed IP part works in any other conditions.

#include <WiFi.h>
#include "time.h"

const char* ssid       = "YOUR_SSID";
const char* password   = "YOUR_PASS";

// **** These lines added :
//Static IP address configuration
IPAddress staticIP(192, 168, 0, 51); //ESP32 static ip
IPAddress gateway(192, 168, 0, 254); //IP Address of WiFi Router
IPAddress subnet(255, 255, 255, 0);  //Subnet mask
IPAddress dns(192, 168, 0, 254);     //DNS
// *** up to here

const char* ntpServer = "pool.ntp.org";
const long  gmtOffset_sec = 3600;
const int   daylightOffset_sec = 3600;

void printLocalTime()
{
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    Serial.println("Failed to obtain time");
    return;
  }
  Serial.println(&timeinfo, "%A, %B %d %Y %H:%M:%S");
}

void setup()
{
  Serial.begin(115200);

  //connect to WiFi
  Serial.printf("Connecting to %s ", ssid);

// **** These lines added :
  WiFi.mode(WIFI_OFF);
  WiFi.config(staticIP, dns, gateway, subnet);
  WiFi.mode(WIFI_STA); //WiFi mode station (connect to wifi router only)
  delay(100);
// *** up to here

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" CONNECTED");
  Serial.print("WiFi connected - IP address: ");
  Serial.println(WiFi.localIP());

  //init and get the time
  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);
  printLocalTime();

  //disconnect WiFi as it's no longer needed
  WiFi.disconnect(true);
  WiFi.mode(WIFI_OFF);
}

void loop()
{
  delay(1000);
  printLocalTime();
}

I get :

Connecting to ***… CONNECTED
WiFi connected - IP address: 192.168.0.51
Failed to obtain time

What is wrong? Thanks for your help.

I remember have the same issue many months ago. If I remember correctly, I declared
IPAddress timeServerIP globally - which worked fine for DHCP.

However, for the static IP, I had to declare IPAddress timeServerIP locally.

Snippet below.

#include <EEPROM.h>
#include <TimeLib.h>          //https://github.com/PaulStoffregen/Time //Time Library - Time-master


const char* ntpServerName = "time.nist.gov";
const char* WeatherServerName = "api.openweathermap.org";

//  IPAddress timeServerIP;   - - - DECLARE LOCAL

const unsigned int NTP_PACKET_SIZE = 48;
byte packetBuffer[NTP_PACKET_SIZE];

void SetTime() {
  Serial.printf("Contacting NTP server ...");
  //get a random server from the pool
  IPAddress timeServerIP;
  WiFi.hostByName(ntpServerName, timeServerIP);
  
  Serial.printf("timeServerIP = ");
  Serial.println(timeServerIP);
  Serial.printf("END");
  sendNTPpacket(timeServerIP); delay(500);// send an NTP packet to a time server
}

Thanks, but can you explain how I get the time and how I can use it? After getting the time, I need to know the day of the week, the current hour and minute.

But I can't see that in your snippet of code.

Below is what I based my NTP code on - nearly line by line (included with esp8266 library). It nicely details the transaction.

/*

 Udp NTP Client

 Get the time from a Network Time Protocol (NTP) time server
 Demonstrates use of UDP sendPacket and ReceivePacket
 For more on NTP time servers and the messages needed to communicate with them,
 see http://en.wikipedia.org/wiki/Network_Time_Protocol

 created 4 Sep 2010
 by Michael Margolis
 modified 9 Apr 2012
 by Tom Igoe
 updated for the ESP8266 12 Apr 2015 
 by Ivan Grokhotkov

 This code is in the public domain.

 */

#include <ESP8266WiFi.h>
#include <WiFiUdp.h>

char ssid[] = "*************";  //  your network SSID (name)
char pass[] = "********";       // your network password


unsigned int localPort = 2390;      // local port to listen for UDP packets

/* Don't hardwire the IP address or we won't get the benefits of the pool.
 *  Lookup the IP address for the host name instead */
//IPAddress timeServer(129, 6, 15, 28); // time.nist.gov NTP server
IPAddress timeServerIP; // time.nist.gov NTP server address
const char* ntpServerName = "time.nist.gov";

const int NTP_PACKET_SIZE = 48; // NTP time stamp is in the first 48 bytes of the message

byte packetBuffer[ NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

// A UDP instance to let us send and receive packets over UDP
WiFiUDP udp;

void setup()
{
  Serial.begin(115200);
  Serial.println();
  Serial.println();

  // We start by connecting to a WiFi network
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, pass);
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  Serial.println("Starting UDP");
  udp.begin(localPort);
  Serial.print("Local port: ");
  Serial.println(udp.localPort());
}

void loop()
{
  //get a random server from the pool
  WiFi.hostByName(ntpServerName, timeServerIP); 

  sendNTPpacket(timeServerIP); // send an NTP packet to a time server
  // wait to see if a reply is available
  delay(1000);
  
  int cb = udp.parsePacket();
  if (!cb) {
    Serial.println("no packet yet");
  }
  else {
    Serial.print("packet received, length=");
    Serial.println(cb);
    // We've received a packet, read the data from it
    udp.read(packetBuffer, NTP_PACKET_SIZE); // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord;
    Serial.print("Seconds since Jan 1 1900 = " );
    Serial.println(secsSince1900);

    // now convert NTP time into everyday time:
    Serial.print("Unix time = ");
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;
    // subtract seventy years:
    unsigned long epoch = secsSince1900 - seventyYears;
    // print Unix time:
    Serial.println(epoch);


    // print the hour, minute and second:
    Serial.print("The UTC time is ");       // UTC is the time at Greenwich Meridian (GMT)
    Serial.print((epoch  % 86400L) / 3600); // print the hour (86400 equals secs per day)
    Serial.print(':');
    if ( ((epoch % 3600) / 60) < 10 ) {
      // In the first 10 minutes of each hour, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.print((epoch  % 3600) / 60); // print the minute (3600 equals secs per minute)
    Serial.print(':');
    if ( (epoch % 60) < 10 ) {
      // In the first 10 seconds of each minute, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.println(epoch % 60); // print the second
  }
  // wait ten seconds before asking for the time again
  delay(10000);
}

// send an NTP request to the time server at the given address
void sendNTPpacket(IPAddress& address)
{
  Serial.println("sending NTP packet...");
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:
  udp.beginPacket(address, 123); //NTP requests are to port 123
  udp.write(packetBuffer, NTP_PACKET_SIZE);
  udp.endPacket();
}

Notice the IPAddress timeServerIP is declared globally in the default sketch; you’ll want to move that.

But is it fitted for an ESP32?

EDIT : after testing, I have the same problem. It works if I do not force a static IP, using this instruction

WiFi.config(staticIP, dns, gateway, subnet);

and

//Static IP address configuration
IPAddress staticIP(192, 168, 0, 51); //ESP32 static ip
IPAddress gateway(192, 168, 0, 254); //IP Address of WiFi Router
IPAddress subnet(255, 255, 255, 0);  //Subnet mask
IPAddress dns(192, 168, 0, 254);     //DNS

If you used the sketch provided in reply #3, the answer is provided below the sketch for the second time in this thread.

Notice the IPAddress timeServerIP is declared globally in the default sketch; you'll want to move that.

Sorry, not native english speaker here... What do you mean exactly ?

JMeller: Notice the IPAddress timeServerIP is declared globally in the default sketch; [u]you'll want to move that[/u].

Move where and why not global?

Search your code for "WiFi.hostByName(ntpServerName, timeServerIP); " and place above that.

IPAddress timeServerIP;
WiFi.hostByName(ntpServerName, timeServerIP);

Why not global? I don’t have the technical answer; I just know what I did to correct it.

Nobody answered his question. The problem is not the IP of the time server, but the IP of the esp rquesting the time. When the esp8266 is on dhcp...time is correctly returned, when the esp8266 is put on a static IP, the time is incorrect. This problem still exists. The example he quoted at first works fine on dhcp, as soon as you configure the esp8266 for static IP it is wildly wrong.

I faced same problem, while using static IP, NTP won't sync or report anything.

Solved by setting also the DNS by calling the function.

replace: WiFi.config(ip, gateway, subnet); with WiFi.config(ip, dns, gateway, subnet);

Then suddenly works. I guess it is hidden bug somewhere. Using https://github.com/gmag11/NtpClient/blob/master and ESP8266 12E

i had the same problem, and couldn't work it out at first.

the problem is that when you only give an IP address and MAC address, the arduino (whether using ethernet or wifi) has no way of reaching off-network destinations (via a gateway), or looking up DNS addresses (using a DNS server). normally these would be provided by a DHCP server.

the solution is to provide these as needed in the Ethernet.begin() or WiFi,config() call.

alternatively, you can set up an NTP server on your local network and refer to it by IP address, rather than DNS name.

cheers!

I used to think that static IP was the best way to connect my stuff. Big mistake. Once my IP scan got up to 75 devices, managing all those (mostly) static IPs started to get overwhelming. And when I had the same code in two or more nodes on my Home Assistant system (basically sensors), I had to change the IP and recompile each.

DHCP just solves a lot of headaches. I just had about 5 or 6 devices, usually some kind of server, that needed a static IP which the router easily handled.

So, OP, why do you need static IP?

I was trying static addressing on an old sketch I was revising. Couldn't get it to work - it took me about an hour to figure it out and it was nothing to do with static IPs.

I'd got creative when I added a new router - old SSID was "hackdesk" new one was HackDesk.

The SSID is case sensitive - probably not much to do with this thread but a lesson never the less.

adding the DNS specification worked for me Thanks for the suggestion!