MPU6050 and flex sensor read problem

I tried reading data from 5 flex sensors (analog pins 0-4) and from an IMU MPU6050 accelerometer on an arduino uno, but the 5th flex sensor (connected to A4) reads values higher than the others and when bent, the serial monitor freezes. The other 4 flex sensor read the data just fine, as well as the accelerometer. The arduino uno is connected to USB and the accelerometer is connected as follows: GND - GND, VDD, VIO - 3.3v (voltage lowered from arduino 5v pin using a voltage regulator AMS1117 - thought it might be an usb voltage problem), SDA - SDA, SCL - SCL. The code i use is this:

#include "I2Cdev.h"
#include "MPU6050.h"

// Arduino Wire library is required if I2Cdev I2CDEV_ARDUINO_WIRE implementation
// is used in I2Cdev.h
#if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
#include "Wire.h"
#endif

// class default I2C address is 0x68
// specific I2C addresses may be passed as a parameter here
// AD0 low = 0x68 (default for InvenSense evaluation board)
// AD0 high = 0x69
MPU6050 accelgyro;
//MPU6050 accelgyro(0x69); // <-- use for AD0 high

int16_t ax, ay, az;
int16_t gx, gy, gz;

int16_t iax, iay, iaz;
int16_t igx, igy, igz;



// uncomment "OUTPUT_READABLE_ACCELGYRO" if you want to see a tab-separated
// list of the accel X/Y/Z and then gyro X/Y/Z values in decimal. Easy to read,
// not so easy to parse, and slow(er) over UART.
#define OUTPUT_READABLE_ACCELGYRO

// uncomment "OUTPUT_BINARY_ACCELGYRO" to send all 6 axes of data as 16-bit
// binary, one right after the other. This is very fast (as fast as possible
// without compression or data loss), and easy to parse, but impossible to read
// for a human.
//#define OUTPUT_BINARY_ACCELGYRO


#define LED_PIN 13
bool blinkState = false;

void setup() {
  // join I2C bus (I2Cdev library doesn't do this automatically)
#if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
  Wire.begin();
#elif I2CDEV_IMPLEMENTATION == I2CDEV_BUILTIN_FASTWIRE
  Fastwire::setup(400, true);
#endif

  // initialize serial communication
  // (38400 chosen because it works as well at 8MHz as it does at 16MHz, but
  // it's really up to you depending on your project)
  Serial.begin(38400);

  // initialize device
  //Serial.println("Initializing I2C devices...");
  accelgyro.initialize();

  // verify connection
  //Serial.println("Testing device connections...");
  //Serial.println(accelgyro.testConnection() ? "successful" : "failed");

  //read initial acc/gyro values
  //accelgyro.getMotion6(&iax, &iay, &iaz, &igx, &igy, &igz);
  
  // configure Arduino LED for
  pinMode(LED_PIN, OUTPUT);
}

void loop() {
  // read raw accel/gyro measurements from device
  accelgyro.getMotion6(&ax, &ay, &az, &gx, &gy, &gz);
  // these methods (and a few others) are also available
  //accelgyro.getAcceleration(&ax, &ay, &az);
  //accelgyro.getRotation(&gx, &gy, &gz);

#ifdef OUTPUT_READABLE_ACCELGYRO
  // display tab-separated accel/gyro x/y/z values
  // Serial.print("a/g:\t");

  char data[200];
  ax = map(ax, -32767, 32767, -10000, 10000);
  ay = map(ay, -32767, 32767, -10000, 10000);
  az = map(az, -32767, 32767, -10000, 10000);
  gx = map(gx, -32767, 32767, -10000, 10000);
  gy = map(gy, -32767, 32767, -10000, 10000);
  gz = map(gz, -32767, 32767, -10000, 10000);
  //sprintf(data, "%d,%d,%d,%d,%d,%d", ax, ay, az, gx, gy, gz);

  int val1 = analogRead(0);
  int val2 = analogRead(1);
  int val3 = analogRead(2);
  int val4 = analogRead(3);
  int val5 = analogRead(4);
   
  sprintf(data, "%d,%d,%d,%d,%d, %d,%d,%d,%d,%d,%d", val1, val2, val3, val4, val5, ax, ay, az, gx, gy, gz);
  //sprintf(data, "%d,%d,%d,%d,%d", val1, val2, val3, val4, val5);
  Serial.println(data);
    
  delay(30);

  
#endif

#ifdef OUTPUT_BINARY_ACCELGYRO
  Serial.write((uint8_t)(ax >> 8)); 
  Serial.write((uint8_t)(ax & 0xFF));
  Serial.write((uint8_t)(ay >> 8)); 
  Serial.write((uint8_t)(ay & 0xFF));
  Serial.write((uint8_t)(az >> 8)); 
  Serial.write((uint8_t)(az & 0xFF));
  Serial.write((uint8_t)(gx >> 8)); 
  Serial.write((uint8_t)(gx & 0xFF));
  Serial.write((uint8_t)(gy >> 8)); 
  Serial.write((uint8_t)(gy & 0xFF));
  Serial.write((uint8_t)(gz >> 8)); 
  Serial.write((uint8_t)(gz & 0xFF));
#endif

  // blink LED to indicate activity
  blinkState = !blinkState;
  digitalWrite(LED_PIN, blinkState);
}

Do you guys have any idea why the serial monitor freezes permanently when bending the 5th flex sensor connected to A4?

A4,A5 on the Uno are also the I2C SCL and SDA. If the project uses I2C, only A0-A3 are usable for analog inputs.