NTC resistor and long wire

Other Hardware Sensors
1

I are going to connect several NTC resistors through a analog MUX (controlled by I2C) to measure up to 16 different temperatures. A few of the sensors will be placed several meters away from the Arduino and the MUX.

Will there be any problems with noice? I thougth a capacitor connected in parallel with the NTC close to the MUX could help? Or is there other ways of doing it?

958×607 75.4 KB

2

100nF will do nicely to suppress noise.

3

Thanks, I thought 10 to 100 nF would to the job.

4

and a twisted wire pair.

5

Thought I should come with an update on this.

I have been testing this for while. I have a UNO 3 connected to a 16 channel A/D MUX (CD74HC4057), which is controlled by a PCF8574 I2C unit.
To the MUX I have connected 11 NTCs, one of them is using a 5 meter long NON-twisted wire (AWG 26).

The function reading the temperature on the NTCs looks like this:

#define MUX_INPUT_PIN   A3
#define MUX_INPUT_CNT   20
#define MUX_READ_DELAY  500

float getTemperature(int sensorNumber)
{
  float   temp, logRt;
  int     readValue, inputValue = 0, count = 0;
  int     rvMin = 1024, rvMax = -1;

  Serial.println("");
  Serial.print("Reading sensor ");
  Serial.println(sensorNumber);

  // Select the desired input channel on the MUX.
  for (int i = 0; 4 > i; i++) {
    byte s = (sensorNumber >> i) & 0b0001;
    i2cMuxController.digitalWrite(i, s);
  }

  // Wait a bit and then read value.
  Serial.print("  Values: ");
  for (int i = 0; MUX_INPUT_CNT > i; i++) {
    delay(MUX_READ_DELAY);
    readValue = analogRead(MUX_INPUT_PIN);

    if (readValue > rvMax) {
      rvMax = readValue;
    }
    if (readValue < rvMin) {
      rvMin = readValue;
    }
    
    Serial.print(readValue);
    Serial.print(" ");
    inputValue += readValue;
    ++count;
  }

  // Calulate average.
  inputValue /= count;
  Serial.println("");
  Serial.print("  Avgerage value=");
  Serial.print(inputValue);
  Serial.print("  Min: ");
  Serial.print(rvMin);
  Serial.print("  Max: ");
  Serial.println(rvMax);
  Serial.print("  Worst max-min diff: ");
  Serial.println(rvMax - rvMin);

  // Calculate degree Centigrade.
  logRt = log(10000.0 * ((1024.0 / inputValue) - 1.0));
  temp = 1.0 / (1.009249522e-03 + (2.378405444e-04 * logRt) + (2.019202697e-07 * logRt * logRt * logRt));
  temp -= 273.15;

  // Round to 1 decimal.
  temp = ((int)(temp * 10.0)) / 10.0;
  Serial.print("  Temperature: ");
  Serial.println(temp);

  return temp;
}

As you can see, it does a number of samples for each sensor and it find the highest and lowest read value. I have tried different values in the define statements (delay and sampling count).

It seems like there is hardly no difference in worst min-max diff for the 10 NTC mounted on a prototype board and the one with 5m long wire. I have moved sensor 11 to different places where I know there is a lot of electromagnetic noise (I got a hand-held meter to measure it).

I have also tried with and without the capacitor (and different values of it), but it does not seem to influence on the result.